REM ********************************************
REM
REM             Script for Level 411
REM		Dwindlestock
REM
REM ********************************************



SET_GENERATE_SPEED(500)

COMPUTER_PLAYER(PLAYER1,0)

MAX_CREATURES(PLAYER0, 20)
MAX_CREATURES(PLAYER1, 25)

START_MONEY(PLAYER0, 6000)
START_MONEY(PLAYER1, 10000)

SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, THIEF,	10)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, DEMONSPAWN,	10)

ADD_CREATURE_TO_POOL(BILE_DEMON,	20)
ADD_CREATURE_TO_POOL(DEMONSPAWN,	20)
ADD_CREATURE_TO_POOL(TROLL,		20)
ADD_CREATURE_TO_POOL(SORCEROR,		5)


CREATURE_AVAILABLE(ALL_PLAYERS, BILE_DEMON,	1, 1)
CREATURE_AVAILABLE(ALL_PLAYERS, DEMONSPAWN,	1, 1)
CREATURE_AVAILABLE(ALL_PLAYERS, TROLL,		1, 1)
CREATURE_AVAILABLE(PLAYER1, SORCEROR,		1, 1)


ROOM_AVAILABLE(ALL_PLAYERS,	TREASURE,	1, 1)
ROOM_AVAILABLE(ALL_PLAYERS,	RESEARCH,	1, 1)
ROOM_AVAILABLE(ALL_PLAYERS,	GARDEN,		1, 1)
ROOM_AVAILABLE(ALL_PLAYERS,	LAIR,		1, 1)
ROOM_AVAILABLE(ALL_PLAYERS,	TRAINING,	1, 1)
ROOM_AVAILABLE(PLAYER0,	BRIDGE,		1, 0)
ROOM_AVAILABLE(PLAYER0,	PRISON,		1, 0)
ROOM_AVAILABLE(PLAYER0,	TORTURE,	1, 0)
ROOM_AVAILABLE(ALL_PLAYERS,	WORKSHOP,	1, 0)
ROOM_AVAILABLE(PLAYER0,	GUARD_POST,	1, 0)


MAGIC_AVAILABLE(ALL_PLAYERS, POWER_IMP,  		1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SLAP, 		1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_CALL_TO_ARMS,	1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SPEED,		1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_CAVE_IN,		1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_DESTROY_WALLS,	1, 0)


DOOR_AVAILABLE(ALL_PLAYERS, WOOD, 1, 0)
DOOR_AVAILABLE(ALL_PLAYERS, BRACED, 1, 0)


REM RESEARCH(ALL_PLAYERS,MAGIC,POWER_DESTROY_WALLS,50000)

CREATE_PARTY(PARTYA)
ADD_TO_PARTY(PARTYA,THIEF,1,100,STEAL_GOLD,0)
ADD_TO_PARTY(PARTYA,THIEF,1,100,STEAL_GOLD,0)
ADD_TO_PARTY(PARTYA,WIZARD,2,200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYA,ARCHER,2,200,ATTACK_DUNGEON_HEART,0)


CREATE_PARTY(PARTYB)
ADD_TO_PARTY(PARTYB,THIEF,3,200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYB,THIEF,3,200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYB,BARBARIAN,2,300,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYB,WIZARD,3,300,ATTACK_DUNGEON_HEART,0)


CREATE_PARTY(PARTYC)
ADD_TO_PARTY(PARTYC,THIEF,4,300,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYC,THIEF,4,300,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYC,ARCHER,4,200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYC,WIZARD,5,400,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYC,WIZARD,5,400,ATTACK_DUNGEON_HEART,0)


CREATE_PARTY(PARTYD)
ADD_TO_PARTY(PARTYD,FAIRY,3,400,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYD,FAIRY,3,400,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYD,FAIRY,4,400,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYD,FAIRY,4,400,ATTACK_DUNGEON_HEART,0)


CREATE_PARTY(PARTYE)
ADD_TO_PARTY(PARTYE,THIEF,6,800,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYE,THIEF,6,800,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYE,BARBARIAN,6,800,ATTACK_DUNGEON_HEART,0)


CREATE_PARTY(LORDPARTY)
ADD_TO_PARTY(LORDPARTY,KNIGHT,8,3600,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(LORDPARTY,BARBARIAN,7,1200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(LORDPARTY,BARBARIAN,7,1200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(LORDPARTY,BARBARIAN,7,1200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(LORDPARTY,ARCHER,7,800,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(LORDPARTY,ARCHER,7,800,ATTACK_DUNGEON_HEART,0)


QUICK_OBJECTIVE(0, "Another dungeon keeper has arrived here along with you, and appears to have the better ground too. Make good use of everything you get your greedy hands on, and send him and the resident heroes packing.", PLAYER0)


IF(PLAYER0, GAME_TURN > 2000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYA,-1,DUNGEON_HEART,0,2,200)
ENDIF


IF(PLAYER0, GAME_TURN > 6000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYB,-1,DUNGEON_HEART,0,3,300)
ENDIF


IF(PLAYER0, GAME_TURN > 10000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYC,-1,1)
ENDIF


IF(PLAYER0, GAME_TURN > 22000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYE,-2,1)
ENDIF



IF(PLAYER0, ENTRANCE >= 1)
	SET_TIMER(PLAYER0,TIMER0)
	QUICK_INFORMATION(1, "You finally have a Portal, but even now the creatures available will be somewhat limited. Perhaps you could persuade some of your prisoners to fill the open vacancies. That, or you could just leave them to rot; it's your choice.")
ENDIF


IF(PLAYER0, TIMER0 > 2000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYB,-2,1)
ENDIF


IF(PLAYER0, TIMER0 > 9000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYD,-3,1)
ENDIF


IF(PLAYER0, TIMER0 > 16000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYD,-3,1)
ENDIF


IF(PLAYER0, PRISON >= 1)
	ROOM_AVAILABLE(PLAYER0,	PRISON,	1, 1)
ENDIF

IF(PLAYER0, TORTURE >= 1)
	ROOM_AVAILABLE(PLAYER0,	TORTURE, 1, 1)
ENDIF

IF(PLAYER0, BRIDGE >= 1)
	ROOM_AVAILABLE(PLAYER0,	BRIDGE, 1, 1)
ENDIF

IF(PLAYER0, WORKSHOP >= 1)
	ROOM_AVAILABLE(PLAYER0,	WORKSHOP, 1, 1)
ENDIF

IF(PLAYER1, BRIDGE >= 1)
	ROOM_AVAILABLE(PLAYER1,	BRIDGE, 1, 1)
ENDIF



IF(PLAYER1,DUNGEON_DESTROYED == 1)
	SET_TIMER(PLAYER0,TIMER1)
	QUICK_INFORMATION(2, "Your rival has been deservedly beaten into submission, but the battle for this realm is not over yet. Ready your forces quickly, for the final clash will soon be upon us.")
ENDIF


IF(PLAYER0, TIMER1 > 2000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LORDPARTY,-2,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYE,-1,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYD,-3,1)
	SET_FLAG(PLAYER0, FLAG0, 1)
ENDIF


IF(PLAYER0, FLAG0 == 1)
	IF(PLAYER_GOOD, TOTAL_CREATURES == 0)
		QUICK_OBJECTIVE(3, "Your dominion over this land is now very much complete. All who could oppose you here now kneel trembling before your legion. All in a days work, naturally.", PLAYER0)
		WIN_GAME
	ENDIF
ENDIF
