REM ANOTHER DUNGEON LEVEL7
REM EBbVxC`킵̖`

REM *** SETUP_SECTION ***

SET_GENERATE_SPEED(650)

MAX_CREATURES(PLAYER0, 15)
MAX_CREATURES(PLAYER3, 30)

START_MONEY(PLAYER0, 8000)
START_MONEY(PLAYER3, 20000)

COMPUTER_PLAYER(PLAYER3, 0)

ADD_CREATURE_TO_POOL(BUG, 20)
ADD_CREATURE_TO_POOL(BILE_DEMON, 12)
ADD_CREATURE_TO_POOL(SORCEROR, 20)
ADD_CREATURE_TO_POOL(TROLL, 20)
ADD_CREATURE_TO_POOL(SPIDER, 12)
ADD_CREATURE_TO_POOL(DARK_MISTRESS, 14)
ADD_CREATURE_TO_POOL(DRAGON, 15)
ADD_CREATURE_TO_POOL(HELL_HOUND, 20)
ADD_CREATURE_TO_POOL(TENTACLE, 20)
ADD_CREATURE_TO_POOL(VAMPIRE, 2)
ADD_CREATURE_TO_POOL(ORC, 15)

CREATURE_AVAILABLE(ALL_PLAYERS, DRAGON, 1, 1)
CREATURE_AVAILABLE(ALL_PLAYERS, SPIDER, 1, 1)
CREATURE_AVAILABLE(ALL_PLAYERS, BILE_DEMON, 1, 1)
CREATURE_AVAILABLE(ALL_PLAYERS, DARK_MISTRESS, 1, 1)
CREATURE_AVAILABLE(ALL_PLAYERS, ORC, 1, 1)
CREATURE_AVAILABLE(PLAYER0, BUG, 1, 1)
CREATURE_AVAILABLE(PLAYER0, TROLL, 1, 1)
CREATURE_AVAILABLE(PLAYER0, SORCEROR, 1, 1)
CREATURE_AVAILABLE(PLAYER0, TENTACLE, 1, 1)
CREATURE_AVAILABLE(PLAYER0, HELL_HOUND, 1, 1)

MAGIC_AVAILABLE(ALL_PLAYERS, POWER_IMP, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_CONCEAL, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SIGHT, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_HOLD_AUDIENCE, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SPEED, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_HEAL_CREATURE, 1, 0)
MAGIC_AVAILABLE(PLAYER0, POWER_CALL_TO_ARMS, 1, 0)
MAGIC_AVAILABLE(PLAYER0, POWER_DISEASE, 1, 0)
MAGIC_AVAILABLE(PLAYER3, POWER_PROTECT, 1, 0)
MAGIC_AVAILABLE(PLAYER3, POWER_CHICKEN, 1, 1)

ROOM_AVAILABLE(ALL_PLAYERS, TREASURE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, LAIR, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GARDEN, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, RESEARCH, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TRAINING, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, BARRACKS, 1, 0)
ROOM_AVAILABLE(ALL_PLAYERS, WORKSHOP, 1, 0)
ROOM_AVAILABLE(ALL_PLAYERS, TORTURE, 1, 0)
ROOM_AVAILABLE(PLAYER0, SCAVENGER, 1, 0)
ROOM_AVAILABLE(PLAYER3, TEMPLE, 1, 0)

TRAP_AVAILABLE(PLAYER0, ALARM, 1, 0)
TRAP_AVAILABLE(PLAYER3, POISON_GAS, 1, 0)
TRAP_AVAILABLE(PLAYER3, WORD_OF_POWER, 1, 0)

DOOR_AVAILABLE(PLAYER3, WOOD, 1, 0)

SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, IMP, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, BUG, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, SPIDER, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, BILE_DEMON, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, DRAGON, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, SORCEROR, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, DARK_MISTRESS, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, TROLL, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, ORC, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, GHOST, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, HELL_HOUND, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, VAMPIRE, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, TENTACLE, 5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, HORNY, 5)
SET_CREATURE_HEALTH(KNIGHT, 1400)
rem SET_CREATURE_HEALTH(WITCH, 900)
SET_CREATURE_STRENGTH(KNIGHT, 150)
SET_CREATURE_ARMOUR(WITCH, 200)
SET_CREATURE_FEAR(WITCH, 0)

REM *** HERO PARTY ***

CREATE_PARTY(AT_ROOM)
ADD_TO_PARTY(AT_ROOM, DWARFA, 7, 400, ATTACK_ROOMS, 0)

CREATE_PARTY(STEAL_G)
ADD_TO_PARTY(STEAL_G, THIEF, 8, 0, STEAL_GOLD, 0)

CREATE_PARTY(SCOUT)
ADD_TO_PARTY(SCOUT, SAMURAI, 6, 400, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(SCOUT, SAMURAI, 6, 400, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(SCOUT, SAMURAI, 6, 400, ATTACK_ENEMIES, 0)

CREATE_PARTY(ATTACK1)
ADD_TO_PARTY(ATTACK1, THIEF, 8, 0, STEAL_GOLD, 0)
ADD_TO_PARTY(ATTACK1, WIZARD, 10, 1000, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK1, THIEF, 8, 0, STEAL_GOLD, 0)
ADD_TO_PARTY(ATTACK1, MONK, 10, 800, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK1, MONK, 10, 800, ATTACK_ENEMIES, 0)

CREATE_PARTY(ATTACK2)
ADD_TO_PARTY(ATTACK2, FAILY, 8, 1000, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK2, GIANT, 8, 1000, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK2, FAILY, 8, 1000, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK2, ARCHER, 8, 1000, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK2, ARCHER, 8, 1000, ATTACK_ENEMIES, 0)

CREATE_PARTY(ATTACK3)
ADD_TO_PARTY(ATTACK3, GIANT, 10, 800, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK3, GIANT, 10, 800, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK3, FAIRY, 8, 600, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK3, FAIRY, 8, 600, ATTACK_ENEMIES, 0)

CREATE_PARTY(ATTACK4)
ADD_TO_PARTY(ATTACK4, SAMURAI, 8, 800, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK4, SAMURAI, 8, 800, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK4, WIZARD, 10, 1000, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK4, WIZARD, 10, 1000, ATTACK_ENEMIES, 0)

CREATE_PARTY(ATTACK5)
ADD_TO_PARTY(ATTACK5, BARBARIAN, 10, 0, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK5, WIZARD, 10, 0, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK5, BARBARIAN, 10, 0, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK5, BARBARIAN, 10, 0, ATTACK_ENEMIES, 0)

CREATE_PARTY(ATTACK6)
ADD_TO_PARTY(ATTACK6, SAMURAI, 6, 400, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK6, SAMURAI, 8, 800, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(ATTACK6, SAMURAI, 6, 400, ATTACK_ENEMIES, 0)

CREATE_PARTY(BOSS)
ADD_TO_PARTY(BOSS, WITCH, 10, 3000, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(BOSS, WIZARD, 10, 1200, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(BOSS, WIZARD, 10, 1200, ATTACK_ENEMIES, 0)

REM *** MAIN ***

IF_ACTION_POINT(1, PLAYER0)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, GIANT, -1, 10, 7, 0)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, ARCHER, -1, 6, 6, 0)
	SET_FLAG(PLAYER_GOOD, FLAG6, 2)
	SET_TIMER(PLAYER_GOOD, TIMER0)
	IF(PLAYER_GOOD, TIMER0 >= 4000)
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, GIANT, -1, 4, 10, 1000)
	ENDIF
ENDIF

IF_ACTION_POINT(3, PLAYER0)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, BARBARIAN, 4, 8, 5, 0)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, ARCHER, 4, 6, 4, 0)
	SET_FLAG(PLAYER_GOOD, FLAG6, 1)
ENDIF

IF_ACTION_POINT(4, PLAYER0)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, MONK, 1, 7, 6, 0)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, SAMURAI, 1, 5, 6, 0)
	SET_FLAG(PLAYER_GOOD, FLAG6, 2)
ENDIF

IF_ACTION_POINT(13, PLAYER0)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, GIANT, -2, 5, 10, 1000)
	SET_FLAG(PLAYER_GOOD, FLAG3, 1)
	SET_FLAG(PLAYER_GOOD, FLAG7, 2)
ENDIF

IF_ACTION_POINT(19, PLAYER0)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, DWARFA, 20, 8, 6, 800)
ENDIF

IF(PLAYER_GOOD, FLAG0 <= 1)
	IF(PLAYER0, TIMER1 < 12000)
		IF(PLAYER0, TIMER0 >= 3500)
			NEXT_COMMAND_REUSABLE
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK3, 3, 2)
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER0, TIMER0)
		ENDIF
	ENDIF
	IF(PLAYER_GOOD, FLAG1 == 0)
		IF(PLAYER_GOOD, FLAG6 >= 1)
			IF(PLAYER_GOOD, FLAG7 >= 1)
				DISPLAY_INFORMATION(933, PLAYER0)
			ENDIF
		ENDIF
		IF(PLAYER_GOOD, FLAG6 == 2)
			IF(PLAYER_GOOD, FLAG7 == 2)
				DISPLAY_OBJECTIVE(934, PLAYER0)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK3, 3, 3)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK4, -2, 3)
				SET_FLAG(PLAYER_GOOD, FLAG5, 1)
				SET_TIMER(PLAYER0, TIMER0)
				SET_TIMER(PLAYER0, TIMER1)
				SET_TIMER(PLAYER_GOOD, TIMER1)
				SET_TIMER(PLAYER_GOOD, TIMER7)
			ENDIF
		ENDIF
	ENDIF
	IF(PLAYER_GOOD, FLAG5 == 0)
		IF_ACTION_POINT(10, PLAYER0)
			ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, KNIGHT, 10, 1, 10, 5000)
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK6, 10, 4)
			ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, BARBARIAN, 10, 6, 10, 800)
			ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, WIZARD, 10, 6, 10, 1000)
			ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, MONK, 10, 6, 10, 800)
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD, STEAL_G, -2, 8)
			ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, SAMURAI, -2, 12, 6, 400)
			ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, ARCHER, -2, 6, 9, 500)
			ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, DWARFA, 20, 3, 8, 400)
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD, AT_ROOM, 20, 6)
			SET_FLAG(PLAYER_GOOD, FLAG1, 1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD, FLAG0 == 2)
	IF(PLAYER_GOOD, FLAG1 <= 1)
		DISPLAY_INFORMATION(49, PLAYER0)
		SET_TIMER(PLAYER_GOOD, TIMER1)
		SET_FLAG(PLAYER_GOOD, FLAG4, 1)
		SET_FLAG(PLAYER_GOOD, FLAG5, 1)
	ENDIF
ENDIF

IF(PLAYER_GOOD, FLAG1 <= 1)
	IF_ACTION_POINT(9, PLAYER0)
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, BARBARIAN, 8, 6, 6, 0)
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, ARCHER, 8, 4, 8, 0)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD, AT_ROOM, 15, 6)
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, DWARFA, 16, 6, 7, 0)
		SET_FLAG(PLAYER_GOOD, FLAG7, 2)
	ENDIF
	IF_ACTION_POINT(12, PLAYER0)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD, STEAL_G, -2, 6)
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, ARCHER, -2, 6, 6, 0)
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, BARBARIAN, 5, 6, 6, 0)
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, SAMURAI, 6, 6, 6, 0)
		SET_FLAG(PLAYER_GOOD, FLAG7, 1)
	ENDIF
	IF_ACTION_POINT(14, PLAYER0)
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, GIANT, 7, 6, 10, 0)
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, SAMURAI, 17, 6, 8, 0)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD, STEAL_G, 18, 6)
		SET_FLAG(PLAYER_GOOD, FLAG7, 2)
	ENDIF
	IF(PLAYER_GOOD, FLAG1 == 1)
		IF(PLAYER_GOOD, KNIGHT == 0)
			SET_FLAG(PLAYER_GOOD, FLAG1, 2)
		ENDIF
	ENDIF
	IF(PLAYER_GOOD, FLAG3 == 0)
		IF(PLAYER_GOOD, TIMER1 >= 1000)
			ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, SCOUT, 5, DUNGEON_HEART, PLAYER0, 7, 400)
			ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, SCOUT, 6, DUNGEON_HEART, PLAYER0, 7, 400)
			SET_TIMER(PLAYER_GOOD, TIMER2)
		ENDIF
		IF(PLAYER_GOOD, TIMER2 >= 6000)
			NEXT_COMMAND_REUSABLE
			ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, SCOUT, 5, DUNGEON_HEART, PLAYER0, 7, 400)
			NEXT_COMMAND_REUSABLE
			ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, SCOUT, 6, DUNGEON_HEART, PLAYER0, 7, 400)
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_GOOD, TIMER2)
		ENDIF
	ENDIF
	IF(PLAYER_GOOD, FLAG3 == 1)
		IF(PLAYER_GOOD, FLAG5 == 1)
			SET_TIMER(PLAYER_GOOD, TIMER3)
			IF(PLAYER_GOOD, TIMER3 >= 2000)
				SET_FLAG(PLAYER_GOOD, FLAG2, 1)
				SET_TIMER(PLAYER_GOOD, TIMER4)
				SET_TIMER(PLAYER_GOOD, TIMER5)
			ENDIF
			IF(PLAYER_GOOD, TIMER4 >= 4000)
				NEXT_COMMAND_REUSABLE
				SET_FLAG(PLAYER_GOOD, FLAG2, 1)
				NEXT_COMMAND_REUSABLE
				SET_TIMER(PLAYER_GOOD, TIMER4)
			ENDIF
		ENDIF
		IF(PLAYER_GOOD, TOTAL_CREATURES < 100)
			IF(PLAYER_GOOD, TIMER5 >= 9000)
				ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, KNIGHT, -2, 1, 10, 5000)
				ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, ARCHER, -2, 6, 9, 500)
				ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, BARBARIAN, -2, 6, 10, 800)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK4, 5, 1)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK4, 6, 1)
				SET_FLAG(PLAYER_GOOD, FLAG1, 1)
				SET_FLAG(PLAYER_GOOD, FLAG5, 2)
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD, FLAG1 == 2)
	IF(PLAYER_GOOD, FLAG0 <= 1)
		DISPLAY_OBJECTIVE(46, PLAYER0)
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, DWARFA, -1, 10, 9, 0)
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, MONK, -1, 8, 8, 0)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK3, 2, 4)
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, FAIRY, 1, 6, 8, 0)
		SET_TIMER(PLAYER0, TIMER0)
		SET_TIMER(PLAYER0, TIMER1)
		SET_TIMER(PLAYER_GOOD, TIMER7)
		SET_FLAG(PLAYER_GOOD, FLAG4, 2)
	ENDIF
ENDIF

IF(PLAYER_GOOD, FLAG2 == 1)
	NEXT_COMMAND_REUSABLE
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK1, 5, DUNGEON, PLAYER0, 9, 800)
	NEXT_COMMAND_REUSABLE
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK1, 6, DUNGEON, PLAYER0, 9, 800)
	NEXT_COMMAND_REUSABLE
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, SCOUT, 5, 2)
	NEXT_COMMAND_REUSABLE
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, SCOUT, 6, 2)
	NEXT_COMMAND_REUSABLE
	SET_FLAG(PLAYER_GOOD, FLAG2, 0)
ENDIF

IF(PLAYER_GOOD, GAME_TURN >= 12000)
	DISPLAY_INFORMATION(47, PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, BOSS, 2, 1)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, WIZARD, 2, 8, 9, 1200)
	SET_FLAG(PLAYER_GOOD, FLAG0, 1)
	IF(PLAYER_GOOD, WITCH == 0)
		DISPLAY_OBJECTIVE(48, PLAYER0)
		ROOM_AVAILABLE(ALL_PLAYERS, BRIDGE, 1, 1)
		TUTORIAL_FLASH_BUTTON(18, -1)
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, IMP, 10)
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, BUG, 10)
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, SPIDER, 10)
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, BILE_DEMON, 10)
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, DRAGON, 10)
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, SORCEROR, 10)
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, DARK_MISTRESS, 10)
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, TROLL, 10)
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, ORC, 10)
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, GHOST, 10)
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, HELL_HOUND, 10)
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, VAMPIRE, 10) 
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, TENTACLE, 10) 
		SET_CREATURE_MAX_LEVEL(ALL_PLAYERS, HORNY, 10)
		SET_FLAG(PLAYER_GOOD, FLAG0, 2)
	ENDIF
ENDIF

IF(PLAYER3, DUNGEON_DESTROYED == 0)
	IF(PLAYER_GOOD, FLAG0 <= 1)
		IF(PLAYER_GOOD, TIMER7 >= 3000)
			NEXT_COMMAND_REUSABLE
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK5, 11, 1)
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_GOOD, TIMER7)
		ENDIF
	ENDIF
	IF(PLAYER_GOOD, FLAG1 == 2)
		IF(PLAYER_GOOD, FLAG4 == 1)
			DISPLAY_OBJECTIVE(50, PLAYER0)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER3, DUNGEON_DESTROYED == 1)
	IF(PLAYER_GOOD, FLAG0 <= 1)
		DISPLAY_INFORMATION(45, PLAYER0)
	ENDIF
	IF(PLAYER_GOOD, FLAG0 == 2)
		IF(PLAYER_GOOD, FLAG1 == 2)
			DISPLAY_OBJECTIVE(51, PLAYER0)
			WIN_GAME
		ENDIF
	ENDIF
ENDIF

IF_AVAILABLE(PLAYER0, POWER_OBEY == 1)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, MONK, 20, 6, 8, 800)
ENDIF

DISPLAY_OBJECTIVE(44, PLAYER0)
