LEVEL_VERSION(1)
SET_GENERATE_SPEED(400)
START_MONEY(ALL_PLAYERS,2500)
MAX_CREATURES(ALL_PLAYERS,20)

ADD_CREATURE_TO_POOL(FLY,20)
ADD_CREATURE_TO_POOL(BUG,20)
ADD_CREATURE_TO_POOL(DEMONSPAWN,20)
ADD_CREATURE_TO_POOL(TROLL,20)
ADD_CREATURE_TO_POOL(SPIDER,20)
ADD_CREATURE_TO_POOL(HELL_HOUND,20)
ADD_CREATURE_TO_POOL(TENTACLE,20)
ADD_CREATURE_TO_POOL(SORCEROR,20)
ADD_CREATURE_TO_POOL(ORC,20)
ADD_CREATURE_TO_POOL(BILE_DEMON,20)
ADD_CREATURE_TO_POOL(DRAGON,20)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,20)

CREATURE_AVAILABLE(ALL_PLAYERS,FLY,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,BUG,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SPIDER,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,HELL_HOUND,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,TENTACLE,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,ORC,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DRAGON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DARK_MISTRESS,1,0)

ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,PRISON,0,0)
ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GRAVEYARD,0,0)
ROOM_AVAILABLE(ALL_PLAYERS,SCAVENGER,1,0)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_POSSESS,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CAVE_IN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CHICKEN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DISEASE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ARMAGEDDON,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DESTROY_WALLS,1,0)

TRAP_AVAILABLE(ALL_PLAYERS,ALARM,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LAVA,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,BOULDER,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,WORD_OF_POWER,1,0)

DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)

CREATE_PARTY(ADVENTURE_A)
	ADD_TO_PARTY(ADVENTURE_A,THIEF,2,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_A,THIEF,2,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_A,THIEF,2,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_A,ARCHER,2,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_A,ARCHER,2,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_A,DWARF,2,200,STEAL_GOLD,500)
	
CREATE_PARTY(ADVENTURE_B)
	ADD_TO_PARTY(ADVENTURE_B,THIEF,4,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_B,THIEF,4,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_B,ARCHER,4,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_B,ARCHER,4,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_B,DWARFA,4,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_B,WIZARD,4,200,STEAL_GOLD,500)
	
CREATE_PARTY(ADVENTURE_C)
	ADD_TO_PARTY(ADVENTURE_C,BARBARIAN,6,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_C,ARCHER,6,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_C,MONK,6,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_C,SAMURAI,6,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_C,WIZARD,6,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_C,WITCH,6,200,STEAL_GOLD,500)
	
CREATE_PARTY(ADVENTURE_D)
	ADD_TO_PARTY(ADVENTURE_D,SAMURAI,8,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_D,ARCHER,8,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_D,WITCH,8,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_D,BARBARIAN,8,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_D,MONK,8,200,STEAL_GOLD,500)
	ADD_TO_PARTY(ADVENTURE_D,GIANT,8,200,STEAL_GOLD,500)

CREATE_PARTY(THIEVES)
	ADD_TO_PARTY(THIEVES,ARCHER,4,200,STEAL_GOLD,500)
	ADD_TO_PARTY(THIEVES,ARCHER,4,200,STEAL_GOLD,500)
	ADD_TO_PARTY(THIEVES,THIEF,4,200,STEAL_GOLD,500)
	ADD_TO_PARTY(THIEVES,THIEF,4,200,STEAL_GOLD,500)
	ADD_TO_PARTY(THIEVES,THIEF,6,200,STEAL_GOLD,500)
	
CREATE_PARTY(DWARVES)
	ADD_TO_PARTY(DWARVES,DWARFA,4,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(DWARVES,DWARFA,4,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(DWARVES,DWARFA,4,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(DWARVES,DWARFA,4,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(DWARVES,DWARFA,4,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(DWARVES,DWARFA,4,200,ATTACK_ENEMIES,500)
	
CREATE_PARTY(MONKS)
	ADD_TO_PARTY(MONKS,MONK,3,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(MONKS,MONK,3,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(MONKS,MONK,5,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(MONKS,MONK,5,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(MONKS,MONK,6,200,ATTACK_ENEMIES,500)
	
CREATE_PARTY(JUSTICE)
	ADD_TO_PARTY(JUSTICE,ARCHER,5,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(JUSTICE,ARCHER,5,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(JUSTICE,MONK,4,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(JUSTICE,MONK,4,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(JUSTICE,SAMURAI,7,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(JUSTICE,SAMURAI,7,200,ATTACK_ENEMIES,500)
	
CREATE_PARTY(TUNNEL_GOLD)
	ADD_TO_PARTY(TUNNEL_GOLD,DWARFA,3,200,STEAL_GOLD,500)
	ADD_TO_PARTY(TUNNEL_GOLD,THIEF,3,200,STEAL_GOLD,500)
	ADD_TO_PARTY(TUNNEL_GOLD,THIEF,3,200,STEAL_GOLD,500)
	ADD_TO_PARTY(TUNNEL_GOLD,THIEF,3,200,STEAL_GOLD,500)
	ADD_TO_PARTY(TUNNEL_GOLD,THIEF,6,200,STEAL_GOLD,500)
	
CREATE_PARTY(TUNNEL_SPELLS)
	ADD_TO_PARTY(TUNNEL_SPELLS,SKELETON,5,200,STEAL_GOLD,500)
	ADD_TO_PARTY(TUNNEL_SPELLS,SKELETON,5,200,STEAL_GOLD,500)
	ADD_TO_PARTY(TUNNEL_SPELLS,SKELETON,5,200,STEAL_GOLD,500)
	ADD_TO_PARTY(TUNNEL_SPELLS,SKELETON,5,200,STEAL_GOLD,500)
	ADD_TO_PARTY(TUNNEL_SPELLS,SKELETON,5,200,STEAL_GOLD,500)
	ADD_TO_PARTY(TUNNEL_SPELLS,TIME_MAGE,7,200,STEAL_GOLD,500)
	
CREATE_PARTY(ELITE)
	ADD_TO_PARTY(ELITE,BARBARIAN,6,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(ELITE,BARBARIAN,6,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(ELITE,ARCHER,5,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(ELITE,ARCHER,5,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(ELITE,ARCHER,5,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(ELITE,WIZARD,5,200,ATTACK_ENEMIES,500)
	
CREATE_PARTY(LANDLORD)
	ADD_TO_PARTY(LANDLORD,DRUID,8,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(LANDLORD,WITCH,8,200,ATTACK_ENEMIES,500)
	ADD_TO_PARTY(LANDLORD,BARBARIAN,8,200,DEFEND_PARTY,500)
	ADD_TO_PARTY(LANDLORD,WIZARD,8,200,DEFEND_PARTY,500)
	ADD_TO_PARTY(LANDLORD,ARCHER,8,200,DEFEND_PARTY,500)
	ADD_TO_PARTY(LANDLORD,KNIGHT,10,2000,ATTACK_ENEMIES,500)
	
CREATE_PARTY(AVATAR)
	ADD_TO_PARTY(AVATAR,TIME_MAGE,10,200,DEFEND_PARTY,500)
	ADD_TO_PARTY(AVATAR,TIME_MAGE,10,200,DEFEND_PARTY,500)
	ADD_TO_PARTY(AVATAR,DRUID,10,200,DEFEND_PARTY,500)
	ADD_TO_PARTY(AVATAR,DRUID,10,200,DEFEND_PARTY,500)
	ADD_TO_PARTY(AVATAR,KNIGHT,10,200,DEFEND_PARTY,500)
	ADD_TO_PARTY(AVATAR,KNIGHT,10,200,DEFEND_PARTY,500)
	ADD_TO_PARTY(AVATAR,KNIGHT,10,200,DEFEND_PARTY,500)
	ADD_TO_PARTY(AVATAR,KNIGHT,10,200,DEFEND_PARTY,500)
	ADD_TO_PARTY(AVATAR,AVATAR,10,2000,ATTACK_ENEMIES,500)

QUICK_OBJECTIVE(1,"Welcome Keeper your new Dungeon lies direktly under the surface. Therefore the entrance in the north will not only let monsters into your dungeon, but nosy adventurers as well. You may dig across grottos and the basements of the nearby village buildings in the east. You goal is to pluder and claim that village to lure the Lord of the Land into your deady Dungeon.",PLAYER0)
ENDIF

IF(PLAYER0,BRIDGE > 0)
	ROOM_AVAILABLE(PLAYER0,BRIDGE,1,1)
ENDIF

REM ***** BEGINN Adventurer Partys *****

REM check for entrance	
IF(PLAYER0,ENTRANCE > 0)
	SET_FLAG(PLAYER0,FLAG0,1)
	QUICK_INFORMATION(1,"You have claimed an entrance. Be caucious because not only monsters can enter your dungeon, but nosy adventurers as well.",PLAYER0)
ENDIF

REM after claiming the portal the play is given some time bevor the first adventureres arrive throu it
IF(PLAYER0,FLAG0 >= 1)
	SET_TIMER(PLAYER0,TIMER0)
		IF(PLAYER0,TIMER0 >= 5000)
		SET_FLAG(PLAYER_GOOD,FLAG0,1)
	ENDIF
ENDIF

REM First adventurer party arrives
IF(PLAYER_GOOD,FLAG0 >= 1)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ADVENTURE_A,-1,DUNGEON,0,1,500)
	SET_TIMER(PLAYER0,TIMER1)
	QUICK_INFORMATION(2,"The first adventurers have arrived, let's make sure they got a warm welcome.",PLAYER0)
	TUTORIAL_FLASH_BUTTON(37,-1)
ENDIF

REM Second adventurer party arrives
IF(PLAYER0,TIMER1 > 5000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ADVENTURE_B,-1,DUNGEON,0,1,500)
	QUICK_INFORMATION(3,"A stronger Party of self declared heros came though the portal.",PLAYER0)
	SET_TIMER(PLAYER0,TIMER2)
ENDIF

REM Third adventurer party arrives
IF(PLAYER0,TIMER2 > 5000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ADVENTURE_C,-1,DUNGEON,0,1,500)
	QUICK_INFORMATION(4,"Another Party enterd your Dungeon master. They seem well equiped and trained",PLAYER0)
	SET_TIMER(PLAYER0,TIMER3)
ENDIF

REM Forth Party arrives
IF(PLAYER0,TIMER3 > 5000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ADVENTURE_D,-1,DUNGEON,0,1,500)
	QUICK_INFORMATION(5,"A group of heros famous for their strengh and loyalty came from another village to challenge our monsters.",PLAYER0)
ENDIF

REM ***** END Adventurer Partys *****


REM ***** BEGIN Village Revenge *****

REM Create Thiefs if player enters Thiev Den
IF_ACTION_POINT(1,PLAYER0)
	SET_TIMER(PLAYER_GOOD,TIMER1)
	QUICK_INFORMATION(6,"You entered a Thief den, let's take their gold and give it to the poor .. meaning to our creatures.",PLAYER0)
ENDIF

IF(PLAYER_GOOD,TIMER1 > 10000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,THIEVES,1,DUNGEON,0,1,500)
	QUICK_INFORMATION(7,"The thiefs whom den we looted are here to claim what is unrightfully theirs..",PLAYER0)
ENDIF

REM Create Monks if player enters Graveyard
IF_ACTION_POINT(2,PLAYER0)
	SET_TIMER(PLAYER_GOOD,TIMER2)
	QUICK_INFORMATION(8,"We found a Crypt under der local curch. Let's perform some dark rituals to awaken a Vampire.",PLAYER0)
ENDIF

IF(PLAYER_GOOD,TIMER2 > 10000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,MONKS,2,DUNGEON,0,1,500)
	QUICK_INFORMATION(9,"The monks from the curch has formed a party to reclaim and cleanse the graveyard.",PLAYER0)
ENDIF

REM Create Dwarfs if player enters Mine
IF_ACTION_POINT(3,PLAYER0)
	SET_TIMER(PLAYER_GOOD,TIMER3)
	QUICK_INFORMATION(10,"We found a mine operated by Dwarfs, let's claim the gold and jewels for us bevore they send reinforcement from the village.",PLAYER0)
ENDIF

IF(PLAYER_GOOD,TIMER3 > 10000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,DWARVES,3,DUNGEON,0,1,500)
	QUICK_INFORMATION(11,"The dwarfs are comming to reclaim their digging rights in the norther mine.",PLAYER0)
ENDIF

REM Create Samurai if player enters Prison
IF_ACTION_POINT(7,PLAYER0)
	SET_TIMER(PLAYER_GOOD,TIMER4)
	QUICK_INFORMATION(12,"We broten into a prison and freed some Thiefs we'll garnt them refuge. But if the villagers found out, they may send someone to look for them.",PLAYER0)
ENDIF

IF(PLAYER_GOOD,TIMER4 > 10000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,JUSTICE,7,DUNGEON,0,1,500)
	QUICK_INFORMATION(13,"A group of justice came from the land of flat to recapture the theifs we granted asylum to.",PLAYER0)
ENDIF

REM Create Samurai if player enters Prison
IF_ACTION_POINT(8,PLAYER0)
	QUICK_INFORMATION(14,"We have fond the well of the village, perhaps we should poison it or something ..",PLAYER0)
ENDIF

REM ***** END Village Revenge *****



REM ***** Beginn TUNNELERS *****

REM If Player get to greedy send greedy dwarfs to souther tunnel
IF(PLAYER0,TOTAL_GOLD_MINED >= 80000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TUNNEL_GOLD,5,DUNGEON,0,1,500)
	QUICK_INFORMATION(15,"Some Heros got wind of your recent wealth. They are on the way but not though the Portal. I can hear them digging.",PLAYER0)
	TUTORIAL_FLASH_BUTTON(37,-1)
ENDIF

REM IF the Player reseaches LIGHTNING send Heros to norther tunnel
IF_AVAILABLE(PLAYER0,POWER_LIGHTNING == 1)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TUNNEL_SPELLS,6,DUNGEON,0,1,500)
	QUICK_INFORMATION(16,"Your recent acomplishments on the field of Dark Magic got some heroes interested. Instead of using the Porta, they seem to dig towards your dungeon.",PLAYER0)
	TUTORIAL_FLASH_BUTTON(37,-1)
ENDIF

REM ***** END TUNNELERS *****




REM ***** BEGINN Lord of the Land *****

REM The Elite arrives, after all other heros are dead
IF_CONTROLS(PLAYER_GOOD,TOTAL_CREATURES <= 0)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ELITE,4,DUNGEON,0,1,500)
	QUICK_INFORMATION(17,"You have sucessfully cleansed the earth of Villagers but they have already send for help. The troops of the nearest garnison will soon be here.",PLAYER0)
	SET_TIMER(PLAYER0,TIMER4)
ENDIF

REM Lord of the Land arrives, after all other heros are dead
IF(PLAYER0,TIMER4 > 100)
	IF_CONTROLS(PLAYER_GOOD,TOTAL_CREATURES <= 0)
		ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,LANDLORD,4,DUNGEON,0,1,500)
		QUICK_INFORMATION(18,"The garnisons Henchman lay down to your feed, but the villagers has ask the Lord of the Land for help. He is here to challenge you.",PLAYER0)
		SET_TIMER(PLAYER0,TIMER5)
	ENDIF
ENDIF

REM Check if the Landlord is dead
IF(PLAYER0,TIMER5 > 100)
	IF_CONTROLS(PLAYER_GOOD,TOTAL_CREATURES <= 0)
		DISPLAY_OBJECTIVE(40,PLAYER0)
		WIN_GAME
		QUICK_INFORMATION(19,"The Lord is utterly defeated and the village burns .. but there are rumors that a new hero has arisen from the fires .. maybe we should leave solang we still can.",PLAYER0)
		SET_TIMER(PLAYER0,TIMER6)
	ENDIF
ENDIF

REM send Avatar
IF(PLAYER0,TIMER6 > 100)
	IF_CONTROLS(PLAYER_GOOD,TOTAL_CREATURES <= 0)
		ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,AVATAR,8,DUNGEON,0,1,500)
		QUICK_INFORMATION(20,"The legendary Hero is here .. he just juped down the well .. if you plan to face him master thats finde .. I better run.",PLAYER0)
	ENDIF
ENDIF

REM ***** END Lord of the Land *****

IF(PLAYER0,DUNGEON_DESTROYED==1)
       LOSE_GAME
ENDIF



