REM Triload
REM ####### REALM #######
REM Level by Oetelaer

SET_GENERATE_SPEED(500)

MAX_CREATURES(PLAYER0,22)
MAX_CREATURES(PLAYER1,34)
MAX_CREATURES(PLAYER2,34)


START_MONEY(PLAYER0,2500)
START_MONEY(PLAYER1,100000)
START_MONEY(PLAYER2,100000)
START_MONEY(PLAYER_GOOD,9999999)

ALLY_PLAYERS(PLAYER_GOOD,PLAYER1)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER2)

COMPUTER_PLAYER(PLAYER_GOOD,1)
COMPUTER_PLAYER(PLAYER1,0)
COMPUTER_PLAYER(PLAYER2,0)

SET_COMPUTER_PROCESS(PLAYER1,"DIG TO CLOSE GOLD",0,25000,500,3,47)
SET_COMPUTER_PROCESS(PLAYER2,"DIG TO CLOSE GOLD",0,25000,500,3,47)

REM SET_CREATURE_STRENGTH([creature],[a])
REM SET_CREATURE_HEALTH([creature],[a])
REM SET_CREATURE_ARMOUR([creature],[a])
REM SET_CREATURE_FEAR([creature],[a])


REM ####### POOL #######


ADD_CREATURE_TO_POOL(FLY,5)
ADD_CREATURE_TO_POOL(BUG,25)
ADD_CREATURE_TO_POOL(SPIDER,25)
ADD_CREATURE_TO_POOL(DEMONSPAWN,10)
ADD_CREATURE_TO_POOL(SORCEROR,25)
ADD_CREATURE_TO_POOL(BILE_DEMON,30)
ADD_CREATURE_TO_POOL(DRAGON,25)
ADD_CREATURE_TO_POOL(TROLL,8)
ADD_CREATURE_TO_POOL(ORC,25)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,34)
ADD_CREATURE_TO_POOL(SKELETON,5)
ADD_CREATURE_TO_POOL(GHOST,2)
ADD_CREATURE_TO_POOL(HELL_HOUND,34)
ADD_CREATURE_TO_POOL(VAMPIRE,25)
ADD_CREATURE_TO_POOL(HORNY,3)


REM ####### MONSTERS #######
REM PLAYER0


CREATURE_AVAILABLE(PLAYER1,FLY,1,1)
CREATURE_AVAILABLE(PLAYER2,FLY,1,1)
CREATURE_AVAILABLE(PLAYER0,BUG,1,1)
CREATURE_AVAILABLE(PLAYER0,SPIDER,1,1)
CREATURE_AVAILABLE(PLAYER0,DEMONSPAWN,1,1)
CREATURE_AVAILABLE(PLAYER1,SORCEROR,1,1)
CREATURE_AVAILABLE(PLAYER2,BILE_DEMON,1,1)
CREATURE_AVAILABLE(PLAYER0,DRAGON,1,1)
CREATURE_AVAILABLE(PLAYER1,TROLL,1,1)
CREATURE_AVAILABLE(PLAYER2,ORC,1,1)
CREATURE_AVAILABLE(PLAYER0,DARK_MISTRESS,1,1)
CREATURE_AVAILABLE(PLAYER1,SKELETON,1,1)
CREATURE_AVAILABLE(PLAYER2,GHOST,1,1)
CREATURE_AVAILABLE(PLAYER0,HELL_HOUND,1,1)
CREATURE_AVAILABLE(PLAYER1,VAMPIRE,1,1)
CREATURE_AVAILABLE(PLAYER0,HORNY,1,1)


REM ####### ROOMS #######
REM PLAYER0

ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(PLAYER0,BRIDGE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(PLAYER1,PRISON,1,0)
ROOM_AVAILABLE(PLAYER2,PRISON,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,0)
ROOM_AVAILABLE(PLAYER1,TEMPLE,1,0)
ROOM_AVAILABLE(PLAYER2,TEMPLE,1,0)
ROOM_AVAILABLE(PLAYER1,GRAVEYARD,1,0)
ROOM_AVAILABLE(PLAYER2,GRAVEYARD,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,SCAVENGER,1,0)

REM ####### SPELLS #######
REM PLAYER0

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_IMP,1,1)
MAGIC_AVAILABLE(PLAYER1,POWER_IMP,1,1)
MAGIC_AVAILABLE(PLAYER2,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)


REM ####### WORKSHOP #######

DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(PLAYER0,STEEL,1,0)
DOOR_AVAILABLE(PLAYER1,STEEL,1,12)
DOOR_AVAILABLE(PLAYER2,STEEL,1,5)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,BOULDER,1,0)


REM ####### PARTIES #######

REM FOR TUNNELLER PARTIES 6 CREATURES, NOT 7
REM WIZARDBARBARIANARCHERMONKDWARFAKNIGHTAVATARTUNNELLERWITCHGIANTFAIRYTHIEFSAMURAI
REM IMPHORNYSKELETONTROLLDRAGONDEMONSPAWNFLYDARK_MISTRESSSORCERORBILE_DEMONBUGVAMPIRESPIDERHELL_HOUNDGHOSTTENTACLEORC

CREATE_PARTY(TUNNEL)
    ADD_TO_PARTY(TUNNEL,DWARFA,10,400,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(TUNNEL,BARBARIAN,8,400,DEFEND_PARTY,0)
    ADD_TO_PARTY(TUNNEL,BARBARIAN,8,400,DEFEND_PARTY,0)
    ADD_TO_PARTY(TUNNEL,BARBARIAN,8,400,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(TUNNEL,WIZARD,7,800,DEFEND_PARTY,0)
    ADD_TO_PARTY(TUNNEL,WIZARD,7,800,DEFEND_PARTY,0)

CREATE_PARTY(CHORONZON)
    ADD_TO_PARTY(CHORONZON,SAMURAI,6,100,DEFEND_PARTY,0)
    ADD_TO_PARTY(CHORONZON,SAMURAI,6,100,DEFEND_PARTY,0)
    ADD_TO_PARTY(CHORONZON,SAMURAI,7,120,DEFEND_PARTY,0)
    ADD_TO_PARTY(CHORONZON,SAMURAI,7,120,DEFEND_PARTY,0)
    ADD_TO_PARTY(CHORONZON,SAMURAI,9,240,DEFEND_PARTY,0)
    ADD_TO_PARTY(CHORONZON,SAMURAI,9,240,DEFEND_PARTY,0)
    ADD_TO_PARTY(CHORONZON,SAMURAI,10,600,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(FAIRIES)
    ADD_TO_PARTY(FAIRIES,FAIRY,4,80,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(FAIRIES,FAIRY,8,160,DEFEND_PARTY,0)
    ADD_TO_PARTY(FAIRIES,FAIRY,8,160,DEFEND_PARTY,0)
    ADD_TO_PARTY(FAIRIES,FAIRY,8,160,DEFEND_PARTY,0)
    ADD_TO_PARTY(FAIRIES,FAIRY,10,240,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(ARCHERS)
    ADD_TO_PARTY(ARCHERS,ARCHER,7,400,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(ARCHERS,ARCHER,8,400,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(ARCHERS,ARCHER,9,400,ATTACK_ENEMIES,0)


CREATE_PARTY(SATAARAN)
    ADD_TO_PARTY(SATAARAN,THIEF,8,200,STEAL_GOLD,0)
    ADD_TO_PARTY(SATAARAN,THIEF,8,200,STEAL_SPELLS,0)

REM ####### OCCURENCES #######


REM ADD_CREATURE_TO_LEVEL(PLAYER?,[MONSTER],AP,[AMOUNT],[EXP LEVEL],[MONEY])
REM ADD_TUNNELLER_PARTY_TO_LEVEL([player],[party name],[action point],[head for],[action point/target player],[experience],[gold])
REM ADD_TUNNELLER_TO_LEVEL([player],[action point],[head for],[action point/target player],[experience],[gold])
REM ADD_PARTY_TO_LEVEL(PLAYER?,[party name],[action point],[COPIES])
REM SET_TIMER(PLAYER0,TIMER0)
REM DISPLAY_OBJECTIVE(DATA.TXT_NR,PLAYER0)
REM DISPLAY_INFORMATION(DATA.TXT_NR,PLAYER0)


IF(PLAYER0,TOTAL_CREATURES > 21)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TUNNEL,-4,DUNGEON,0,2,100)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TUNNEL,-5,DUNGEON,0,2,100)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRIES,2,1)
ENDIF

IF(PLAYER0,BRIDGE > 0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRIES,2,1)
ENDIF

IF(PLAYER1,BRIDGE > 0)
    ROOM_AVAILABLE(PLAYER1,BRIDGE,1,1)
ENDIF

IF(PLAYER2,BRIDGE > 0)
    ROOM_AVAILABLE(PLAYER2,BRIDGE,1,1)
ENDIF

IF(PLAYER0,PRISON > 0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHORONZON,-4,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHORONZON,-5,1)
    ROOM_AVAILABLE(PLAYER0,PRISON,1,1)
ENDIF

IF(PLAYER0,TEMPLE > 0)
    ROOM_AVAILABLE(PLAYER0,TEMPLE,1,1)
ENDIF


IF(PLAYER0,GRAVEYARD > 0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TUNNEL,-4,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TUNNEL,-5,1)
    ROOM_AVAILABLE(PLAYER0,GRAVEYARD,1,1)
ENDIF




REM MONEY GAME_TURN TOTAL_IMPS TOTAL_CREATURES TOTAL_RESEARCH TOTAL_DOORS TOTAL_AREA TOTAL_CREATURES_LEFT CREATURES_ANNOYED BATTLES_WON BATTLES_LOST ROOMS_DESTROYED SPELLS_STOLEN TIMES_BROKEN_INTO DUNGEON_DESTROYED CREATURES_SCAVENGED_LOST CREATURES_SCAVENGED_GAINED ALL_DUNGEONS_DESTROYED
REM == | != | > | < | <= | >=


IF_ACTION_POINT(2,PLAYER0)
    MAGIC_AVAILABLE(PLAYER_GOOD,POWER_LIGHTNING,1,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ARCHERS,-1,2)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SATAARAN,-4,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SATAARAN,-5,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHORONZON,-2,1)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,3,2,10,800)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,4,1,10,800)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,-3,1,10,800)
    SET_TIMER(PLAYER0,TIMER0)
ENDIF

IF(PLAYER0,TIMER0 >= 4181)
    MAGIC_AVAILABLE(PLAYER_GOOD,POWER_SPEED,1,1)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,4,5,8,800)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SATAARAN,-4,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SATAARAN,-5,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHORONZON,-3,1)
ENDIF

IF_ACTION_POINT(4,PLAYER0)
    MAGIC_AVAILABLE(PLAYER_GOOD,POWER_CALL_TO_ARMS,1,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHORONZON,1,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ARCHERS,1,1)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TUNNEL,1,DUNGEON,0,2,100)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRIES,1,1)
ENDIF

IF_ACTION_POINT(5,PLAYER0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHORONZON,-3,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SATAARAN,-4,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SATAARAN,-5,1)
ENDIF

IF_ACTION_POINT(6,PLAYER0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHORONZON,-3,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SATAARAN,-4,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SATAARAN,-5,1)
ENDIF

IF_ACTION_POINT(1,PLAYER0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHORONZON,-3,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SATAARAN,-4,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SATAARAN,-5,1)
ENDIF


REM ####### CLIMAX #######

IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,-3,1,10,800)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,-3,1,10,800)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,AVATAR,-3,1,10,800)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SATAARAN,-4,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SATAARAN,-5,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHORONZON,-3,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TUNNEL,4,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRIES,5,1)
ENDIF

IF(PLAYER1,DUNGEON_DESTROYED == 1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRIES,2,1)
    IF(PLAYER2,DUNGEON_DESTROYED == 1)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRIES,2,1)
        IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
            IF(PLAYER_GOOD,TOTAL_CREATURES == 0)
                WIN_GAME
            ENDIF
        ENDIF
    ENDIF
ENDIF
