REM ********************************************
REM Dragon Whelps
REM Script for Level 224
REM Steve Tupper
REM ********************************************


REM ************************************
REM ********** SETUP COMMANDS **********
REM ************************************


REM ********** Set up player information **********

REM *** Number of turns wait for new creature (max 12 turns per second depending on computer speed) ***
SET_GENERATE_SPEED(3600)

REM *** money start with - duh ***
START_MONEY(PLAYER0,90000)

REM *** remember max of 255 in all dungeons on level at any time ***
MAX_CREATURES(PLAYER0,15)


REM ********** Set up rooms, traps, doors and magic **********

REM *** rooms available to players also ENTRANCE but don't need here ***
ROOM_AVAILABLE(PLAYER0,TREASURE,1,1)
ROOM_AVAILABLE(PLAYER0,RESEARCH,1,1)
ROOM_AVAILABLE(PLAYER0,TRAINING,1,0)
ROOM_AVAILABLE(PLAYER0,WORKSHOP,1,0)
ROOM_AVAILABLE(PLAYER0,TEMPLE,1,0)
ROOM_AVAILABLE(PLAYER0,BARRACKS,1,0)
ROOM_AVAILABLE(PLAYER0,GARDEN,1,1)
ROOM_AVAILABLE(PLAYER0,LAIR,1,1)
ROOM_AVAILABLE(PLAYER0,BRIDGE,1,0)
ROOM_AVAILABLE(PLAYER0,GUARD_POST,1,0)


REM *** spells available to players ***
MAGIC_AVAILABLE(PLAYER0,POWER_OBEY,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_CAVE_IN,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_SPEED,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_CHICKEN,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_IMP,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_DISEASE,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_DESTROY_WALLS,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_ARMAGEDDON,1,0)


REM *** doors available to players ***
DOOR_AVAILABLE(PLAYER0,WOOD,0,0)
DOOR_AVAILABLE(PLAYER0,BRACED,0,0)
DOOR_AVAILABLE(PLAYER0,STEEL,0,0)
DOOR_AVAILABLE(PLAYER0,MAGIC,1,0)

REM *** traps available to players ***
TRAP_AVAILABLE(PLAYER0,BOULDER,1,0)
TRAP_AVAILABLE(PLAYER0,POISON_GAS,1,0)
TRAP_AVAILABLE(PLAYER0,LIGHTNING,1,0)
TRAP_AVAILABLE(PLAYER0,ALARM,1,0)
TRAP_AVAILABLE(PLAYER0,WORD_OF_POWER,1,0)



REM ********** Set up creature information **********
ADD_CREATURE_TO_POOL(DEMONSPAWN,5)

CREATURE_AVAILABLE(PLAYER0,DEMONSPAWN,1,1)


REM ************************************************
REM ********** CONDITIONS & GAME COMMANDS **********
REM ************************************************

QUICK_OBJECTIVE(1,"Finally, after being driven from your previous home and after days of searching you have found the perfect place to bring up your litter. Your mate and pups are on their way too. Provide all that they need to reach maturity; nesting, food, gold and fire.",PLAYER0)

IF(PLAYER0,GAME_TURN > 1000)
    QUICK_INFORMATION(2,"Be on the look out for natural, predators, they can smell young dragon whelps for miles")
ENDIF

IF(PLAYER0,GAME_TURN > 7000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SPIDER,4,1,1,200)
ENDIF
IF(PLAYER0,GAME_TURN > 10000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,HELL_HOUND,8,1,1,200)
ENDIF

REM *** BEGIN THE ONSLAUGHT! ***
IF(PLAYER0,GAME_TURN > 15000)
QUICK_INFORMATION(3,"You knew that the peace wouldnt last long - looks like the people from above have heard they have a dragon in the vacinity and have put a price on you and your pup's heads! This time you are determined not be driven out - protect your whelps")
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,1,1,1,100)
ENDIF

IF(PLAYER0,GAME_TURN > 18000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,1,1,2,200)
ENDIF

IF(PLAYER0,GAME_TURN > 21000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SPIDER,3,1,5,0)
ENDIF

IF(PLAYER0,GAME_TURN > 24000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,HELL_HOUND,6,1,5,0)
ENDIF

IF(PLAYER0,GAME_TURN > 29000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,BARBARIAN,1,1,4,100)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DWARFA,1,1,4,100)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,1,1,4,100)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,1,1,4,100)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,1,1,4,100)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WITCH,1,1,4,100)
ENDIF

IF(PLAYER0,GAME_TURN > 32000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,1,1,3,300)
ENDIF

IF(PLAYER0,GAME_TURN > 35000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,1,1,4,400)
ENDIF

IF(PLAYER0,GAME_TURN > 38000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,1,1,5,500)
ENDIF

IF(PLAYER0,GAME_TURN > 43000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,1,1,6,600)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SPIDER,5,1,8,0)
ENDIF

IF(PLAYER0,GAME_TURN > 47000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,1,1,7,700)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,HELL_HOUND,9,1,8,0)
ENDIF

IF(PLAYER0,GAME_TURN > 52000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,1,1,8,800)
ENDIF

IF(PLAYER0,GAME_TURN > 56000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,1,1,9,900)
ENDIF

IF(PLAYER0,GAME_TURN > 57000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SPIDER,2,1,10,0)
ENDIF

IF(PLAYER0,GAME_TURN > 59000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,HELL_HOUND,7,1,10,0)
ENDIF

IF(PLAYER0,GAME_TURN > 65000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,1,1,10,1000)
ENDIF

IF(PLAYER0,GAME_TURN > 72000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,AVATAR,1,1,5,10000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,HELL_HOUND,8,2,10,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SPIDER,4,5,10,0)
ENDIF

IF(PLAYER0,GAME_TURN > 80000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SPIDER,4,5,10,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SPIDER,6,5,10,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SPIDER,8,5,10,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SPIDER,2,5,10,0)
ENDIF

IF(PLAYER0,GAME_TURN > 85000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,HELL_HOUND,3,3,10,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,HELL_HOUND,5,2,10,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,HELL_HOUND,7,3,10,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,HELL_HOUND,9,2,10,0)
ENDIF

IF(PLAYER0,GAME_TURN > 95000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,AVATAR,1,1,10,10000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,8,2,10,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,4,1,10,0)
ENDIF


IF_ACTION_POINT(10,PLAYER0)
    QUICK_INFORMATION(4,"This level was made for Clare")
ENDIF


REM ************************************************
REM ********** WIN / LOSE GAME CONDITIONS **********
REM ************************************************

REM *** Win or lose condition ***
NEXT_COMMAND_REUSABLE
IF(PLAYER0,GAME_TURN >= 96000)
    NEXT_COMMAND_REUSABLE
    IF(PLAYER_GOOD,TOTAL_CREATURES == 0)
        WIN_GAME
    ENDIF
ENDIF
NEXT_COMMAND_REUSABLE
IF(PLAYER0,TOTAL_CREATURES < 3)
    LOSE_GAME
ENDIF
