LEVEL_VERSION(1)

START_MONEY(PLAYER0,50000)
START_MONEY(PLAYER1,250000)
START_MONEY(PLAYER_GOOD,50000)

COMPUTER_PLAYER(PLAYER1,2)

MAX_CREATURES(PLAYER0,17)
MAX_CREATURES(PLAYER1,32)

ALLY_PLAYERS(PLAYER0,PLAYER1,2)

REM Shogun

SET_CREATURE_CONFIGURATION(SAMURAI,Health,4000)
SET_CREATURE_CONFIGURATION(SAMURAI,Strength,150)
SET_CREATURE_CONFIGURATION(SAMURAI,Armour,140)
SET_CREATURE_CONFIGURATION(SAMURAI,Luck,30)
SET_CREATURE_CONFIGURATION(SAMURAI,HealThreshold,25)
SET_CREATURE_CONFIGURATION(SAMURAI,FearsomeFactor,10)

SET_CREATURE_PROPERTY(SAMURAI,NEVER_CHICKENS,1)
SET_CREATURE_PROPERTY(SAMURAI,IMMUNE_TO_BOULDER,1)
SET_CREATURE_PROPERTY(SAMURAI,ONE_OF_KIND,1)
SET_CREATURE_PROPERTY(SAMURAI,UNAFFECTED_BY_WIND,1)
SET_CREATURE_PROPERTY(SAMURAI,NO_IMPRISONMENT,1)
SET_CREATURE_PROPERTY(SAMURAI,ILLUMINATED,1)
SET_CREATURE_PROPERTY(SAMURAI,LORD,1)
SET_CREATURE_INSTANCE(SAMURAI, 2, ARMOUR, 2)
SET_CREATURE_INSTANCE(SAMURAI, 3, INVISIBILITY, 3)
SET_CREATURE_INSTANCE(SAMURAI, 4, HEAL, 4)
SET_CREATURE_INSTANCE(SAMURAI, 10, WORD_OF_POWER, 10)

SET_CREATURE_PROPERTY(KNIGHT,LORD,0)
SET_CREATURE_PROPERTY(SORCEROR,IMMUNE_TO_GAS,1)
SET_CREATURE_INSTANCE(SORCEROR, 8, FREEZE, 8)
SET_CREATURE_CONFIGURATION(GIANT,HurtByLava,0)

RESEARCH(PLAYER1,ROOM,BRIDGE,25000)

SET_GENERATE_SPEED(700)
ADD_CREATURE_TO_POOL(TROLL,10)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,5)
ADD_CREATURE_TO_POOL(BILE_DEMON,15)
ADD_CREATURE_TO_POOL(SORCEROR,6)
ADD_CREATURE_TO_POOL(ORC,10)
ADD_CREATURE_TO_POOL(HELL_HOUND,10)
ADD_CREATURE_TO_POOL(SPIDER,5)
ADD_CREATURE_TO_POOL(SKELETON,25)
ADD_CREATURE_TO_POOL(GHOST,6)
ADD_CREATURE_TO_POOL(VAMPIRE,3)
ADD_CREATURE_TO_POOL(DRAGON,4)

CREATURE_AVAILABLE(PLAYER0,TROLL,1,0)
CREATURE_AVAILABLE(PLAYER0,SORCEROR,1,0)
CREATURE_AVAILABLE(PLAYER1,SKELETON,1,80)
CREATURE_AVAILABLE(PLAYER1,GHOST,1,0)
CREATURE_AVAILABLE(PLAYER0,BILE_DEMON,1,0)
CREATURE_AVAILABLE(PLAYER0,DARK_MISTRESS,1,0)
CREATURE_AVAILABLE(PLAYER0,ORC,1,0)
CREATURE_AVAILABLE(PLAYER0,DRAGON,1,0)
CREATURE_AVAILABLE(PLAYER1,SPIDER,1,0)
CREATURE_AVAILABLE(PLAYER0,HELL_HOUND,1,0)
CREATURE_AVAILABLE(PLAYER0,VAMPIRE,1,0)
CREATURE_AVAILABLE(PLAYER1,VAMPIRE,1,1)

ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(PLAYER0,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(PLAYER1,GUARD_POST,1,0)
ROOM_AVAILABLE(PLAYER1,TORTURE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(PLAYER1,TEMPLE,1,0)
ROOM_AVAILABLE(PLAYER1,GRAVEYARD,1,0)

SET_COMPUTER_PROCESS(PLAYER1,"BUILD A TORTURE ROOM",-5,5,6,5,0)
SET_COMPUTER_PROCESS(PLAYER1,"BUILD A GRAVEYARD ROOM",0,5,6,11,0)
SET_COMPUTER_PROCESS(PLAYER1,"BUILD A WORKSHOP ROOM",-20,7,7,8,0)
SET_COMPUTER_PROCESS(PLAYER1,"BUILD A BARRACK ROOM",-10,4,4,12,0)

REM SET_COMPUTER_GLOBALS(PLAYER1,50,1,1,1,10000,1)

IF(PLAYER0,TEMPLE > 0)
    ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,1)
    TUTORIAL_FLASH_BUTTON(12,100)
ENDIF

IF(PLAYER0,TORTURE > 0)
    ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,1)
    TUTORIAL_FLASH_BUTTON(17,100)
ENDIF

IF(PLAYER_GOOD,BATTLES_LOST >= 12)
	MAGIC_AVAILABLE(PLAYER1,POWER_SPEED,1,0)
ENDIF

IF(PLAYER_GOOD,BATTLES_LOST >= 24)
	COMPUTER_PLAYER(PLAYER1,0)
ENDIF

IF(PLAYER_GOOD,BATTLES_LOST >= 36)
	MAGIC_AVAILABLE(PLAYER1,POWER_DESTROY_WALLS,1,0)
ENDIF

IF(PLAYER0,BRIDGE > 0)
    ROOM_AVAILABLE(PLAYER0,BRIDGE,1,1)
	ROOM_AVAILABLE(PLAYER1,BRIDGE,1,0)
    TUTORIAL_FLASH_BUTTON(18,100)
ENDIF

IF(PLAYER0,GUARD_POST > 0)
    ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,1)
    TUTORIAL_FLASH_BUTTON(19,100)
ENDIF

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CHICKEN,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_SPEED,1,0)

TRAP_AVAILABLE(ALL_PLAYERS,ALARM,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,WORD_OF_POWER,1,0)

CREATE_PARTY(KNIGHT)
	ADD_TO_PARTY(KNIGHT,KNIGHT,7,1000,DEFEND_LOCATION,25000)

CREATE_PARTY(ONE)
    ADD_TO_PARTY(ONE,THIEF,5,300,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(ONE,THIEF,4,250,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(ONE,THIEF,4,400,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(ONE,ARCHER,4,350,DEFEND_PARTY,0)
    ADD_TO_PARTY(ONE,DWARFA,3,300,STEAL_GOLD,0)

CREATE_PARTY(TWO)
    ADD_TO_PARTY(TWO,BARBARIAN,4,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(TWO,BARBARIAN,5,450,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(TWO,ARCHER,4,350,DEFEND_PARTY,0)
    ADD_TO_PARTY(TWO,ARCHER,5,350,DEFEND_PARTY,0)

CREATE_PARTY(THREE)
    ADD_TO_PARTY(THREE,MONK,5,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(THREE,MONK,6,600,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(THREE,WITCH,4,400,DEFEND_PARTY,0)
    ADD_TO_PARTY(THREE,WITCH,5,400,DEFEND_PARTY,0)

CREATE_PARTY(FOUR)
    ADD_TO_PARTY(FOUR,KNIGHT,7,1000,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(FOUR,KNIGHT,7,1000,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(FOUR,WIZARD,7,750,DEFEND_PARTY,0)

CREATE_PARTY(BRUTES)
    ADD_TO_PARTY(BRUTES,GIANT,6,500,SABOTAGE_ROOMS,0)
    ADD_TO_PARTY(BRUTES,GIANT,6,500,SABOTAGE_ROOMS,0)
    ADD_TO_PARTY(BRUTES,GIANT,6,500,ATTACK_ROOMS,0)
    ADD_TO_PARTY(BRUTES,GIANT,6,500,ATTACK_ROOMS,0)
    ADD_TO_PARTY(BRUTES,GIANT,6,500,DEFEND_PARTY,0)
    ADD_TO_PARTY(BRUTES,GIANT,6,500,DEFEND_PARTY,0)

CREATE_PARTY(SCOUTS)
    ADD_TO_PARTY(SCOUTS,DWARFA,10,750,STEAL_GOLD,0)
    ADD_TO_PARTY(SCOUTS,THIEF,9,700,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(SCOUTS,THIEF,9,700,DEFEND_PARTY,0)
    ADD_TO_PARTY(SCOUTS,THIEF,8,700,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(SCOUTS,ARCHER,9,500,DEFEND_PARTY,0)
    ADD_TO_PARTY(SCOUTS,ARCHER,8,500,DEFEND_PARTY,0)
    ADD_TO_PARTY(SCOUTS,ARCHER,8,500,DEFEND_PARTY,0)

CREATE_PARTY(MYSTIC)
    ADD_TO_PARTY(MYSTIC,MONK,7,750,DEFEND_PARTY,0)
    ADD_TO_PARTY(MYSTIC,WIZARD,8,800,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(MYSTIC,FAIRY,8,1000,STEAL_SPELLS,0)
    ADD_TO_PARTY(MYSTIC,WITCH,8,500,STEAL_SPELLS,0)

CREATE_PARTY(HOLY)
    ADD_TO_PARTY(HOLY,MONK,7,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(HOLY,MONK,8,500,STEAL_SPELLS,0)
    ADD_TO_PARTY(HOLY,MONK,7,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(HOLY,MONK,6,500,DEFEND_PARTY,0)

CREATE_PARTY(ELITES)
    ADD_TO_PARTY(ELITES,KNIGHT,9,1500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(ELITES,WIZARD,8,1250,STEAL_SPELLS,0)
    ADD_TO_PARTY(ELITES,BARBARIAN,8,1000,DEFEND_ROOMS,0)
    ADD_TO_PARTY(ELITES,GIANT,7,1000,ATTACK_ENEMIES,0)

CREATE_PARTY(SHOGUN)
    ADD_TO_PARTY(SHOGUN,SAMURAI,10,5000,DEFEND_HEART,200)
    ADD_TO_PARTY(SHOGUN,TIME_MAGE,10,1000,STEAL_SPELLS,200)
    ADD_TO_PARTY(SHOGUN,ARCHER,8,1000,DEFEND_PARTY,200)
    ADD_TO_PARTY(SHOGUN,MONK,8,1000,DEFEND_PARTY,200)
    ADD_TO_PARTY(SHOGUN,KNIGHT,8,1000,DEFEND_ROOMS,200)
    ADD_TO_PARTY(SHOGUN,WITCH,9,800,STEAL_SPELLS,200)
	ADD_TO_PARTY(SHOGUN,FAIRY,8,800,DEFEND_ROOMS,200)

QUICK_OBJECTIVE(0,"This realm is ruled by the Shogun, a legendary Samurai warrior with great swordfighting skills. I say it's time we put these so-called skills to the test! Be warned, the Shogun may decide to pre-emptively attack us if we become too powerful.",PLAYER0)


RANDOMISE_FLAG(PLAYER0,FLAG1,100)

IF(PLAYER0,FLAG1 > 50)
	IF(PLAYER0,FLAG1 <= 60)
		SET_PLAYER_COLOR(PLAYER0,BLUE)
		SET_PLAYER_COLOR(PLAYER1,RED)
	ENDIF
ENDIF

IF(PLAYER0,FLAG1 > 60)
	IF(PLAYER0,FLAG1 <= 70)
		SET_PLAYER_COLOR(PLAYER0,YELLOW)
		SET_PLAYER_COLOR(PLAYER1,BLACK)
	ENDIF
ENDIF

IF(PLAYER0,FLAG1 > 70)
	IF(PLAYER0,FLAG1 <= 80)
		SET_PLAYER_COLOR(PLAYER0,GREEN)
		SET_PLAYER_COLOR(PLAYER1,BLACK)
	ENDIF
ENDIF

IF(PLAYER0,FLAG1 > 80)
	IF(PLAYER0,FLAG1 <= 90)
		SET_PLAYER_COLOR(PLAYER0,ORANGE)
		SET_PLAYER_COLOR(PLAYER1,BLACK)
	ENDIF
ENDIF

IF(PLAYER0,FLAG1 > 90)
	SET_PLAYER_COLOR(PLAYER0,PURPLE)
	SET_PLAYER_COLOR(PLAYER1,BLACK)
ENDIF

ADD_PARTY_TO_LEVEL(PLAYER_GOOD,KNIGHT,-9,2)

IF_SLAB_OWNER(13,​63,​PLAYER0)
	IF(PLAYER0,ENTRANCE > 9)
		MAX_CREATURES(PLAYER0,25)
		ADD_CREATURE_TO_POOL(DRAGON,8)
	ENDIF
ENDIF

IF_SLAB_OWNER(13,​63,​PLAYER1)
	IF(PLAYER1,ENTRANCE > 9)
		MAX_CREATURES(PLAYER1,40)
	ENDIF
ENDIF

IF_ACTION_POINT(3,PLAYER0)
    IF(PLAYER_GOOD,FLAG1 == 0)
		SET_FLAG(PLAYER_GOOD,FLAG1,1)
    ENDIF
ENDIF

IF_ACTION_POINT(3,PLAYER1)
	IF(PLAYER_GOOD,FLAG1 == 0)
	    SET_FLAG(PLAYER_GOOD,FLAG1,2)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ELITES,-6,1)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ELITES,-8,1)
	ENDIF
ENDIF

IF(PLAYER1,DUNGEON_DESTROYED == 1)
    IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
        IF(PLAYER_GOOD,FLAG1 == 0)
			IF(PLAYER0,TOTAL_CREATURES >= 25)
				SET_FLAG(PLAYER_GOOD,FLAG1,3)
				SET_FLAG(PLAYER_GOOD,FLAG2,2)
				SET_TIMER(PLAYER_GOOD,TIMER1)
				SET_TIMER(PLAYER_GOOD,TIMER2)
				SET_TIMER(PLAYER_GOOD,TIMER3)
				CHANGE_SLAB_TYPE(​32,​58,​DIRT)
				CHANGE_SLAB_TYPE(​68,​61,​DIRT)
				SET_DOOR(UNLOCKED,47,49)
				SET_DOOR(UNLOCKED,57,49)
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG1 != 0)
	SET_TIMER(PLAYER_GOOD,TIMER1)
	SET_TIMER(PLAYER_GOOD,TIMER2)
ENDIF

IF(PLAYER_GOOD,TIMER3 >= 1000)
    IF(PLAYER_GOOD,FLAG2 != 0)
        ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,-7,ACTION_POINT,10,8,1000)
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DWARFA,-7,2,7,500)
        ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,-9,ACTION_POINT,9,8,1000)
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DWARFA,-9,2,7,500)
		ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,-5,ACTION_POINT,11,8,1000)
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DWARFA,-5,2,7,500)
    ENDIF
ENDIF

IF_ACTION_POINT(4,PLAYER0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ONE,2,1)
ENDIF

IF_ACTION_POINT(5,PLAYER0)
    SET_TIMER(PLAYER0,TIMER0)
ENDIF

IF(PLAYER0,TIMER0 >= 1500)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TWO,-1,1)
ENDIF

IF(PLAYER0,TIMER0 >= 3000)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,THREE,-2,1)
ENDIF

IF_ACTION_POINT(7,PLAYER0)
	IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
		SET_TIMER(PLAYER0,TIMER1)
	ENDIF
ENDIF

IF(PLAYER0,TIMER1 >= 2500)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,THREE,-3,1)
ENDIF

IF(PLAYER0,TIMER1 >= 5000)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,BRUTES,-4,1)
ENDIF

IF(PLAYER0,TIMER1 >= 7500)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,HOLY,-4,1)
ENDIF

IF(PLAYER0,TIMER1 >= 10000)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FOUR,-3,1)
ENDIF

IF(PLAYER_GOOD,FLAG1 != 0)
    IF(PLAYER_GOOD,TIMER2 >= 2000)
        IF(PLAYER_GOOD,SAMURAI == 1)
			IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
				IF(PLAYER_GOOD,TOTAL_CREATURES <= 30)
					SET_FLAG(PLAYER_GOOD,FLAG2,1)
					NEXT_COMMAND_REUSABLE
					ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FOUR,-7,1)
					NEXT_COMMAND_REUSABLE
					SET_TIMER(PLAYER_GOOD,TIMER2)
				ENDIF
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG1 != 0)
    IF(PLAYER_GOOD,TIMER1 >= 1000)
        QUICK_OBJECTIVE(1,"The Shogun himself has arrived... string him up!",PLAYER_GOOD)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SHOGUN,-7,1)
		SET_TIMER(PLAYER_GOOD,TIMER4)
		ADD_GOLD_TO_PLAYER(PLAYER_GOOD,50000)
    ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG1 != 0)
    IF(PLAYER_GOOD,TIMER1 >= 5000)
		IF(PLAYER_GOOD,SAMURAI == 1)
			IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD,BRUTES,-5,1)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD,BRUTES,-6,1)
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG1 != 0)
	IF(PLAYER_GOOD,TIMER1 >= 8000)
		IF(PLAYER_GOOD,SAMURAI == 1)
			IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SCOUTS,-8,1)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SCOUTS,-9,1)
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG1 != 0)
    IF(PLAYER_GOOD,TIMER1 >= 15000)
		IF(PLAYER_GOOD,SAMURAI == 1)
			IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MYSTIC,-5,1)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MYSTIC,-6,1)
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG1 != 0)
    IF(PLAYER_GOOD,TIMER1 >= 25000)
		IF(PLAYER_GOOD,SAMURAI == 1)
			IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ELITES,-8,1)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ELITES,-9,1)
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG1 != 0)
    IF(PLAYER_GOOD,TIMER1 >= 1500)
        IF(PLAYER_GOOD,SAMURAI == 0)
            QUICK_OBJECTIVE(2,"The Shogun has fallen, now eliminate any remaining opposition!",PLAYER1)
        ENDIF
    ENDIF
ENDIF



IF(PLAYER_GOOD,TIMER4 >= 7500)
	ADD_TO_PARTY(FOUR,FAIRY,7,500,STEAL_SPELLS,0)
	ADD_TO_PARTY(FOUR,WITCH,7,500,STEAL_SPELLS,0)
ENDIF

IF(PLAYER_GOOD,TIMER4 >= 15000)
	ADD_TO_PARTY(FOUR,MONK,7,600,SABOTAGE_ROOMS,0)
	ADD_TO_PARTY(FOUR,GIANT,7,600,SABOTAGE_ROOMS,0)
ENDIF

IF(PLAYER0,ALL_DUNGEONS_DESTROYED == 1)
    IF(PLAYER_GOOD,TOTAL_CREATURES == 0)
        IF(PLAYER_GOOD,FLAG1 != 0)
			DISPLAY_OBJECTIVE(8,PLAYER0)
            WIN_GAME
        ENDIF
    ENDIF
ENDIF
