REM ********************************************
REM
REM Script for Level 218
REM
REM ********************************************

SET_GENERATE_SPEED(400)

MAX_CREATURES(PLAYER0,15)

START_MONEY(PLAYER0,5000)


ADD_CREATURE_TO_POOL(FLY,5)
ADD_CREATURE_TO_POOL(TROLL,10)
ADD_CREATURE_TO_POOL(TENTACLE,5)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,2)
ADD_CREATURE_TO_POOL(SORCEROR,10)
ADD_CREATURE_TO_POOL(BILE_DEMON,10)
ADD_CREATURE_TO_POOL(BUG,10)
ADD_CREATURE_TO_POOL(ORC,10)
ADD_CREATURE_TO_POOL(DRAGON,10)

CREATURE_AVAILABLE(PLAYER0,FLY,1,1)
CREATURE_AVAILABLE(PLAYER0,DRAGON,1,1)
CREATURE_AVAILABLE(PLAYER0,TROLL,1,1)
CREATURE_AVAILABLE(PLAYER0,TENTACLE,1,1)
CREATURE_AVAILABLE(PLAYER0,DARK_MISTRESS,1,1)
CREATURE_AVAILABLE(PLAYER0,SORCEROR,1,1)
CREATURE_AVAILABLE(PLAYER0,BILE_DEMON,1,1)
CREATURE_AVAILABLE(PLAYER0,BUG,1,1)
CREATURE_AVAILABLE(PLAYER0,ORC,1,1)


ROOM_AVAILABLE(PLAYER0,TREASURE,1,1)
ROOM_AVAILABLE(PLAYER0,RESEARCH,1,1)
ROOM_AVAILABLE(PLAYER0,WORKSHOP,1,0)
ROOM_AVAILABLE(PLAYER0,GARDEN,1,1)
ROOM_AVAILABLE(PLAYER0,LAIR,1,1)
ROOM_AVAILABLE(PLAYER0,GUARD_POST,1,0)
ROOM_AVAILABLE(PLAYER0,TRAINING,1,0)
ROOM_AVAILABLE(PLAYER0,BARRACKS,1,0)
ROOM_AVAILABLE(PLAYER0,TEMPLE,1,0)
ROOM_AVAILABLE(PLAYER0,BRIDGE,1,0)

DOOR_AVAILABLE(PLAYER0,WOOD,1,0)
DOOR_AVAILABLE(PLAYER0,BRACED,1,0)
DOOR_AVAILABLE(PLAYER0,STEEL,1,0)
DOOR_AVAILABLE(PLAYER0,MAGIC,1,0)

TRAP_AVAILABLE(PLAYER0,WORD_OF_POWER,1,0)
TRAP_AVAILABLE(PLAYER0,ALARM,1,0)
TRAP_AVAILABLE(PLAYER0,POISON_GAS,1,0)

MAGIC_AVAILABLE(PLAYER0,POWER_OBEY,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_IMP,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_SLAP,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_SPEED,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_PROTECT,1,0)



CREATE_PARTY(MINE)
    ADD_TO_PARTY(MINE,BARBARIAN,4,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE,BARBARIAN,3,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE,BARBARIAN,3,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE,BARBARIAN,3,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE,BARBARIAN,3,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE,ARCHER,2,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE,ARCHER,2,0,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(MINE2)
    ADD_TO_PARTY(MINE2,WIZARD,6,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE2,WIZARD,6,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE2,WIZARD,5,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE2,MONK,6,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE2,MONK,6,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE2,MONK,6,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE2,MONK,5,0,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(MINE3)
    ADD_TO_PARTY(MINE3,GIANT,7,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE3,GIANT,7,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE3,GIANT,7,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE3,THIEF,5,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE3,THIEF,5,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE3,THIEF,4,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE3,THIEF,4,0,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(MINE4)
    ADD_TO_PARTY(MINE4,SAMURAI,7,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE4,SAMURAI,7,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE4,SAMURAI,7,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE4,SAMURAI,7,0,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(MINE4,FAIRY,9,0,ATTACK_DUNGEON_HEART,0)

QUICK_OBJECTIVE(1,"Welcome to the syndicate mine complex. Gold is more than present in this land. However, the smugglers built many galleries to protect their treasures. The only gem of the country is the personnal treasure of the Syndicate's Constable, Keeper.",PLAYER0)

IF_ACTION_POINT(5,PLAYER0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MINE2,6,1)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,7,5,5,0)
ENDIF

IF(PLAYER_GOOD,SAMURAI == 0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,FAIRY,1,5,7,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,BARBARIAN,9,3,4,0)
    SET_TIMER(PLAYER_GOOD,TIMER1)
ENDIF

IF(PLAYER_GOOD,BARBARIAN == 0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MINE,-2,1)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DWARFA,-2,5,4,0)
    SET_TIMER(PLAYER_GOOD,TIMER0)
ENDIF

IF(PLAYER_GOOD,GIANT == 0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MINE3,3,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MINE2,-3,1)
    SET_TIMER(PLAYER_GOOD,TIMER2)
ENDIF

IF(PLAYER_GOOD,TIMER0 >= 3200)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WITCH,-1,5,4,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,-1,6,4,0)
ENDIF

IF(PLAYER_GOOD,TIMER1 >= 3200)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,MONK,9,4,7,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DWARFA,9,5,6,0)
ENDIF

IF(PLAYER_GOOD,TIMER2 >= 4000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,FAIRY,3,3,8,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,MONK,-4,3,9,0)
    SET_TIMER(PLAYER_GOOD,TIMER3)
ENDIF

IF(PLAYER_GOOD,TIMER3 >= 5500)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MINE3,-3,2)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,3,5,5,0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MINE,-4,2)
    SET_TIMER(PLAYER_GOOD,TIMER4)
ENDIF

IF(PLAYER_GOOD,THIEF == 0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MINE2,6,1)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,6,5,5,0)
    SET_TIMER(PLAYER_GOOD,TIMER5)
ENDIF

IF(PLAYER_GOOD,TIMER4 >= 5500)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MINE4,3,2)
ENDIF

IF(PLAYER_GOOD,TIMER5 >= 6500)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,6,5,6,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,6,7,7,0)
ENDIF

IF_ACTION_POINT(8,PLAYER0)
    QUICK_OBJECTIVE(2," The Constable sends his more fervent troops to annihilate you. Failure is not an option, Keeper.",PLAYER0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,BARBARIAN,-2,4,10,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,-4,4,8,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,MONK,9,4,8,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,4,3,10,0)
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,10,ACTION_POINT,11,9,800)
    SET_FLAG(PLAYER_GOOD,FLAG0,1)
ENDIF

IF(PLAYER_GOOD,FLAG0 == 1)
    IF(PLAYER_GOOD,TOTAL_CREATURES == 0)
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,2,1,10,0)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MINE2,2,2)
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,MONK,2,4,9,0)
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,FAIRY,2,4,9,0)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MINE,4,2)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MINE,9,2)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MINE,-4,2)
        SET_FLAG(PLAYER_GOOD,FLAG1,1)
    ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG1 == 1)
    IF(PLAYER_GOOD,TOTAL_CREATURES == 0)
        WIN_GAME
    ENDIF
ENDIF

IF(PLAYER0,TORTURE >= 1)
    ROOM_AVAILABLE(PLAYER0,TORTURE,1,1)
    TUTORIAL_FLASH_BUTTON(2,-1)
    TUTORIAL_FLASH_BUTTON(17,-1)
ENDIF

IF(PLAYER_GOOD,SAMURAI == 0)
    IF(PLAYER_GOOD,SKELETON == 0)
        QUICK_OBJECTIVE(3,"You have now conquered a large part of the territory and won the battle, but not the war, be alert, Keeper.",PLAYER0)
    ENDIF
ENDIF
