REM ********************************************
REM Steve Tupper
REM Script for Level 205
REM Dragon Lords
REM ********************************************


REM ************************************
REM ********** SETUP COMMANDS **********
REM ************************************


REM ********** Set up player information **********

REM *** reasonably long delay 1 minute ***
SET_GENERATE_SPEED(720)

REM *** 1=blue 2=green 3=yellow  ***
COMPUTER_PLAYER(PLAYER1,5)
COMPUTER_PLAYER(PLAYER2,4)
COMPUTER_PLAYER(PLAYER3,10)

REM *** money sart with - duh ***
START_MONEY(PLAYER0,10000)
START_MONEY(PLAYER1,20000)
START_MONEY(PLAYER2,5000)
START_MONEY(PLAYER3,10000)

REM *** remember max of 255 in all dungeons on level at any time ***
MAX_CREATURES(PLAYER0,25)
MAX_CREATURES(PLAYER1,20)
MAX_CREATURES(PLAYER2,30)
MAX_CREATURES(PLAYER3,25)

REM *** join forces green and white ***
ALLY_PLAYERS(PLAYER_GOOD,PLAYER2)


REM ********** Set up rooms, traps, doors and magic **********

REM *** rooms available to players also ENTRANCE but don't need here ***
ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(PLAYER2,PRISON,1,0)
ROOM_AVAILABLE(PLAYER3,TORTURE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(PLAYER1,WORKSHOP,1,0)
REM *** White has a temple ***
ROOM_AVAILABLE(PLAYER0,GRAVEYARD,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,BRIDGE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,0)

REM *** spells available to players ***
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CAVE_IN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ARMAGEDDON,1,0)
REM *** White has lightning ***
MAGIC_AVAILABLE(PLAYER1,POWER_PROTECT,1,1)
MAGIC_AVAILABLE(PLAYER3,POWER_CONCEAL,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_DISEASE,1,1)
MAGIC_AVAILABLE(PLAYER2,POWER_CHICKEN,1,1)


REM *** doors available to players ***
DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)

REM *** traps available to players ***
TRAP_AVAILABLE(ALL_PLAYERS,ALARM,1,0)
TRAP_AVAILABLE(PLAYER1,POISON_GAS,1,0)
TRAP_AVAILABLE(PLAYER0,WORD_OF_POWER,1,0)
TRAP_AVAILABLE(PLAYER2,LAVA,1,0)


REM ********** Set up creature information **********

REM *** remember to have enough to cover all players ***
ADD_CREATURE_TO_POOL(DEMONSPAWN,100)


REM *** the 1 field must be in here ***
CREATURE_AVAILABLE(ALL_PLAYERS,DRAGON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SKELETON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,VAMPIRE,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,GHOST,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,HORNY,1,0)

REM *** ? = 0 - 255 ***
SET_CREATURE_STRENGTH(DRAGON,150)

REM *** ? = 0 - 1024 ***
SET_CREATURE_HEALTH(DRAGON,1000)
SET_CREATURE_HEALTH(WIZARD,500)

REM *** ? = 0 - 255 ***
SET_CREATURE_ARMOUR(DRAGON,100)
SET_CREATURE_ARMOUR(WIZARD,100)

REM *** PARTY? can actually be any name in capitals as long as not one used elsewhere eg VAMPYRES but not VAMPIRE ***
CREATE_PARTY(RED)
CREATE_PARTY(BLUE)
CREATE_PARTY(GREEN)
CREATE_PARTY(YELLOW)
CREATE_PARTY(WHITE)

REM *** objective = STEAL_GOLD, STEAL_SPELLS, ATTACK_ENEMIES, ATTACK_DUNGEON_HEART, ATTACK_ROOMS, DEFEND_PARTY ***
    ADD_TO_PARTY(RED,VAMPIRE,5,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(RED,SKELETON,6,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(RED,GHOST,7,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(BLUE,BILE_DEMON,5,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(BLUE,ORC,6,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(BLUE,TROLL,7,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(GREEN,WITCH,5,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(GREEN,GIANT,6,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(GREEN,ARCHER,7,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(WHITE,SAMURAI,5,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(WHITE,MONK,6,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(WHITE,FAIRY,7,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(YELLOW,BARBARIAN,5,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(YELLOW,SORCEROR,6,200,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(YELLOW,THIEF,7,200,ATTACK_DUNGEON_HEART,0)


REM ************************************************
REM ********** CONDITIONS & GAME COMMANDS **********
REM ************************************************

REM *** After half an hour all hell breaks lose! ***
IF(PLAYER0,GAME_TURN > 21600)
    REM *** drops pre defined party at action pt or hero gate (if hero gate then use negative number eg -1 for gate 1) ***
    ADD_PARTY_TO_LEVEL(PLAYER0,RED,1,3)
    ADD_PARTY_TO_LEVEL(PLAYER1,BLUE,4,3)
    ADD_PARTY_TO_LEVEL(PLAYER3,YELLOW,5,3)
    ADD_PARTY_TO_LEVEL(PLAYER2,GREEN,2,3)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,WHITE,3,3)
ENDIF

IF(PLAYER0,GAME_TURN < 50)
QUICK_OBJECTIVE(1,"Rubidia is ruled over by five great Dragon Lords, each with his own powerful dragon mount and special abilities and expertise. You are one of these powerful Lords and find yourself suddenly transported here. Gather your wits together my Lord I sense danger and foul play.",PLAYER0)
ENDIF

IF(PLAYER0,GAME_TURN > 50)
QUICK_INFORMATION(2,"Above you lies Rubidia, now a desolate place due to the Dragon wars, it seems that you have been summoned here by a powerful mage to finally do battle with your counter parts and end the war once and for all")
ENDIF

IF(PLAYER0,GAME_TURN > 100)
QUICK_INFORMATION(3,"You are an evil lord and hold sway over the undead. You are quite wealthy and have mastered the art of pestilance. It would seem that some of your followers are here too, but your legions of dragons alas are not.")
ENDIF
IF(PLAYER0,GAME_TURN > 3650)
    QUICK_INFORMATION(5,"Blue is another evil lord, he is rich and values machines and steel, brute force is his game and has recruited trolls, orcs and demons to his side.")
ENDIF
IF(PLAYER0,GAME_TURN > 7200)
QUICK_INFORMATION(6,"White is the purest of the Lords, he is a fool, poor due to his gifts to the needy. He is however very strong and has been granted the power over lightning by his gods. He has recruited the honourable samurai and other pure races")
ENDIF
IF(PLAYER0,GAME_TURN > 10800)
QUICK_INFORMATION(7,"Green is a nature worshipper, he has recruited the Elves and Giants of the forest of Gilthos to his side. He is poor but take care, he could easily forge an aliance with the other good force here.")
ENDIF
IF(PLAYER0,GAME_TURN > 14400)
    QUICK_INFORMATION(8,"Finally the Yellow Lord is of neutral allegiance. He is of similar power to yourself and has mastered the art of illusion. He is also fond of torture!")
ENDIF


REM ************************************************
REM ********** WIN / LOSE GAME CONDITIONS **********
REM ************************************************

REM *** Win or lose condition ***
IF(PLAYER0,ALL_DUNGEONS_DESTROYED == 1)
    WIN_GAME
ENDIF

IF(PLAYER0,KNIGHT == 0)
    LOSE_GAME
ENDIF
