REM ********************************************
REM
REM Unsettled Fortress
REM
REM ********************************************

SET_GENERATE_SPEED(400)
MAX_CREATURES(PLAYER0,35)
START_MONEY(PLAYER0,5000)

ADD_CREATURE_TO_POOL(BUG,50)
ADD_CREATURE_TO_POOL(FLY,35)
ADD_CREATURE_TO_POOL(SPIDER,75)
ADD_CREATURE_TO_POOL(TROLL,50)

CREATURE_AVAILABLE(PLAYER0,FLY,1,1)
CREATURE_AVAILABLE(PLAYER0,BUG,1,1)
CREATURE_AVAILABLE(PLAYER0,SPIDER,1,1)
CREATURE_AVAILABLE(PLAYER0,TROLL,1,1)

ROOM_AVAILABLE(PLAYER0,TREASURE,1,1)
ROOM_AVAILABLE(PLAYER0,LAIR,1,1)
ROOM_AVAILABLE(PLAYER0,GARDEN,1,1)
ROOM_AVAILABLE(PLAYER0,TRAINING,1,1)
ROOM_AVAILABLE(PLAYER0,RESEARCH,1,1)
ROOM_AVAILABLE(PLAYER0,WORKSHOP,1,0)
ROOM_AVAILABLE(PLAYER0,GUARD_POST,1,0)
ROOM_AVAILABLE(PLAYER0,TORTURE,1,0)
ROOM_AVAILABLE(PLAYER0,BARRACKS,1,0)

MAGIC_AVAILABLE(PLAYER0,POWER_HAND,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_SLAP,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_DISEASE,1,0)

DOOR_AVAILABLE(PLAYER0,STEEL,1,0)
DOOR_AVAILABLE(PLAYER0,MAGIC,1,0)

TRAP_AVAILABLE(PLAYER0,ALARM,1,0)
TRAP_AVAILABLE(PLAYER0,POISON_GAS,1,0)
TRAP_AVAILABLE(PLAYER0,WORD_OF_POWER,1,0)
TRAP_AVAILABLE(PLAYER0,LAVA,1,0)

REM Armageddon patron troops
CREATE_PARTY(GUARDIANS)
    ADD_TO_PARTY(GUARDIANS,WIZARD,5,200,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(GUARDIANS,FAIRY,5,100,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(GUARDIANS,GIANT,5,100,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(GUARDIANS,MONK,7,200,DEFEND_PARTY,0)
    ADD_TO_PARTY(GUARDIANS,SAMURAI,5,300,ATTACK_ENEMIES,0)

REM Enemy covering force
CREATE_PARTY(ONE)
    ADD_TO_PARTY(ONE,ARCHER,5,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(ONE,BARBARIAN,5,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(ONE,GIANT,5,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(ONE,HELL_HOUND,6,600,ATTACK_ROOMS,0)

REM Enemy troop reinforcements
CREATE_PARTY(TWO)
    ADD_TO_PARTY(TWO,WIZARD,5,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(TWO,SAMURAI,5,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(TWO,THIEF,5,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(TWO,MONK,6,500,DEFEND_PARTY,0)
    ADD_TO_PARTY(TWO,DRAGON,6,600,ATTACK_ENEMIES,0)

REM The enemy troop reinforcements 2
CREATE_PARTY(THREE)
    ADD_TO_PARTY(THREE,WIZARD,5,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(THREE,FAIRY,6,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(THREE,FAIRY,6,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(THREE,MONK,6,500,DEFEND_PARTY,0)
    ADD_TO_PARTY(THREE,WITCH,7,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(THREE,SKELETON,8,1000,ATTACK_ENEMIES,0)

REM Weak enemy's Army
CREATE_PARTY(FOUR)
    ADD_TO_PARTY(FOUR,BARBARIAN,3,250,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(FOUR,ARCHER,3,250,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(FOUR,THIEF,3,250,ATTACK_ENEMIES,0)

REM The weak enemy's Army 2
CREATE_PARTY(FIVE)
    ADD_TO_PARTY(FIVE,GIANT,3,250,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(FIVE,SAMURAI,3,250,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(FIVE,MONK,3,250,ATTACK_ENEMIES,0)

REM The weak enemy's Army 3
CREATE_PARTY(SIX)
    ADD_TO_PARTY(SIX,WITCH,3,250,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(SIX,FAIRY,3,250,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(SIX,DWARFA,3,250,ATTACK_ENEMIES,0)

REM More than 100,000 dug gold mine during the emergence of the enemy
IF(PLAYER0,TOTAL_GOLD_MINED >= 150000)
    SET_TIMER(PLAYER0,TIMER1)
ENDIF

IF(PLAYER0,TIMER1 >= 2000)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,FOUR,-1,DUNGEON,0,9,50)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,FIVE,-2,DUNGEON,0,9,50)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,SIX,-3,DUNGEON,0,9,50)
ENDIF

REM Bailout switch (research to enable the bridge jewelry = T.)
IF_ACTION_POINT(1,PLAYER0)
    ROOM_AVAILABLE(PLAYER0,BRIDGE,1,0)
ENDIF

REM Armageddon patron summoned troops
IF_ACTION_POINT(2,PLAYER0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GUARDIANS,2,2)
ENDIF

REM Messages discovered fortress door
REM IF_ACTION_POINT(3,PLAYER0)
REM DISPLAY_INFORMATION(1,PLAYER0)
REM ENDIF

REM Allow the enemy to Temple study
IF(PLAYER_GOOD,TENTACLE == 0)
    ROOM_AVAILABLE(PLAYER0,TEMPLE,1,0)
ENDIF

REM Relief emergence of enemy troops and start the timer
IF_ACTION_POINT(4,PLAYER0)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ONE,-1,DUNGEON,0,8,50)
    SET_TIMER(PLAYER0,TIMER0)
ENDIF

REM Enemy reinforcements
IF(PLAYER0,TIMER0 >= 500)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TWO,-2,DUNGEON,0,9,50)
ENDIF

REM The enemy reinforcements 2
IF(PLAYER0,TIMER0 >= 1000)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,THREE,-3,DUNGEON,0,9,50)
    SET_FLAG(PLAYER0,FLAG0,1)
ENDIF

REM The enemy troop reinforcements after 2 sortie, skeleton research to enable prison
IF(PLAYER0,FLAG0 == 1)
    IF(PLAYER_GOOD,SKELETON == 0)
        ROOM_AVAILABLE(PLAYER0,PRISON,1,0)
    ENDIF
ENDIF

REM Annihilate the enemy, he'll clear

IF(PLAYER_GOOD,TOTAL_CREATURES == 0)
    WIN_GAME
ENDIF

REM Defeat on annihilation on all players Imps
IF(PLAYER0,TOTAL_IMPS == 0)
    LOSE_GAME
ENDIF
