REM Script for Level 214	(Gang de Nowel)

REM Ncessite la modification de creature.txt et dd1creat.txt (Mod "Boule de neige")
REM Cratures modifies : Wiz, Barb, Knight, Giant, Thief, HR, Skel, Troll, Demo, Sorce, Bile, Imp, Ghost/!\, Tentacle, Orc.

REM ---------BASE------------

SET_GENERATE_SPEED(150)

SET_CREATURE_MAX_LEVEL(PLAYER0,DEMONSPAWN,10)

MAX_CREATURES(PLAYER0,30)

START_MONEY(PLAYER0,35000)

ADD_CREATURE_TO_POOL(BILE_DEMON,10)
ADD_CREATURE_TO_POOL(TROLL,15)
ADD_CREATURE_TO_POOL(DEMONSPAWN,10)
ADD_CREATURE_TO_POOL(SORCEROR,15)
ADD_CREATURE_TO_POOL(ORC,10)
ADD_CREATURE_TO_POOL(TENTACLE,10)

CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,TENTACLE,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,ORC,1,1)

ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,PRISON,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,BRIDGE,1,1)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)

DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,ALARM,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)

REM -------------EVENTS-------------

SET_TIMER(PLAYER0,TIMER0)

IF(PLAYER0,TIMER0 >= 1)
QUICK_OBJECTIVE(1,"Vous voici face  un cruel dilemne, Gardien! Le Seigneur Mentalow est un bouffon joyeux passant ses journes  faire  festoyer avec son peuple. La neige tombe constamment sur son territoire et en surplus, celle-ci possde des proprits horriblement bnfiques. Elle est charge en antimagie. De ce fait, vous et vos cratures ne pouvez lancer de sortilges. Il va vous falloir trouver une mthode bien  vous...",PLAYER0)
ENDIF

IF(PLAYER0,TIMER0 >= 200)
QUICK_INFORMATION(2,"Bien que Mentalow passe le plus grand de son temps  faire la fte, il en a pas moins une arme assez concquente, dont mme les inspecteurs des impts n'osent l'approcher. Soyez le premier  lui taxer ses normes richesses!")
ENDIF

IF(PLAYER0,BATTLES_WON >= 10)
    QUICK_INFORMATION(3,"Le Seigneur Mentalow vous demande de vous rendre sans histoire... Dois-je lui envoyer des gros mots, histoire de lui faire connaitre nos intentions?")
ENDIF

IF(PLAYER0,BATTLES_WON >= 2)
    QUICK_INFORMATION(4,"Les conflits ont dbuts, mais apparamment, vos cratures ont trouv la mthode. Une bataille de boule de neige... Au moins, elles prennent du plaisir!")
    CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,1)
ENDIF

IF(PLAYER0,BILE_DEMON == 1)
    QUICK_INFORMATION(5,"Le dmon bilieux se met aussi de la partie! Apparamment, il ne compte pas lancer que des petites boules lui...")
ENDIF

IF(PLAYER0,TROLL > 4)
    IF(PLAYER0,BILE_DEMON > 1)
QUICK_INFORMATION(6,"Jaloux de la facilit dont vos dmons bilieux font les plus grosses boules, vos trolls ont adopt une autre technique... Allez jeter un oeil dans l'atelier!")
        TRAP_AVAILABLE(ALL_PLAYERS,BOULDER,1,3)
    ENDIF
ENDIF

REM -------------------------------------EVENT NEIGE-----------------------

IF(PLAYER0,TIMER0 >= 30000)
QUICK_INFORMATION(7,"Jouons  un petit jeu, Gardien! Les forces de Mentalow vous submergeront si vous n'tes pas prpar. Une crature vous attend a l'OUEST d'ici. Faites lui traverser le parcours pour atteindre l'autre rive: une surprise vous y attend! Faites attention quand mme  ce qu'elle ne reste pas coince...")
    ADD_CREATURE_TO_LEVEL(PLAYER0,IMP,7,1,7,0)
ENDIF

IF_ACTION_POINT(8,PLAYER0)
QUICK_INFORMATION(8,"Bon travail, Gardien! Votre persvrance vous a permis de rappeler trois fantmes  la vie. Etant immatriels, les fantmes auront la fcheuse habitude de renvoyer les choses matriels sur leurs ennemis.")
    ADD_CREATURE_TO_LEVEL(PLAYER0,GHOST,9,1,7,0)
    ADD_CREATURE_TO_LEVEL(PLAYER0,GHOST,10,1,7,0)
    ADD_CREATURE_TO_LEVEL(PLAYER0,GHOST,11,1,7,0)
ENDIF

REM -----------------------------------GEMMES-------------------------------

IF_ACTION_POINT(4,PLAYER0)
QUICK_INFORMATION(9,"STOP! Arrtez-vous, Gardien! Votre avidit risque de vous perdre! Ces gemmes ne sont que de l'or habilement cach. Si vous vous en approchez trop, des hros en embuscade n'hsiteront pas  vous massacrer. Il va vous falloir acclrer avant d'tre  cours d'or.")
ENDIF

IF_ACTION_POINT(5,PLAYER0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,6,5,7,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,6,5,7,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,BARBARIAN,6,5,7,0)
ENDIF

REM ----------------------------NOWEL----------------------------------------

IF_ACTION_POINT(2,PLAYER0)
    QUICK_INFORMATION(10,"Joyeux Nol, Gardien!")
    SET_TIMER(PLAYER0,TIMER1)
ENDIF

IF(PLAYER0,TIMER1 >= 200)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,IMP,2,7,1,10000)
ENDIF

REM --------------------------------------------------------------------------

IF(PLAYER0,TIMER0 >= 500)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,1,5,2,2500)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,1,3,4,7500)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,1,1,5,10000)
ENDIF

IF_ACTION_POINT(12,PLAYER0)
    QUICK_INFORMATION(11,"Voil l'entre du Chteau du Seigneur Mentalow. N'hsitez pas  tout casser, pour votre propre plaisir personnel, bien sr!")
ENDIF

IF(PLAYER0,SPELLS_STOLEN == 1)
    QUICK_INFORMATION(12,"Il semblerait que certains livres magiques fonctionnent ici. Une recherche plus pousse s'impose!")
ENDIF

REM -----------------------------------WIN-------------------------------------

IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
QUICK_OBJECTIVE(13,"Voil une bonne chose de faite! Le Seigneur Mentalow ne pourra pas festoyer avant longtemps! J'espre que vous y avez pris un peu de plaisir tout de mme...",PLAYER0)
    WIN_GAME
ENDIF

REM -----------------------------------LOSE-------------------------------------

IF(PLAYER0,IMP == 0)
    QUICK_OBJECTIVE(14,"Vous n'avez plus de lutins, Gardien. Je ne pense pas que vous pouvez encore faire quelque chose d'utile...",PLAYER0)
    LOSE_GAME
ENDIF
