


REM ######################################################
REM ######################################################
REM ### BASIC SETTINGS


LEVEL_VERSION(1)

SET_GENERATE_SPEED(500)

MAX_CREATURES(ALL_PLAYERS,10)

START_MONEY(ALL_PLAYERS,8000)



REM ######################################################
REM ######################################################
REM ### PLAYERS GETS +5 CREATURE MAX PER PORTAL CLAIMED.


IF(PLAYER0,ENTRANCE == 9)
	NEXT_COMMAND_REUSABLE
	MAX_CREATURES(PLAYER0,15)
ENDIF

IF(PLAYER0,ENTRANCE == 18)
	NEXT_COMMAND_REUSABLE
	MAX_CREATURES(PLAYER0,20)
ENDIF

IF(PLAYER0,ENTRANCE == 27)
	NEXT_COMMAND_REUSABLE
	MAX_CREATURES(PLAYER0,25)
ENDIF

IF(PLAYER0,ENTRANCE == 36)
	NEXT_COMMAND_REUSABLE
	MAX_CREATURES(PLAYER0,30)
ENDIF


IF(PLAYER1,ENTRANCE == 9)
	NEXT_COMMAND_REUSABLE
	MAX_CREATURES(PLAYER1,15)
ENDIF

IF(PLAYER1,ENTRANCE == 18)
	NEXT_COMMAND_REUSABLE
	MAX_CREATURES(PLAYER1,20)
ENDIF

IF(PLAYER1,ENTRANCE == 27)
	NEXT_COMMAND_REUSABLE
	MAX_CREATURES(PLAYER1,25)
ENDIF

IF(PLAYER1,ENTRANCE == 36)
	NEXT_COMMAND_REUSABLE
	MAX_CREATURES(PLAYER1,30)
ENDIF



REM ######################################################
REM ######################################################
REM ### WE PLAYING SKINS OR SCALES TODAY, BRUV?


SET_FLAG(PLAYER0,FLAG0,DRAWFROM(1,2))



REM ######################################################
REM ######################################################
REM ### POOLS CLOSED FOR :
REM ### GHOST, SKELETON, VAMPIRE, HORNY, IMP.
REM ### KNIGHT, TUNNELLER, AVATAR.


ADD_CREATURE_TO_POOL(FLY,30)
ADD_CREATURE_TO_POOL(BUG,30)
ADD_CREATURE_TO_POOL(SPIDER,30)
ADD_CREATURE_TO_POOL(SORCEROR,30)
ADD_CREATURE_TO_POOL(TROLL,30)
ADD_CREATURE_TO_POOL(BILE_DEMON,30)
ADD_CREATURE_TO_POOL(DEMONSPAWN,30)
ADD_CREATURE_TO_POOL(DRAGON,30)
ADD_CREATURE_TO_POOL(ORC,30)
ADD_CREATURE_TO_POOL(TENTACLE,30)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,30)
ADD_CREATURE_TO_POOL(HELL_HOUND,30)
ADD_CREATURE_TO_POOL(DRUID,30)


ADD_CREATURE_TO_POOL(WIZARD,30)
ADD_CREATURE_TO_POOL(BARBARIAN,30)
ADD_CREATURE_TO_POOL(ARCHER,30)
ADD_CREATURE_TO_POOL(MONK,30)
ADD_CREATURE_TO_POOL(DWARFA,30)
ADD_CREATURE_TO_POOL(WITCH,30)
ADD_CREATURE_TO_POOL(GIANT,30)
ADD_CREATURE_TO_POOL(FAIRY,30)
ADD_CREATURE_TO_POOL(THIEF,30)
ADD_CREATURE_TO_POOL(SAMURAI,30)
ADD_CREATURE_TO_POOL(TIME_MAGE,30)



REM ######################################################
REM ######################################################
REM ### PLAYERS DRAW FROM HERO POOL OR CREATURE POOL.


IF(PLAYER0,FLAG0 == 1)
	CREATURE_AVAILABLE(ALL_PLAYERS,FLY,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,BUG,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,SPIDER,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,DRAGON,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,ORC,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,TENTACLE,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,DARK_MISTRESS,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,HELL_HOUND,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,DRUID,1,0)
ENDIF


IF(PLAYER0,FLAG0 == 2)
	CREATURE_AVAILABLE(ALL_PLAYERS,WIZARD,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,BARBARIAN,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,ARCHER,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,MONK,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,DWARFA,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,WITCH,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,GIANT,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,FAIRY,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,THIEF,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,SAMURAI,1,0)
	CREATURE_AVAILABLE(ALL_PLAYERS,TIME_MAGE,1,0)
ENDIF



REM ######################################################
REM ######################################################


ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,BRIDGE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,PRISON,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GRAVEYARD,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,SCAVENGER,1,0)


MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SIGHT,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CAVE_IN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CHICKEN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ARMAGEDDON,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DESTROY_WALLS,1,0)


DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)


TRAP_AVAILABLE(ALL_PLAYERS,ALARM,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LAVA,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,WORD_OF_POWER,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,BOULDER,1,0)



REM ######################################################
REM ######################################################
REM ### DRAGONS WEST/EAST


CREATE_PARTY(DRAGON5)
ADD_TO_PARTY(DRAGON5,DRAGON,5,0,DEFEND_LOCATION,0)

CREATE_PARTY(DRAGON6)
ADD_TO_PARTY(DRAGON6,DRAGON,6,0,DEFEND_LOCATION,0)

CREATE_PARTY(DRAGON7)
ADD_TO_PARTY(DRAGON7,DRAGON,7,0,DEFEND_LOCATION,0)

CREATE_PARTY(DEMON8)
ADD_TO_PARTY(DEMON8,DEMONSPAWN,8,0,DEFEND_LOCATION,0)


ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAGON5,5,1)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAGON5,6,1)

ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAGON6,5,1)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAGON6,6,1)

ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAGON7,5,1)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAGON7,6,1)

ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DEMON8,5,2)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DEMON8,6,2)



REM ######################################################
REM ######################################################
REM ### LIBRARY HEROES WEST/EAST -- SPAWNS IF PLAYERS ARE USING HEROES


CREATE_PARTY(LOCK8)
ADD_TO_PARTY(LOCK8,SORCEROR,8,0,DEFEND_LOCATION,0)

CREATE_PARTY(DRUID10)
ADD_TO_PARTY(DRUID10,DRUID,10,0,DEFEND_LOCATION,0)

CREATE_PARTY(TENT9)
ADD_TO_PARTY(TENT9,TENTACLE,9,0,DEFEND_LOCATION,0)


IF(PLAYER0,FLAG0 == 2)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAGON7,7,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAGON7,8,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LOCK8,7,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LOCK8,8,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRUID10,7,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRUID10,8,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TENT9,7,2)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TENT9,8,2)
ENDIF



REM ######################################################
REM ######################################################
REM ### LIBRARY HEROES WEST/EAST -- SPAWNS IF PLAYERS ARE USING CREATURES


CREATE_PARTY(MONK9)
ADD_TO_PARTY(MONK9,MONK,9,0,DEFEND_LOCATION,0)

CREATE_PARTY(WIZ8)
ADD_TO_PARTY(WIZ8,WIZARD,8,0,DEFEND_LOCATION,0)

CREATE_PARTY(TIME8)
ADD_TO_PARTY(TIME8,TIME_MAGE,8,0,DEFEND_LOCATION,0)

CREATE_PARTY(FAIRY7)
ADD_TO_PARTY(FAIRY7,FAIRY,7,0,DEFEND_LOCATION,0)


IF(PLAYER0,FLAG0 == 1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MONK9,7,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MONK9,8,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,WIZ8,7,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,WIZ8,8,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TIME8,7,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TIME8,8,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRY7,7,2)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRY7,8,2)
ENDIF



REM ######################################################
REM ######################################################
REM ### COUNT HARASS PARTIES AT NORTH/SOUTH GEMS AND STOP SPAWNING IF THEY AREN'T BEING DEALT WITH.


IF(PLAYER0,FLAG0 != 0)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(1,PLAYER_GOOD,ANY_CREATURE,PLAYER_GOOD,FLAG1)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(2,PLAYER_GOOD,ANY_CREATURE,PLAYER_GOOD,FLAG2)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(3,PLAYER_GOOD,ANY_CREATURE,PLAYER_GOOD,FLAG3)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(4,PLAYER_GOOD,ANY_CREATURE,PLAYER_GOOD,FLAG4)
ENDIF



REM ######################################################
REM ######################################################
REM ### TIMER0 IF PLAYERS USING HEROES, TIMER1 IF PLAYERS USING CREATURES


IF(PLAYER0,FLAG0 == 2)
	SET_TIMER(PLAYER0,TIMER0)
ENDIF


IF(PLAYER0,FLAG0 == 1)
	SET_TIMER(PLAYER0,TIMER1)
ENDIF



REM ######################################################
REM ######################################################
REM ### HARASS PARTY LOOP NEAR NORTH/SOUTH GEMS -- SPAWNS IF PLAYERS ARE USING HEROES


CREATE_PARTY(CREATURES)
ADD_TO_PARTY(CREATURES,HELL_HOUND,4,0,DEFEND_LOCATION,0)



IF(PLAYER0,TIMER0 >= 5000)
	IF(PLAYER_GOOD,FLAG1 <= 6)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CREATURES,-1,2)
	ENDIF
	IF(PLAYER_GOOD,FLAG2 <= 6)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CREATURES,-2,2)
	ENDIF
	IF(PLAYER_GOOD,FLAG3 <= 6)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CREATURES,-3,2)
	ENDIF
	IF(PLAYER_GOOD,FLAG4 <= 6)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CREATURES,-4,2)
	ENDIF
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER0,TIMER0)
ENDIF



REM ######################################################
REM ######################################################
REM ### HARASS PARTY LOOP NEAR NORTH/SOUTH GEMS -- SPAWNS IF PLAYERS ARE USING CREATURES


CREATE_PARTY(HEROES)
ADD_TO_PARTY(HEROES,FAIRY,4,0,DEFEND_LOCATION,0)


IF(PLAYER0,TIMER1 >= 5000)
	IF(PLAYER_GOOD,FLAG1 <= 6)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,HEROES,-1,2)
	ENDIF
	IF(PLAYER_GOOD,FLAG2 <= 6)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,HEROES,-2,2)
	ENDIF
	IF(PLAYER_GOOD,FLAG3 <= 6)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,HEROES,-3,2)
	ENDIF
	IF(PLAYER_GOOD,FLAG4 <= 6)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,HEROES,-4,2)
	ENDIF
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER0,TIMER1)
ENDIF



REM ######################################################
REM ######################################################
REM ### HARASS PARTY NEAR GEMS, STRENGTH ADVANCEMENT -- SPAWNS IF PLAYERS ARE USING HEROES


IF(PLAYER0,GAME_TURN >= 24000)
	ADD_TO_PARTY(CREATURES,HELL_HOUND,6,0,DEFEND_LOCATION,0)
	DELETE_FROM_PARTY(CREATURES,HELL_HOUND,4)
ENDIF


IF(PLAYER0,GAME_TURN >= 48000)
	ADD_TO_PARTY(CREATURES,HELL_HOUND,7,0,DEFEND_LOCATION,0)
	DELETE_FROM_PARTY(CREATURES,HELL_HOUND,6)
ENDIF


IF(PLAYER0,GAME_TURN >= 80000)
	ADD_TO_PARTY(CREATURES,HELL_HOUND,8,0,DEFEND_LOCATION,0)
ENDIF



REM ######################################################
REM ######################################################
REM ### HARASS PARTY NEAR GEMS, STRENGTH ADVANCEMENT -- SPAWNS IF PLAYERS ARE USING CREATURES


IF(PLAYER0,GAME_TURN >= 24000)
	ADD_TO_PARTY(HEROES,FAIRY,6,0,DEFEND_LOCATION,0)
	DELETE_FROM_PARTY(HEROES,FAIRY,4)
ENDIF


IF(PLAYER0,GAME_TURN >= 48000)
	ADD_TO_PARTY(HEROES,FAIRY,8,0,DEFEND_LOCATION,0)
	DELETE_FROM_PARTY(HEROES,FAIRY,6)
ENDIF


IF(PLAYER0,GAME_TURN >= 80000)
	ADD_TO_PARTY(HEROES,FAIRY,8,0,DEFEND_LOCATION,0)
ENDIF



REM ######################################################
REM ######################################################
REM ### MESSAGE CONTROL


IF(PLAYER0,GAME_TURN > 100)
	IF(PLAYER0,FLAG0 == 1)
		QUICK_OBJECTIVE(​1,​"Creature limit is 10 + 5 per portal owned. Creature pool contains Creatures, including Druid, at 30x quantity. Pool contains no Horned Reaper, Vampire, Skeleton or Ghost.",ALL_PLAYERS)
	ENDIF
ENDIF


IF(PLAYER0,GAME_TURN > 100)
	IF(PLAYER0,FLAG0 == 2)
		QUICK_OBJECTIVE(​2,​"Creature limit is 10 + 5 per portal owned. Creature pool contains Heroes, including Time Mage, at 30x quantity. Pool contains no Knight, Tunneller or Avatar.",ALL_PLAYERS)
	ENDIF
ENDIF



REM ######################################################
REM ######################################################
REM ### VICTORY CONTROL



IF(PLAYER0,ALL_DUNGEONS_DESTROYED == 1)
	WIN_GAME
ENDIF

IF(PLAYER1,ALL_DUNGEONS_DESTROYED == 1)
	WIN_GAME
ENDIF



REM ######################################################
REM ######################################################