REM Script for Level 214	(Gang de Nowel)

REM Requires changing creature.txt and dd1creat.txt ("Snowball" mod)
REM Creatures changed: Wiz, Barb, Knight, Giant, Thief, HR, Skel, Troll, Demo, Sorce, Bile, Imp, Ghost /!\, Tentacle, Orc.

REM ---------BASE------------

SET_GENERATE_SPEED(150)

SET_CREATURE_MAX_LEVEL(PLAYER0,DEMONSPAWN,10)

MAX_CREATURES(PLAYER0,30)

START_MONEY(PLAYER0,35000)

ADD_CREATURE_TO_POOL(BILE_DEMON,10)
ADD_CREATURE_TO_POOL(TROLL,15)
ADD_CREATURE_TO_POOL(DEMONSPAWN,10)
ADD_CREATURE_TO_POOL(SORCEROR,15)
ADD_CREATURE_TO_POOL(ORC,10)
ADD_CREATURE_TO_POOL(TENTACLE,10)

CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,TENTACLE,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,ORC,1,1)

ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,PRISON,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,BRIDGE,1,1)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)

DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,ALARM,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)

REM -------------EVENTS-------------

SET_TIMER(PLAYER0,TIMER0)

IF(PLAYER0,TIMER0 >= 1)
QUICK_OBJECTIVE(1,"You are facing a cruel dilemma, Keeper. The Lord Mentalow is a cheerful buffoon who spends his days celebrating with his people. Snow lies constantly on its territory and surplus, it has horribly beneficial properties. It is loaded with antimagic. As a result, you and your creatures can't launch spells. You will have to find a good method for this...",PLAYER0)
ENDIF

IF(PLAYER0,TIMER0 >= 200)
QUICK_INFORMATION(2,"Although Mentalow pass most of every day and night on party, it has no less a fairly consistent army; even tax inspectors never dare to approach them. Be the first to tax their enormous wealth!")
ENDIF

IF(PLAYER0,BATTLES_WON >= 10)
    QUICK_INFORMATION(3,"The Lord Mentalow wants to write a history without you... Should I send him swear words, to let him know our intentions?")
ENDIF

IF(PLAYER0,BATTLES_WON >= 2)
    QUICK_INFORMATION(4,"Conflicts have started, but apparently, your creatures have found the method. A snowball battle... at least, they would enjoy it!")
    CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,1)
ENDIF

IF(PLAYER0,BILE_DEMON == 1)
    QUICK_INFORMATION(5,"The Bile Demon is also the party! Apparently, he small balls won't make ane effect on him...")
ENDIF

IF(PLAYER0,TROLL > 4)
    IF(PLAYER0,BILE_DEMON > 1)
QUICK_INFORMATION(6,"Jealous of the Bile Demons which make larger balls with ease, your trolls have adopted another technique... Go have a look in the workshop!")
        TRAP_AVAILABLE(ALL_PLAYERS,BOULDER,1,3)
    ENDIF
ENDIF

REM -------------------------------------EVENT NEIGE-----------------------

IF(PLAYER0,TIMER0 >= 30000)
QUICK_INFORMATION(7,"Let's play a little game, Keeper! The forces Mentalow overwhelm you if you're not prepared. A creature is waiting for you WEST here. Make him cross the trail to reach the other side: a surprise is waiting for you! Be careful not to make it stuck...")
    ADD_CREATURE_TO_LEVEL(PLAYER0,IMP,7,1,7,0)
ENDIF

IF_ACTION_POINT(8,PLAYER0)
QUICK_INFORMATION(8,"Good work, Keeper! Your perseverance allowed you to recall three ghosts to life. As immaterial, the ghosts will have the unfortunate habit of influencing material world if enemies are near.")
    ADD_CREATURE_TO_LEVEL(PLAYER0,GHOST,9,1,7,0)
    ADD_CREATURE_TO_LEVEL(PLAYER0,GHOST,10,1,7,0)
    ADD_CREATURE_TO_LEVEL(PLAYER0,GHOST,11,1,7,0)
ENDIF

REM -----------------------------------GEMMES-------------------------------

IF_ACTION_POINT(4,PLAYER0)
QUICK_INFORMATION(9,"STOP! Watch out, Guard! Your greed may lost you! These gems are only gold cleverly concealed. If you approach them, heroes ambush will not hesitate to kill you. You will have to accelerate to be able to run out with gold.")
ENDIF

IF_ACTION_POINT(5,PLAYER0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,6,5,7,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,6,5,7,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,BARBARIAN,6,5,7,0)
ENDIF

REM ----------------------------NOWEL----------------------------------------

IF_ACTION_POINT(2,PLAYER0)
    QUICK_INFORMATION(10,"Merry Christmas, Keeper!")
    SET_TIMER(PLAYER0,TIMER1)
ENDIF

IF(PLAYER0,TIMER1 >= 200)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,IMP,2,7,1,10000)
ENDIF

REM --------------------------------------------------------------------------

IF(PLAYER0,TIMER0 >= 500)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,1,5,2,2500)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,1,3,4,7500)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,1,1,5,10000)
ENDIF

IF_ACTION_POINT(12,PLAYER0)
    QUICK_INFORMATION(11,"This is the entrance to the Chateau of Lord Mentalow. Do not hesitate to use any means; for your own personal pleasure, of course!")
ENDIF

IF(PLAYER0,SPELLS_STOLEN == 1)
    QUICK_INFORMATION(12,"It seems that some magic books were stolen. Further research is needed!")
ENDIF

REM -----------------------------------WIN-------------------------------------

IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
QUICK_OBJECTIVE(13,"This is a good thing done! The Lord Mentalow will not celebrate any longer! Still, I hope you've taken a bit of fun...",PLAYER0)
    WIN_GAME
ENDIF

REM -----------------------------------LOSE-------------------------------------

IF(PLAYER0,IMP == 0)
    QUICK_OBJECTIVE(14,"You've lost all your Imps, keeper. I do not think you can still do something useful...",PLAYER0)
    LOSE_GAME
ENDIF
