REM ********************************************
REM Script for Level 202
REM Minotaur Maze
REM ********************************************


START_MONEY(PLAYER0,15000)

ROOM_AVAILABLE(PLAYER0,TREASURE,1,1)
ROOM_AVAILABLE(PLAYER0,LAIR,1,1)
ROOM_AVAILABLE(PLAYER0,GARDEN,1,1)
ROOM_AVAILABLE(PLAYER0,TRAINING,0,0)
ROOM_AVAILABLE(PLAYER0,RESEARCH,0,0)
ROOM_AVAILABLE(PLAYER0,BRIDGE,0,0)
ROOM_AVAILABLE(PLAYER0,BARRACKS,0,0)
ROOM_AVAILABLE(PLAYER0,GUARD_POST,1,0)
ROOM_AVAILABLE(PLAYER0,TORTURE,0,0)
ROOM_AVAILABLE(PLAYER0,TEMPLE,0,0)
ROOM_AVAILABLE(PLAYER0,WORKSHOP,0,0)
ROOM_AVAILABLE(PLAYER0,GRAVEYARD,0,0)
ROOM_AVAILABLE(PLAYER0,PRISON,0,0)


IF(PLAYER0,BRIDGE > 0)
    ROOM_AVAILABLE(PLAYER0,BRIDGE,1,1)
ENDIF
IF(PLAYER0,WORKSHOP > 0)
    ROOM_AVAILABLE(PLAYER0,WORKSHOP,1,1)
ENDIF

MAGIC_AVAILABLE(PLAYER0,POWER_HAND,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_IMP,0,0)
MAGIC_AVAILABLE(PLAYER0,POWER_SLAP,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_OBEY,0,0)
MAGIC_AVAILABLE(PLAYER0,POWER_CALL_TO_ARMS,0,0)
MAGIC_AVAILABLE(PLAYER0,POWER_HEAL_CREATURE,0,0)
MAGIC_AVAILABLE(PLAYER0,POWER_SPEED,0,0)
MAGIC_AVAILABLE(PLAYER0,POWER_PROTECT,0,0)
MAGIC_AVAILABLE(PLAYER0,POWER_CONCEAL,0,0)
MAGIC_AVAILABLE(PLAYER0,POWER_CAVE_IN,0,0)
MAGIC_AVAILABLE(PLAYER0,POWER_CHICKEN,0,0)
MAGIC_AVAILABLE(PLAYER0,POWER_LIGHTNING,0,0)
MAGIC_AVAILABLE(PLAYER0,POWER_DESTROY_WALLS,0,0)

DOOR_AVAILABLE(PLAYER0,MAGIC,1,0)


CREATE_PARTY(GUARDIANS)
REM Party Name,Creature Name,Experience,Amount of Gold,Objective,Countdown
    ADD_TO_PARTY(GUARDIANS,HORNY,10,10000,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(GUARDIANS,HORNY,10,10000,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(GUARDIANS,HORNY,10,10000,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(GUARDIANS,HORNY,10,10000,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(GUARDIANS,HORNY,10,10000,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(GUARDIANS,HORNY,10,10000,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(GUARDIANS,HORNY,10,10000,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(GUARDIANS,KNIGHT,10,100000,ATTACK_DUNGEON_HEART,0)


QUICK_OBJECTIVE(1,"They say that this land is ruled by legendary horde of minotaurs in the very heart of the labyrinth. Tresures of unspeakable power were hidden here, master. Legend says that some time ago three brothers, Champions of Light were trapped here... ",PLAYER0)

IF(PLAYER0,FAIRY > 0)
    QUICK_INFORMATION(9,"Master, I have to warn you. There are no portals and training rooms in this labyrinth, so take care of creatures you find.")
ENDIF


IF(PLAYER0,GAME_TURN > 250)
    QUICK_INFORMATION(8,"Beware, Master! Some pathes are extremely dangerous. To the North lies The Lost City and The Hall of Seven Doors. Find them as fast as possible.")
ENDIF


IF(PLAYER0,AVATAR == 3)

    QUICK_INFORMATION(2,"Oh my Gods! You've found them, master! Perhaps now you can challenge minotaurs horde. Go with the light, master! The Three MUST SURVIVE!")
    SET_TIMER(PLAYER0,TIMER0)
ENDIF

IF(PLAYER0,TIMER0 >= 360)
QUICK_INFORMATION(6,"My Lord, be warned! By resquing The Three you have disturbed the Guardians of this land! Soon they'll be here! The Three must survive! If not, all would be lost!")
ENDIF

IF(PLAYER0,TIMER0 >= 2400)
    QUICK_INFORMATION(7,"My Gods! They are coming!!!")
ENDIF


IF(PLAYER0,TIMER0 >= 2520)
    REM The player the party is assigned to	Party Name	Action Point or Hero Door	Number of copies of party

    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GUARDIANS,-1,1)

ENDIF


IF_ACTION_POINT(4,PLAYER0)
    QUICK_INFORMATION(3,"Now you can reveal the location of The Brothers and resque them.")
ENDIF

IF_ACTION_POINT(3,PLAYER0)
    QUICK_INFORMATION(4,"Beware! Beyond rest the spirits of miners who were buried alive here centures ago.")
ENDIF

IF_ACTION_POINT(2,PLAYER0)
    SET_TIMER(PLAYER0,TIMER1)
    QUICK_INFORMATION(5,"You have found the Hall of Seven Doors! Chose your path wisely, master. And beware! This Hall emits powerful magic. ")
ENDIF

IF(PLAYER0,TIMER1 >= 200)
    QUICK_INFORMATION(10,"On the walls of this Hall you can read the runes: By seeking bridge, book and wall one can join The Three...")
ENDIF


IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
    IF(PLAYER_GOOD,TOTAL_CREATURES >= 1)
        QUICK_INFORMATION(11,"You have destroyed The Heart of evil, but some cretures still lurk within this place. Kill them all!")
    ENDIF
ENDIF

IF(PLAYER0,TIMER0 <= 1)
    IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
        IF(PLAYER_GOOD,TOTAL_CREATURES >= 1)
            QUICK_INFORMATION(12,"You have managed to destroy The Heart of evil without help of The Three! I am impressed, master! But to win you have to find them!")
        ENDIF
    ENDIF
ENDIF


IF(PLAYER0,TIMER0 >= 2520)
    IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
        IF(PLAYER_GOOD,TOTAL_CREATURES == 0)
            WIN_GAME
        ENDIF
    ENDIF
ENDIF


IF(PLAYER0,TIMER0 >= 1)
    IF(PLAYER0,AVATAR < 3)
        LOSE_GAME
    ENDIF
ENDIF
