LEVEL_VERSION(1)

SET_GENERATE_SPEED(500)

COMPUTER_PLAYER(PLAYER0,7)

START_MONEY(PLAYER1,3000)
START_MONEY(PLAYER0,5000)

MAX_CREATURES(PLAYER1,18)
MAX_CREATURES(PLAYER0,20)

ADD_CREATURE_TO_POOL(BUG,3)
ADD_CREATURE_TO_POOL(FLY,2)
ADD_CREATURE_TO_POOL(SPIDER,12)
ADD_CREATURE_TO_POOL(TROLL,8)
ADD_CREATURE_TO_POOL(DEMONSPAWN,12)
ADD_CREATURE_TO_POOL(SORCEROR,6)

SET_CREATURE_MAX_LEVEL(PLAYER1,DEMONSPAWN,10)

CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,0)
CREATURE_AVAILABLE(PLAYER1,FLY,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,0)
CREATURE_AVAILABLE(PLAYER1,BUG,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SPIDER,1,0)
CREATURE_AVAILABLE(PLAYER0,BILE_DEMON,1,0)
	
REM	Room availability
ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(PLAYER0,GUARD_POST,1,0)
ROOM_AVAILABLE(PLAYER1,BRIDGE,1,0)

REM	Spells availability
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_SPEED,1,1)

REM	Doors and traps availability
DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)

CREATE_PARTY(ONE)
	ADD_TO_PARTY(ONE,DWARFA,3,100,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ONE,ARCHER,3,100,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ONE,DWARFA,3,100,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ONE,ARCHER,3,100,ATTACK_ENEMIES,0)

CREATE_PARTY(TWO)
	ADD_TO_PARTY(TWO,FAIRY,4,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(TWO,FAIRY,4,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(TWO,BARBARIAN,3,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(TWO,BARBARIAN,3,200,ATTACK_ENEMIES,0)

CREATE_PARTY(THREE)
	ADD_TO_PARTY(THREE,GIANT,3,300,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(THREE,GIANT,3,300,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(THREE,BARBARIAN,4,300,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(THREE,BARBARIAN,4,300,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(THREE,ARCHER,4,300,ATTACK_ENEMIES,0)

QUICK_OBJECTIVE(1,"This time, you are going to play the role of Blue Keeper. You have been revived by magic power and are vengeful to the keepers who defeated you in the past. Find your first opponent in this realm and defeat him.",PLAYER1)

IF(PLAYER1,PRISON > 0)
	QUICK_INFORMATION(2,"Great job! You have claimed the prison. But the enemy keeper have already rescued the spiders and bile demon in it.",PLAYER1)
	ROOM_AVAILABLE(PLAYER1,PRISON,1,1)
ENDIF

IF(PLAYER1,SKELETONS_RAISED >= 8)
	SET_GAME_RULE(PrisonSkeletonChance,0)
	QUICK_INFORMATION(11, "You can't get more skeletons from prison.", PLAYER1)
ENDIF

IF(PLAYER0,PRISON > 0)
	SET_CREATURE_TENDENCIES(PLAYER0,IMPRISON,1)
	ROOM_AVAILABLE(PLAYER0,PRISON,1,1)
ENDIF

IF(PLAYER1,GAME_TURN>=10000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ONE,-1,DUNGEON,1,1,100)
	QUICK_INFORMATION(3,"I notice the heroes are sending their party to invade your dungeon. Wait, are there heroes in this realm originally? When did they arrive here?",PLAYER1)
ENDIF

IF(PLAYER1,GAME_TURN>=13000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ONE,-2,DUNGEON,1,1,100)
ENDIF

IF(PLAYER1,GAME_TURN>=18000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TWO,-1,DUNGEON,1,2,100)
ENDIF

IF(PLAYER1,GAME_TURN>=21000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TWO,-2,DUNGEON,1,2,100)
ENDIF

IF(PLAYER1,GAME_TURN>=31000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,THREE,-1,DUNGEON,1,4,100)
ENDIF

IF(PLAYER1,GAME_TURN>=35000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,THREE,-2,DUNGEON,1,4,100)
ENDIF

IF(PLAYER1,GAME_TURN>=8000)	
	IF_SLAB_TYPE(42,49,LAVA)
			CHANGE_SLAB_TYPE(42,49,BRIDGE_FRAME)
			CHANGE_SLAB_OWNER(42,49,PLAYER0)
	ENDIF
	IF_SLAB_TYPE(42,50,LAVA)
			CHANGE_SLAB_TYPE(42,50,BRIDGE_FRAME)
			CHANGE_SLAB_OWNER(42,50,PLAYER0)
	ENDIF
	IF_SLAB_TYPE(42,51,LAVA)
			CHANGE_SLAB_TYPE(42,51,BRIDGE_FRAME)
			CHANGE_SLAB_OWNER(42,51,PLAYER0)
	ENDIF
	IF_SLAB_TYPE(42,52,LAVA)
			CHANGE_SLAB_TYPE(42,52,BRIDGE_FRAME)
			CHANGE_SLAB_OWNER(42,52,PLAYER0)
	ENDIF
	ROOM_AVAILABLE(PLAYER0,BRIDGE,1,0)
ENDIF

IF(PLAYER0,DUNGEON_DESTROYED >= 1)
	QUICK_OBJECTIVE(4,"You have crushed your first opponent and cliamed back this first realm, but this is just a beginning.",PLAYER1)
	WIN_GAME
ENDIF

REM ****************************************************************************
