REM Play Level Solarpaint Rock

REM ******* Basic settings *******

SET_GENERATE_SPEED(120)

MAX_CREATURES(PLAYER0,42)

START_MONEY(PLAYER0,20000)

ADD_CREATURE_TO_POOL(FLY,16)
ADD_CREATURE_TO_POOL(BUG,6)
ADD_CREATURE_TO_POOL(SPIDER,10)
ADD_CREATURE_TO_POOL(DEMONSPAWN,16)
ADD_CREATURE_TO_POOL(SORCEROR,16)
ADD_CREATURE_TO_POOL(BILE_DEMON,16)
ADD_CREATURE_TO_POOL(DRAGON,10)
ADD_CREATURE_TO_POOL(TROLL,16)
ADD_CREATURE_TO_POOL(ORC,16)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,16)
ADD_CREATURE_TO_POOL(HELL_HOUND,16)
ADD_CREATURE_TO_POOL(VAMPIRE,10)
ADD_CREATURE_TO_POOL(TENTACLE,6)
ADD_CREATURE_TO_POOL(HORNY,16)

REM ********** Available creatures **********

CREATURE_AVAILABLE(ALL_PLAYERS,FLY,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,BUG,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,SPIDER,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,DRAGON,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,ORC,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,DARK_MISTRESS,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,HELL_HOUND,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,VAMPIRE,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,TENTACLE,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,HORNY,1,1)

REM ********** Available rooms **********

ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,BRIDGE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GRAVEYARD,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,SCAVENGER,1,0)

IF(PLAYER0,SCAVENGER >= 9)
    ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,0)
ENDIF

REM ********** Available spells **********

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CHICKEN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DISEASE,1,0)

REM ********** Available doors & traps **********

DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,ALARM,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,WORD_OF_POWER,1,0)

REM ********** Game settings **********

IF(PLAYER0,DUNGEON_DESTROYED == 1)
    LOSE_GAME
ENDIF

REM ********** Parties **********

CREATE_PARTY(ONE)
    ADD_TO_PARTY(ONE,WITCH,3,300,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(ONE,SAMURAI,3,400,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(ONE,MONK,3,350,ATTACK_ENEMIES,0)

CREATE_PARTY(TWO)
    ADD_TO_PARTY(TWO,THIEF,3,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(TWO,THIEF,3,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(TWO,THIEF,3,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(TWO,ARCHER,4,500,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(TWO,ARCHER,5,500,ATTACK_ENEMIES,0)

CREATE_PARTY(THREE)
    ADD_TO_PARTY(THREE,BARBARIAN,3,600,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(THREE,BARBARIAN,3,600,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(THREE,BARBARIAN,3,600,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(THREE,GIANT,2,600,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(THREE,GIANT,2,600,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(THREE,GIANT,2,600,ATTACK_ENEMIES,0)

CREATE_PARTY(FOUR)
    ADD_TO_PARTY(FOUR,WIZARD,5,800,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(FOUR,WIZARD,5,800,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(FOUR,FAIRY,4,600,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(FOUR,FAIRY,4,600,ATTACK_ENEMIES,0)

CREATE_PARTY(FIVE)
    ADD_TO_PARTY(FIVE,SAMURAI,10,0,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(FIVE,SAMURAI,10,0,ATTACK_ENEMIES,0)

CREATE_PARTY(SIX)
    ADD_TO_PARTY(SIX,AVATAR,9,8000,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(SIX,KNIGHT,10,400,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(SIX,WIZARD,10,400,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(SIX,SAMURAI,10,400,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(SIX,FAIRY,10,400,ATTACK_ENEMIES,0)

REM ********** Triggers & End game **********

IF(PLAYER0,GAME_TURN >= 1000)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ONE,2,DUNGEON_HEART,0,2,100)
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,2,DUNGEON_HEART,0,2,100)
    SET_TIMER(PLAYER0,TIMER0)
ENDIF

IF(PLAYER0,TIMER0 >= 3000)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TWO,3,DUNGEON_HEART,0,3,100)
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,3,DUNGEON_HEART,0,3,100)
ENDIF

IF(PLAYER0,TIMER0 >= 5500)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,THREE,4,DUNGEON_HEART,0,3,100)
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,4,DUNGEON_HEART,0,3,100)
ENDIF

IF(PLAYER0,TIMER0 >= 8000)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,FOUR,5,DUNGEON_HEART,0,4,100)
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,5,DUNGEON_HEART,0,4,100)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,3,2,4,400)
    SET_TIMER(PLAYER_GOOD,TIMER3)
    SET_TIMER(PLAYER0,TIMER1)
    SET_TIMER(PLAYER_GOOD,TIMER0)
ENDIF

IF(PLAYER0,TIMER0 >= 9500)
    SET_TIMER(PLAYER0,TIMER2)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,4,1,1,300)
ENDIF

IF(PLAYER0,TIMER0 >= 11000)
    SET_TIMER(PLAYER0,TIMER3)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,2,4,4,400)
ENDIF

IF(PLAYER0,TIMER0 >= 12500)
    SET_TIMER(PLAYER0,TIMER4)
    SET_TIMER(PLAYER_GOOD,TIMER1)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,3,1,1,400)
ENDIF

IF(PLAYER0,TIMER0 >= 14000)
    SET_TIMER(PLAYER0,TIMER5)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,BARBARIAN,5,4,5,400)
ENDIF

IF(PLAYER0,TIMER0 >= 15500)
    SET_TIMER(PLAYER0,TIMER6)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DWARFA,2,1,1,400)
ENDIF

IF(PLAYER0,TIMER0 >= 17000)
    SET_TIMER(PLAYER0,TIMER7)
    SET_TIMER(PLAYER_GOOD,TIMER2)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,3,4,5,400)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DWARFA,4,1,1,400)
ENDIF

IF(PLAYER0,TIMER0 >= 18500)
    SET_TIMER(PLAYER_GOOD,TIMER4)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,FAIRY,3,1,2,400)
ENDIF

IF(PLAYER0,TIMER1 >= 12000)
    IF(PLAYER_GOOD,TIMER3 < 60100)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,2,2,8,400)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,FAIRY,4,2,7,400)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER0,TIMER1)
    ENDIF
ENDIF

IF(PLAYER0,TIMER2 >= 12000)
    IF(PLAYER_GOOD,TIMER3 < 60100)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,3,3,8,400)
        NEXT_COMMAND_REUSABLE
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,THREE,5,1)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER0,TIMER2)
    ENDIF
ENDIF

IF(PLAYER0,TIMER3 >= 12000)
    IF(PLAYER_GOOD,TIMER3 < 60100)
        NEXT_COMMAND_REUSABLE
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FOUR,3,1)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WITCH,2,2,7,400)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER0,TIMER3)
    ENDIF
ENDIF

IF(PLAYER0,TIMER4 >= 12000)
    IF(PLAYER_GOOD,TIMER3 < 60100)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DWARFA,5,3,9,400)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,4,1,3,400)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER0,TIMER4)
    ENDIF
ENDIF

IF(PLAYER0,TIMER5 >= 12000)
    IF(PLAYER_GOOD,TIMER3 < 60100)
        NEXT_COMMAND_REUSABLE
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TWO,2,1)
        NEXT_COMMAND_REUSABLE
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,THREE,5,1)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER0,TIMER5)
    ENDIF
ENDIF

IF(PLAYER0,TIMER6 >= 12000)
    IF(PLAYER_GOOD,TIMER3 < 60100)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,FAIRY,3,3,8,400)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,2,4,3,400)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER0,TIMER6)
    ENDIF
ENDIF

IF(PLAYER0,TIMER7 >= 12000)
    IF(PLAYER_GOOD,TIMER3 < 60100)
        NEXT_COMMAND_REUSABLE
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FOUR,5,1)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DWARFA,2,3,6,400)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER0,TIMER7)
    ENDIF
ENDIF

IF(PLAYER_GOOD,TIMER4 >= 12000)
    IF(PLAYER_GOOD,TIMER3 < 60100)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,MONK,3,1,4,400)
        NEXT_COMMAND_REUSABLE
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TWO,4,1)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER_GOOD,TIMER4)
    ENDIF
ENDIF

IF(PLAYER_GOOD,TIMER0 >= 13500)
    IF(PLAYER_GOOD,TIMER3 < 60100)
        NEXT_COMMAND_REUSABLE
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FIVE,1,1)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER_GOOD,TIMER0)
    ENDIF
ENDIF

IF(PLAYER_GOOD,TIMER1 >= 13500)
    IF(PLAYER_GOOD,TIMER3 < 60100)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,1,1,10,0)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER_GOOD,TIMER1)
    ENDIF
ENDIF

IF(PLAYER_GOOD,TIMER2 >= 13500)
    IF(PLAYER_GOOD,TIMER3 < 60100)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,MONK,1,1,10,0)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER_GOOD,TIMER2)
    ENDIF
ENDIF

IF(PLAYER_GOOD,TIMER3 >= 62000)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SIX,1,1)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SAMURAI,2,1,9,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SAMURAI,3,1,9,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SAMURAI,4,1,9,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SAMURAI,5,1,9,0)
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,1,DUNGEON_HEART,0,10,100)
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,6,DUNGEON_HEART,0,10,100)
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,7,DUNGEON_HEART,0,10,100)
    IF(PLAYER_GOOD,AVATAR == 0)
        WIN_GAME
    ENDIF
ENDIF
