REM Knight's Quest
REM by DzjeeAr
REM Debugging and modifications: Yohabro@dungeon-keeper.net
REM ---------------------------------------------------------------------------

REM List of changes and corrections:
REM * Mod: An elf and added a few square attributed to the keeper red (the east, near the centre and north near the pond) to claim the entire territory.
REM * Cor: Assigning a FLAG to win. Initially it had killed the knight hero in the zone of action point 15.

REM General settings ----------------------------------------------------------
QUICK_OBJECTIVE(0,"Welcome, keeper. Your task will be a little exordiary this time. A knight novice wishes to get even with the local Grand Lord. Help Chevalier achieve this and he will deliver to you this underground world.",PLAYER0)
START_MONEY(PLAYER0,0)

IF(PLAYER0,KNIGHT == 0)
    LOSE_GAME
ENDIF

SET_CREATURE_STRENGTH(THIEF,20)
SET_CREATURE_HEALTH(KNIGHT,1400)

SET_FLAG(PLAYER0,FLAG0,0)


REM
IF(PLAYER0,MONEY >= 35000)
    QUICK_INFORMATION(5,"Good news, keeper: Spell 'Healing' is available. But be careful, you must have at least 35000 gold to use.")
    NEXT_COMMAND_REUSABLE
    MAGIC_AVAILABLE(PLAYER0,POWER_HEAL_CREATURE,1,1)
ENDIF

IF(PLAYER0,MONEY < 35000)
    NEXT_COMMAND_REUSABLE
    MAGIC_AVAILABLE(PLAYER0,POWER_HEAL_CREATURE,0,0)
ENDIF

IF_ACTION_POINT(1,PLAYER0)
    QUICK_INFORMATION(1,"Good news, Keeper. Useful tool...")
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,2,5,1,0)
ENDIF

IF_ACTION_POINT(3,PLAYER0)
    QUICK_INFORMATION(2,"Stay focused! An enemy squad prepared a set up.")
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,4,7,1,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,4,2,1,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,5,7,2,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,5,3,1,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,6,9,1,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,6,3,1,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,7,10,1,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,7,2,3,0)
ENDIF

IF(PLAYER_GOOD,BILE_DEMON == 0)
    QUICK_INFORMATION(3,"Attention, Keeper! An enemy squad is searching for you...")
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DEMONSPAWN,8,2,1,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DEMONSPAWN,9,3,1,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DEMONSPAWN,10,2,2,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DEMONSPAWN,11,2,1,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DEMONSPAWN,12,3,1,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DEMONSPAWN,13,4,1,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,14,8,1,0)
    IF(PLAYER_GOOD,TOTAL_CREATURES == 0)
        IF_ACTION_POINT(15,PLAYER0)
            QUICK_INFORMATION(4,"The Grand Lord approaches!...")
            ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,10,1,6,50000)
            SET_FLAG(PLAYER0,FLAG0,1)
        ENDIF
    ENDIF
ENDIF

IF(PLAYER0,FLAG0 == 1)
    IF(PLAYER_GOOD,KNIGHT == 0)
        WIN_GAME
    ENDIF
ENDIF
