LEVEL_VERSION(1)

START_MONEY(PLAYER1,102)
REM COMPUTER_PLAYER(PLAYER0,1)

QUICK_OBJECTIVE(1,"You plays the role of the Hound this time! Go and eat all of these enemy imps for lunch!",PLAYER1)
QUICK_INFORMATION(2,"The number of enemy imps left is shown above.",PLAYER1)

SET_TIMER(PLAYER0,TIMER0)
BONUS_LEVEL_TIME(5000)

DISPLAY_VARIABLE(PLAYER0,IMP,0,0)

SET_CREATURE_HEALTH(IMP,100)
SET_CREATURE_STRENGTH(IMP,7)
SET_CREATURE_FEAR_WOUNDED(IMP,0)
SET_CREATURE_FEAR_STRONGER(IMP,10000)

IF(PLAYER0,IMP == 0)
	SET_FLAG(PLAYER0,FLAG1,1)
	ADD_HEART_HEALTH(PLAYER0,-30000,1)
	DISPLAY_OBJECTIVE(147,PLAYER0)
	ADD_CREATURE_TO_LEVEL(PLAYER1,IMP,PLAYER1,3,10,0)
	ROOM_AVAILABLE(ALL_PLAYERS,BRIDGE,1,1)
	REM Using a timer to make sure add creature command will be executed
	SET_TIMER(PLAYER0,TIMER1)
	BONUS_LEVEL_TIME(0)
ENDIF

IF(PLAYER0,TIMER0 >= 5000)
	IF(PLAYER0,FLAG1 == 0)
		QUICK_OBJECTIVE(4,"You are too slow. This is not like relaxedly walking your dog!",PLAYER1)
		LOSE_GAME 
	ENDIF
ENDIF

IF(PLAYER1,HELL_HOUND<=0)
	QUICK_OBJECTIVE(5,"You lost your Hound from some imps? What a shame!",PLAYER1)
	LOSE_GAME
ENDIF

IF(PLAYER0,TIMER1 >= 10)
	QUICK_OBJECTIVE(3,"The Hound is full now and he is happy to be with you to the next realm!",PLAYER1)
	WIN_GAME
ENDIF
