REM ********************************************
REM
REM             Script for Level 202
REM		Vangloria
REM
REM ********************************************

START_MONEY(PLAYER0, 8000)

SET_GENERATE_SPEED(500)

MAX_CREATURES(PLAYER0, 25)

SET_CREATURE_MAX_LEVEL(PLAYER0, DEMONSPAWN, 10)


ADD_CREATURE_TO_POOL(FLY,	5)
ADD_CREATURE_TO_POOL(DEMONSPAWN,10)
ADD_CREATURE_TO_POOL(SORCEROR,	10)
ADD_CREATURE_TO_POOL(TROLL,	20)
ADD_CREATURE_TO_POOL(SPIDER,	30)
ADD_CREATURE_TO_POOL(ORC,	10)

CREATURE_AVAILABLE(PLAYER0, FLY,	1, 1)
CREATURE_AVAILABLE(PLAYER0, DEMONSPAWN,	1, 1)
CREATURE_AVAILABLE(PLAYER0, SORCEROR,	1, 1)
CREATURE_AVAILABLE(PLAYER0, TROLL,	1, 1)
CREATURE_AVAILABLE(PLAYER0, SPIDER,	1, 1)
CREATURE_AVAILABLE(PLAYER0, ORC,	1, 1)


ROOM_AVAILABLE(PLAYER0,	TREASURE,	1, 1)
ROOM_AVAILABLE(PLAYER0,	RESEARCH,	1, 1)
ROOM_AVAILABLE(PLAYER0,	GARDEN,		1, 1)
ROOM_AVAILABLE(PLAYER0,	LAIR,		1, 1)
ROOM_AVAILABLE(PLAYER0,	TRAINING,	1, 1)
ROOM_AVAILABLE(PLAYER0,	WORKSHOP,	1, 0)
ROOM_AVAILABLE(PLAYER0,	GUARD_POST,	1, 0)
ROOM_AVAILABLE(PLAYER0,	BARRACKS,	1, 0)
ROOM_AVAILABLE(PLAYER0,	GRAVEYARD,	1, 0)
ROOM_AVAILABLE(PLAYER0,	TEMPLE,		1, 0)


MAGIC_AVAILABLE(PLAYER0, POWER_IMP,  1,	1)
MAGIC_AVAILABLE(PLAYER0, POWER_SLAP, 1,	1)
MAGIC_AVAILABLE(PLAYER0, POWER_SIGHT,	1, 0)
MAGIC_AVAILABLE(PLAYER0, POWER_CALL_TO_ARMS,	1, 0)
MAGIC_AVAILABLE(PLAYER0, POWER_SPEED,		1, 0)
MAGIC_AVAILABLE(PLAYER0, POWER_PROTECT,		1, 0)
MAGIC_AVAILABLE(PLAYER0, POWER_HEAL_CREATURE,	1, 0)


DOOR_AVAILABLE(PLAYER0, WOOD, 1, 0)
DOOR_AVAILABLE(PLAYER0, BRACED, 1, 0)
DOOR_AVAILABLE(PLAYER0,	STEEL,	1, 0)
TRAP_AVAILABLE(PLAYER0,	ALARM,		1, 0)
TRAP_AVAILABLE(PLAYER0,	POISON_GAS,	1, 0)


CREATE_PARTY(PARTYA)
ADD_TO_PARTY(PARTYA,DWARFA,2,200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYA,DWARFA,2,200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYA,DWARFA,3,200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYA,DWARFA,3,200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYA,WIZARD,3,500,ATTACK_DUNGEON_HEART,0)


CREATE_PARTY(PARTYB)
ADD_TO_PARTY(PARTYB,DWARFA,3,200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYB,DWARFA,3,200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYB,DWARFA,3,200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYB,WIZARD,5,600,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYB,WIZARD,5,600,ATTACK_DUNGEON_HEART,0)


CREATE_PARTY(PARTYC)
ADD_TO_PARTY(PARTYC,DWARFA,5,300,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYC,DWARFA,5,300,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYC,DWARFA,6,400,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYC,WIZARD,5,600,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYC,WIZARD,5,600,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(PARTYC,WIZARD,6,800,ATTACK_DUNGEON_HEART,0)


CREATE_PARTY(LORDPARTY)
ADD_TO_PARTY(LORDPARTY,KNIGHT,8,4000,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(LORDPARTY,WIZARD,7,1200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(LORDPARTY,WIZARD,7,1200,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(LORDPARTY,DWARFA,8,800,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(LORDPARTY,DWARFA,7,400,ATTACK_DUNGEON_HEART,0)
ADD_TO_PARTY(LORDPARTY,DWARFA,7,400,ATTACK_DUNGEON_HEART,0)


QUICK_OBJECTIVE(0, "Forgotten tunnels and putrid rivers criss-cross this underworld. Prime real estate of course, but do not delay in establishing your forces, Keeper. Repungant legions of do-gooders will be upon us soon.", PLAYER0)


IF(PLAYER0, GAME_TURN > 8000)
	QUICK_INFORMATION(1, "Know that a self-righteous band is already on the march. See that all pointed implements are sharpened in preparation; many more will follow.")
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYA,-3,DUNGEON_HEART,0,2,200)
ENDIF


IF(PLAYER0, GAME_TURN > 11000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYA,-4,DUNGEON_HEART,0,2,200)
ENDIF


IF(PLAYER0, GAME_TURN > 15000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYB,-3,1)
ENDIF


IF(PLAYER0, GAME_TURN > 18000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYB,-4,1)
ENDIF


IF(PLAYER0, GAME_TURN > 22000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYC,-1,DUNGEON_HEART,0,5,500)
ENDIF



IF(PLAYER0, GAME_TURN > 26000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYB,-4,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYB,-3,1)
ENDIF


IF(PLAYER0, GAME_TURN > 30000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYC,-4,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYC,-3,1)
ENDIF


IF(PLAYER0, BARRACKS >= 1)
	ROOM_AVAILABLE(PLAYER0,	BARRACKS,	1, 1)
ENDIF


IF(PLAYER0, BRIDGE >= 1)
	QUICK_OBJECTIVE(2, "The bridge design you've acquired will allow you to control more of this realm than before. Keep exploring, but with haste; the leaders of this land won't tolerate you for much longer.", PLAYER0)
	ROOM_AVAILABLE(PLAYER0,	BRIDGE,	1, 1)
	SET_TIMER(PLAYER0,TIMER0)
ENDIF


IF(PLAYER0,TIMER0 >= 4000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYC,-2,1)
ENDIF


IF(PLAYER0,TIMER0 >= 8000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LORDPARTY,-2,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTYC,-1,1)
	SET_FLAG(PLAYER0, FLAG0, 1)
ENDIF


IF(PLAYER0, FLAG0 == 1)
	IF(PLAYER_GOOD, KNIGHT == 0)
		IF(PLAYER_GOOD, WIZARD == 0)
			QUICK_OBJECTIVE(3, "Well done, Keeper. The pitiful forces of justice here are no more. Shall we continue our improvements on the now-defenceless inhabitants of the surface?", PLAYER0)
			WIN_GAME
		ENDIF
	ENDIF
ENDIF
