


REM ######################################################
REM ######################################################


REM ### ACTION POINT 1 -	HERO SPAWN			NORTH ORIGINAL TUNNELLER
REM ### ACTION POINT 2 -	HERO SPAWN			WEST GRAVESITE	
REM ### ACTION POINT 3 -	PLAYER PORTAL		MESSAGE POINTER
REM ### ACTION POINT 4 -	SPAWN TRIGGER		EAST DUNGEON ENTRY
REM ### ACTION POINT 5 -	HERO SPAWN			EAST DUNGEON LAIR
REM ### ACTION POINT 6 -	HERO SPAWN			EAST DUNGEON LIBRARY
REM ### ACTION POINT 7 -	HERO SPAWN			EAST DUNGEON HATCHERY
REM ### ACTION POINT 8 -	SPAWN TRIGGER		EAST DUNGEON GUARDPOST
REM ### ACTION POINT 9 -	HERO SPAWN			EAST DUNGEON BARRACK
REM ### ACTION POINT 10 -	HERO SPAWN			EAST DUNGEON TRAINING + TRAINING ROOM MESSAGE DIRECT
REM ### ACTION POINT 11 -	HERO SPAWN			EAST DUNGEON WORKSHOP
REM ### ACTION POINT 12 -	HERO SPAWN			SOUTH-WEST PORTAL
REM ### ACTION POINT 13 -	PORTAL				SOUTH-WEST
REM ### ACTION POINT 14 -	SPAWN TRIGGER		WEST HALLWAY
REM ### ACTION POINT 15 -	REVEAL LOCATION		MIDDLE-WEST KARAOKE BAR
REM ### ACTION POINT 16 -	HERO SPAWN			WEST TREASURY
REM ### ACTION POINT 17 -	
REM ### ACTION POINT 18 -	REVEAL RECT			CENTER TRAINING
REM ### ACTION POINT 19 -	MESSAGE TRIGGER		WEST DUNGEON, NEAR AVATAR
REM ### ACTION POINT 20 -				
REM ### ACTION POINT 21 -				
REM ### ACTION POINT 22 -	PORTAL				NORTH-WEST UPPER, DRAGONS
REM ### ACTION POINT 23 -	PORTAL				NORTH-EAST
REM ### ACTION POINT 24 -	PORTAL				WEST DUNGEON, AVATAR
REM ### ACTION POINT 25 -	PORTAL				EAST DUNGEON
REM ### ACTION POINT 26 -	PORTAL				SOUTH ARCHER GUARDS
REM ### ACTION POINT 27 -	HERO SPAWN			NORTH SPIDER CAVE		

REM ### HERO GATE 1 -		DECORATIVE			EAST TREASURY

REM ### MESSAGE 1 -			INTRODUCTION
REM ### MESSAGE 2 -			REAL OBJECTIVE AND MAP REVEAL
REM ### MESSAGE 3 -			LEVEL 4 TRAINING RESTRICTION
REM ### MESSAGE 4 -			REVEAL TRAINING ROOM
REM ### MESSAGE 5 -			WITCH KARAOKE
REM ### MESSAGE 6 -			VICTORY
REM ### MESSAGE 7 -			LEVEL 6 TRAINING RESTRICTION
REM ### MESSAGE 8 -			HINT #1
REM ### MESSAGE 9 -			HINT #2
REM ### MESSAGE 10 -		HINT #3
REM ### MESSAGE 11 -		HINT #4
REM ### MESSAGE 12 -		HINT #5
REM ### MESSAGE 13 -		HINT #6
REM ### MESSAGE 14 -		INDIANA BONES
REM ### MESSAGE 15 -		AVATAR WARNING
REM ### MESSAGE 16 -		AVATAR SLAIN

REM ### P0 FLAG0 -			START TUNNELLER TIMER AS SOON AS PLAYER HAS BEGUN EXCAVATING // CHECKS WHEN LOTL SPAWNS // UPDATES TO CONTROL TRAINING ROOM GUIDANCE MESSAGE
REM ### P0 FLAG1 -			KARAOKE BAR REVEAL + MESSAGE AFTER DOOR COLLAPSE.

REM ### P0 TIMER0 -			INITIAL TUNNELLER AND HERO PARTIES // UPDATES TO CONTROL TRAINING ROOM MESSAGE // FINAL MESSAGE DELIVERY + WIN GAME
REM ###	P0 TIMER1 -			CHECKS IF LOTL IS DEAD AND BATTLES HAVE STOPPED
REM ### P0 TIMER2 -			FREE IMP RESPAWN UP TO 4
REM ### P0 TIMER3 -			SPECIAL 1, LOOPS QUICKLY TO APPLY HASTE
REM ### P0 TIMER4 - 		SPECIAL 2, SUMMONS HORNY FOR 30 SECONDS
REM ### P0 TIMER5 -			SPECIAL 3, LOOPS QUICKLY TO APPLY HEAL
REM ### P0 TIMER6 -			DISABLES SPECIAL 1 SO IT DOESN'T LOOP INDEFINITELY
REM ### P0 TIMER7 -			DISABLES SPECIAL 3 SO IT DOESN'T LOOP INDEFINITELY

REM ### P1 TIMER1 -			SENDS HINTS UPON PLAYER DEATH WITH SLIGHT DELAY


REM ### BOX0 -				GOLDEN IDOL
REM ### BOX1 -				V-TEC
REM ### BOX2 - 				AVATAR OF RAGE
REM ### BOX3 - 				HEALING RAIN



REM ######################################################
REM ######################################################


LEVEL_VERSION(1)

RUN_AFTER_VICTORY(1)

SET_GENERATE_SPEED(300)

START_MONEY(PLAYER0,2500)

MAX_CREATURES(PLAYER0,12)

SET_TEXTURE(PLAYER0,0)



REM ######################################################
REM ######################################################
REM ### GIVE WHITE DUNGEON A FAKE HEART THAT IS ATTACKABLE BY THE PLAYER, WON'T BE ATTACKED BY HEROES, AND DOESN'T REMOVE WHITE TERRITORY WHEN DESTROYED.
REM ### MODIFY VAMPIRE TO HAVE SPEED INSTEAD OF FLIGHT SO IT FITS THEMATICALLY WITH THE CUSTOM SPECIAL REWARD ###
REM ### DEFAULT TRAINING LEVEL 4.
REM ### WOOD DOOR IS ONLY WORKSHOP ITEM AVAILABLE, AND I REALLY DIDN'T THINK HE NEEDED HIS OWN SECTION.


ALLY_PLAYERS(PLAYER_GOOD,PLAYER1,3)
COMPUTER_PLAYER(PLAYER1,8)


SET_CREATURE_INSTANCE(VAMPIRE,2,SPEED,2)


SET_GAME_RULE(TRAININGROOMMAXLEVEL,4)


DOOR_AVAILABLE(PLAYER0,WOOD,1,0)


SET_CREATURE_PROPERTY(AVATAR,LORD,0)



REM ######################################################
REM ######################################################


ADD_CREATURE_TO_POOL(FLY,50)
ADD_CREATURE_TO_POOL(BUG,20)
ADD_CREATURE_TO_POOL(SPIDER,6)

CREATURE_AVAILABLE(PLAYER0,FLY,1,0)
CREATURE_AVAILABLE(PLAYER0,BUG,1,0)
CREATURE_AVAILABLE(PLAYER0,SPIDER,1,0)



REM ######################################################
REM ######################################################



ROOM_AVAILABLE(PLAYER0,TREASURE,1,1)
ROOM_AVAILABLE(PLAYER0,LAIR,1,1)
ROOM_AVAILABLE(PLAYER0,GARDEN,1,1)

ROOM_AVAILABLE(PLAYER0,RESEARCH,3,0)
ROOM_AVAILABLE(PLAYER0,WORKSHOP,3,0)



IF(PLAYER0,TRAINING > 1)
	QUICK_INFORMATION(3,"[One of your Imps has brought forward a notice of inspection regarding the recently acquired Training Room. It cites multiple critical safety violations, and more importantly, the inventory consists almost entirely of cardio equipment, and no squat rack. Until better facilities can be found, your creature's training will be restricted to level 4.]",18)
ENDIF


IF_SLAB_OWNER(34,53,PLAYER0)
	IF_SLAB_OWNER(74,48,PLAYER0)
		QUICK_INFORMATION(7,"Good news, Keeper. We've found another Training Room; Formerly owned by a lesser Keeper once referred to as Gold. Some great and powerful creatures once trained here. [Your creatures can now train up until level 6.]",10)
		SET_GAME_RULE(TRAININGROOMMAXLEVEL,6)
		ROOM_AVAILABLE(PLAYER0,TRAINING,1,1)
	ENDIF
ENDIF


	
REM ######################################################
REM ######################################################
REM ### IMP ONLY SPELL INITIALLY AVAILABLE, PLUS FREE IMP RESPAWN ###


MAGIC_AVAILABLE(PLAYER0,POWER_IMP,1,1)


SET_TIMER(PLAYER0,TIMER2)

IF(PLAYER0,TIMER2 >= 500)
	IF(PLAYER0,IMP <= 3)
		NEXT_COMMAND_REUSABLE
		USE_POWER_AT_LOCATION(PLAYER0,PLAYER0,POWER_IMP,1,1)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER0,TIMER2)
	ENDIF
ENDIF



REM ######################################################
REM ######################################################
REM ### WE DON'T WANT THESE GUYS TO LEAVE THEIR ROOMS ###


CREATE_PARTY(RAX)
ADD_TO_PARTY(RAX,ORC,10,0,DEFEND_LOCATION,0)
ADD_TO_PARTY(RAX,ORC,10,0,DEFEND_LOCATION,0)
ADD_TO_PARTY(RAX,DARK_MISTRESS,9,0,DEFEND_LOCATION,0)
ADD_TO_PARTY(RAX,HELL_HOUND,6,0,DEFEND_LOCATION,0)
ADD_TO_PARTY(RAX,HELL_HOUND,6,0,DEFEND_LOCATION,0)


CREATE_PARTY(LEGGIES)
ADD_TO_PARTY(LEGGIES,SPIDER,4,0,DEFEND_LOCATION,0)


CREATE_PARTY(SHELLIES)
ADD_TO_PARTY(SHELLIES,BUG,5,0,DEFEND_LOCATION,0)


CREATE_PARTY(AVATAR)
ADD_TO_PARTY(AVATAR,AVATAR,8,5000,DEFEND_LOCATION,0)


CREATE_PARTY(TRGIANT1)
CREATE_PARTY(TRBARB1)
CREATE_PARTY(TRDORF1)
CREATE_PARTY(TRTHIEF2)
CREATE_PARTY(TRARCH2)
CREATE_PARTY(TRKNIGHT1)


ADD_TO_PARTY(TRGIANT1,GIANT,1,0,DEFEND_ROOMS,0)
ADD_TO_PARTY(TRBARB1,BARBARIAN,1,0,DEFEND_ROOMS,0)
ADD_TO_PARTY(TRDORF1,DWARFA,1,0,DEFEND_ROOMS,0)
ADD_TO_PARTY(TRTHIEF2,THIEF,2,100,DEFEND_ROOMS,0)
ADD_TO_PARTY(TRARCH2,ARCHER,2,0,DEFEND_ROOMS,0)
ADD_TO_PARTY(TRKNIGHT1,KNIGHT,1,0,DEFEND_ROOMS,0)


CREATE_PARTY(GHASTLY)
ADD_TO_PARTY(GHASTLY,GHOST,3,0,DEFEND_LOCATION,0)
CREATE_PARTY(HAUNTER)
ADD_TO_PARTY(HAUNTER,GHOST,4,0,DEFEND_LOCATION,0)



REM ######################################################
REM ######################################################
REM ### TUNNELLER PARTIES ###


CREATE_PARTY(FIRST_TUNNEL)
ADD_TO_PARTY(FIRST_TUNNEL,THIEF,1,50,ATTACK_ENEMIES,0)
ADD_TO_PARTY(FIRST_TUNNEL,ARCHER,1,50,ATTACK_ENEMIES,0)

CREATE_PARTY(SECOND_TUNNEL)
ADD_TO_PARTY(SECOND_TUNNEL,DWARFA,1,80,ATTACK_ENEMIES,0)
ADD_TO_PARTY(SECOND_TUNNEL,ARCHER,1,50,ATTACK_ENEMIES,0)
ADD_TO_PARTY(SECOND_TUNNEL,THIEF,1,50,ATTACK_ENEMIES,0)
ADD_TO_PARTY(SECOND_TUNNEL,THIEF,1,50,ATTACK_ENEMIES,0)

CREATE_PARTY(MAGI)
ADD_TO_PARTY(MAGI,FAIRY,2,100,ATTACK_ENEMIES,0)
ADD_TO_PARTY(MAGI,TIME_MAGE,2,100,ATTACK_ENEMIES,0)
ADD_TO_PARTY(MAGI,WIZARD,,2,100,ATTACK_ENEMIES,0)
ADD_TO_PARTY(MAGI,WITCH,2,100,ATTACK_ENEMIES,0)

CREATE_PARTY(BRUISERS)
ADD_TO_PARTY(BRUISERS,BARBARIAN,1,150,ATTACK_ENEMIES,0)
ADD_TO_PARTY(BRUISERS,GIANT,1,150,ATTACK_ENEMIES,0)
ADD_TO_PARTY(BRUISERS,SAMURAI,1,150,ATTACK_ENEMIES,0)

CREATE_PARTY(LORD)
ADD_TO_PARTY(LORD,KNIGHT,1,200,ATTACK_ENEMIES,0)
ADD_TO_PARTY(LORD,MONK,1,150,ATTACK_ENEMIES,0)
ADD_TO_PARTY(LORD,MONK,1,150,ATTACK_ENEMIES,0)
ADD_TO_PARTY(LORD,ARCHER,2,100,ATTACK_ENEMIES,0)
ADD_TO_PARTY(LORD,WIZARD,2,100,ATTACK_ENEMIES,0)



REM ######################################################
REM ######################################################
REM ### START TUNNELLER COUNTDOWN AFTER PLAYER HAS BEGUN DIGGING AROUND ###


IF(PLAYER0,TOTAL_AREA >= 39)
	IF(PLAYER0,FLAG0 == 0)
		SET_FLAG(PLAYER0,FLAG0,1)
		SET_TIMER(PLAYER0,TIMER0)
	ENDIF
ENDIF

IF(PLAYER0,TOTAL_GOLD_MINED >= 1)
	IF(PLAYER0,FLAG0 == 0)
		SET_FLAG(PLAYER0,FLAG0,1)
		SET_TIMER(PLAYER0,TIMER0)
	ENDIF
ENDIF



REM ######################################################
REM ######################################################
REM ### TUNNELLER SPAWNS ###


IF(PLAYER0,TIMER0 >= 1800)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,FIRST_TUNNEL,1,DUNGEON_HEART,0,1,100)
ENDIF


IF(PLAYER0,TIMER0 >= 3000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,SECOND_TUNNEL,1,DUNGEON_HEART,0,1,100)
ENDIF


IF(PLAYER0,TIMER0 >= 4250)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MAGI,1,1)
ENDIF


IF(PLAYER0,TIMER0 >= 5250)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,BRUISERS,1,1)
ENDIF


IF(PLAYER0,TIMER0 >= 6500)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LORD,1,1)
	SET_CREATURE_PROPERTY(KNIGHT,LORD,0)
	SET_FLAG(PLAYER0,FLAG0,2)
ENDIF



REM ######################################################
REM ######################################################
REM ### CHECK IF PLAYER HAS KILLED KNIGHT - ENSURE KNIGHT'S PARTY IS DEAD AS WELL - REVEAL OBJECTIVE AND PORTAL LOCATIONS - TIMER0/FLAG0 FOR TRAINING ROOM REVEAL LATER ###


IF(PLAYER0,FLAG0 == 2)
	IF(PLAYER_GOOD,KNIGHT == 0)
		SET_TIMER(PLAYER0,TIMER1)
	ENDIF
ENDIF


IF(PLAYER0,TIMER1 >= 300)
	IF(PLAYER0,ACTIVE_BATTLES != 0)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER0,TIMER1)
	ENDIF
ENDIF


IF(PLAYER0,TIMER1 >= 500)
	QUICK_OBJECTIVE(2,"Celebrating so soon? You end the life of some bumbling drunkard in a tin-can and think yourself the victor? Not so, Keeper, not so. This realm houses seven shafts to deeper, distant locales of the subterrane; Seize them all so that we may spread our tendrils of influence farther across the realm.",3)
	REVEAL_MAP_LOCATION(PLAYER0,22,-1)
	REVEAL_MAP_LOCATION(PLAYER0,23,18)
	REVEAL_MAP_LOCATION(PLAYER0,24,-1)
	REVEAL_MAP_LOCATION(PLAYER0,25,18)
	REVEAL_MAP_LOCATION(PLAYER0,26,-1)
	REVEAL_MAP_LOCATION(PLAYER0,13,-1)
	ADD_CREATURE_TO_LEVEL(PLAYER0,IMP,PLAYER0,4,1,0)
	SET_TIMER(PLAYER0,TIMER0)
	SET_FLAG(PLAYER0,FLAG0,3)
ENDIF



REM ######################################################
REM ######################################################
REM ### BECAUSE CREATURE LIMIT


REM ##############################
REM ### DUNGEON LAIR
IF_ACTION_POINT(4,PLAYER0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,FLY,​5,2,​7,​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,FLY,​5,2,​6,​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,FLY,​5,4,​5,​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,BUG,​5,2,​6,​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,BUG,​5,2,​4,​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,SPIDER,​5,2,​6,​0)
ENDIF


REM ##############################
REM ### DUNGEON LIBRARY
IF_ACTION_POINT(5,PLAYER0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,SORCEROR,​6,1,​8,​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,SORCEROR,​6,1,​6,​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,DRAGON,​6,1,​6,​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,TENTACLE,6,2,​6,​0)
ENDIF


REM ##############################
REM ### DUNGEON HATCHERY
IF_ACTION_POINT(5,PLAYER0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,BILE_DEMON,​7,1,​5,​0)
ENDIF


REM ##############################
REM ### DUNGEON BARRACKS
IF_ACTION_POINT(8,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,RAX,9,1)
ENDIF


REM ##############################
REM ### DUNGEON TRAINING
IF_ACTION_POINT(8,PLAYER0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,DEMONSPAWN,​10,4,​6,​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,SKELETON,10,2,​7,​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,ORC,10,1,​6,​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,ORC,10,2,​5,​0)
ENDIF


REM ##############################
REM ### DUNGEON WORKSHOP
IF_ACTION_POINT(8,PLAYER0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,BILE_DEMON,11,1,7,​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,TROLL,11,6,9,​0)
ENDIF


REM ##############################
REM ### SOUTH-WEST
IF_ACTION_POINT(12,PLAYER0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,SAMURAI,13,3,​7,​0)
ENDIF


REM ##############################
REM ### SOUTH-EAST, NEAR ARCHER GUARDS
ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,BARBARIAN,26,2,4,​0)
ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,ARCHER,26,2,5,​0)
ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,DWARFA,26,3,3,​0)
ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,WIZARD,26,1,5,​0)
ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,WITCH,26,1,4,​0)


REM ##############################
REM ### WEST
IF_ACTION_POINT(14,PLAYER0)
	ADD_CREATURE_TO_LEVEL(​PLAYER_GOOD,DWARFA,16,7,4,​0)
ENDIF


REM ##############################
REM ### CENTRAL NORTH
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LEGGIES,27,2)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SHELLIES,27,5)


REM ##############################
REM ### PORTAL AVATAR
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,AVATAR,24,1)


REM ##############################
REM ### MIDDLE TRAINING ROOM
IF(PLAYER0,FLAG0 == 3)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TRGIANT1,18,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TRBARB1,18,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TRDORF1,18,2)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TRTHIEF2,18,2)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TRARCH2,18,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TRKNIGHT1,18,1)
ENDIF


REM ##############################
REM ### WEST GRAVESITE
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GHASTLY,2,3)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,HAUNTER,2,2)



REM ######################################################
REM ######################################################
REM ### CUSTOM SPECIAL BOXES -- TOOLTIP AND ACTION


REM ##################################
REM ### SPECIAL GUARDED BY VAMPIRE

SET_BOX_TOOLTIP(1, "V-TEC: Cast Vampiric Speed on all creatures, lasting 30 seconds.")

IF(PLAYER0,BOX1_ACTIVATED == 1)
	SET_TIMER(PLAYER0,TIMER3)
	SET_TIMER(PLAYER0,TIMER6)
ENDIF

IF(PLAYER0,TIMER3 >= 1)
	IF(PLAYER0,TIMER6 <= 300)
		NEXT_COMMAND_REUSABLE
		USE_POWER_ON_CREATURE(PLAYER0,ANY_CREATURE,ANYWHERE,PLAYER0,POWER_SPEED,9,1)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER0,TIMER3)
	ENDIF
ENDIF



REM ################################
REM ### SPECIAL GUARDED BY HORNY

SET_BOX_TOOLTIP(2, "Avatar of Rage: Summon a level 7 Horned Reaper for 30 seconds.")

IF(PLAYER0,BOX2_ACTIVATED == 1)
	SET_TIMER(PLAYER0,TIMER4)
	ADD_CREATURE_TO_LEVEL(PLAYER0,HORNY,LAST_EVENT,1,7,0)
ENDIF

IF(PLAYER0,TIMER4 >= 600)
	 KILL_CREATURE(​PLAYER0,HORNY,​ANYWHERE,2​)
ENDIF



REM ##################################
REM ### SPECIAL GUARDED BY FAIRIES

SET_BOX_TOOLTIP(3, "Healing Rain: Creatures have fast health regeneration for 45 seconds.")

IF(PLAYER0,BOX3_ACTIVATED == 1)
	SET_TIMER(PLAYER0,TIMER5)
	SET_TIMER(PLAYER0,TIMER7)
ENDIF

IF(PLAYER0,TIMER5 >= 1)
	IF(PLAYER0,TIMER7 <= 900)
		NEXT_COMMAND_REUSABLE
		USE_POWER_ON_CREATURE(PLAYER0,ANY_CREATURE,ANYWHERE,PLAYER0,POWER_HEAL_CREATURE,3,1)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER0,TIMER5)
	ENDIF
ENDIF



REM ##################################
REM ### SPECIAL GUARDED BY INDIANA BONES

SET_BOX_TOOLTIP(0, "Golden Idol: Increases gold reserves by 10,000.")

IF(PLAYER0,BOX0_ACTIVATED == 1)
	ADD_GOLD_TO_PLAYER(PLAYER0,10000)
ENDIF



REM ######################################################
REM ######################################################
REM ### AVATAR SPEECH WHEN PLAYER INITIATES FIGHT


IF_SLAB_TYPE(​23,37,PRETTY_PATH)
	PLAY_MESSAGE(PLAYER0,SPEECH,118)
ENDIF



REM ######################################################
REM ######################################################
REM ### WHAT IS DEFINITELY NOT A STRIP CLUB ANYMORE AND IS NOW A FAMILY FRIENDLY KARAOKE BAR.

IF_SLAB_TYPE(24,43,PRETTY_PATH)
	SET_FLAG(PLAYER0,FLAG1,1)
ENDIF

IF_SLAB_TYPE(21,39,PRETTY_PATH)
	SET_FLAG(PLAYER0,FLAG1,1)
ENDIF


IF(PLAYER0,FLAG1 == 1)
	REVEAL_MAP_LOCATION(PLAYER0,15,-1)
	QUICK_MESSAGE(5,"YOU GIVE LOOOVE A BAD NAME!",WITCH)
ENDIF



REM ######################################################
REM ######################################################
REM ### LOOSE MESSAGES


QUICK_OBJECTIVE(1,"This curious world sells itself as new, yet a strong sense of familiarity still lingers. Thoughts for another time, Keeper, as the delightful tick of rock and pick betray the approach of tunnelling Hero parties. Claim that portal, field your army and prepare for their arrival.",3)


IF(PLAYER0,FLAG0 == 3)
	IF(PLAYER0,TIMER0 >= 1750)
		QUICK_INFORMATION(4,"This handful of creepy crawlies you call an army wouldn't stand up to a kitchen broom let alone an outfit of mercenaries. If you intend your minions to fight sturdier foes, and not simply scuttle 'neath the nearest low cabinet, you'd be well advised to whip them into shape. Luckily for you, Keeper, the clunk and creak of age-old machinery resonates throughout our dungeon; a neighbouring hero Training Room. What convenience.",18)
		REVEAL_MAP_LOCATION(PLAYER0,18,-1)
	ENDIF
ENDIF


IF_SLAB_TYPE(​16,78,PRETTY_PATH)
	QUICK_MESSAGE(14,"INDIANA BONES: This belongs in a museum!",Skeleton)
ENDIF


IF_ACTION_POINT(19,PLAYER0)
	QUICK_INFORMATION(15,"Be mindful, Keeper, as a great warrior guards this portal. We seek only the Seven gateways of the realm, and as such, to see his death is no necessary evil. Oh, but how I would relish it..",24)
ENDIF


IF(PLAYER_GOOD,AVATAR == 0)
	QUICK_INFORMATION(16,"Well struck, Keeper! Their warrior falls!")
ENDIF



REM ####################################################################
REM ####################################################################
REM ### ANNOYINGLY GIVE PLAYERS ADVICE IF THEIR HEART GETS DESTROYED


IF(PLAYER0,DUNGEON_DESTROYED == 1)
	SET_TIMER(PLAYER1,TIMER1)
ENDIF


IF(PLAYER1,TIMER1 >= 100)
	QUICK_INFORMATION(8,"Build a big hatchery with your starting gold and manually force-feed your minions during battle to replenish their health. The utility of this action dwindles as your creatures gain a larger pool of health, but at early levels it is indispensable.")
ENDIF

IF(PLAYER1,TIMER1 >= 200)
	QUICK_INFORMATION(9,"Samurai hit hard, and with high accuracy. Giants hit even harder, but miss often. Learn to respect both of these opponents, and if they should team up, consider splitting them apart and fighting them separately.")
ENDIF

IF(PLAYER1,TIMER1 >= 300)
	QUICK_INFORMATION(10,"Spiders are your friend. They learn Slow at level 2, dramatically cutting the damage output of affected enemies. At level 4, they learn Freeze. With a handful of spiders, and a keen sense of timing, a wily Keeper can keep an enemy creature permanently frozen.")
ENDIF

IF(PLAYER1,TIMER1 >= 400)
	QUICK_INFORMATION(11,"Do you see the colourful shimmer boasted by many of the heroes? That is Rebound. Rebound reflects all incoming projectiles back toward the attacker. If time is by your side, bait your enemies into activating their Rebound, and then attack as it fizzles out.")
ENDIF

IF(PLAYER1,TIMER1 >= 500)
	QUICK_INFORMATION(12,"Blaze a trail. Seek the Northwest passage. Leave no stone unturned; No question unanswered. But untimely exploration can come at a cost. If your explorers should prove to be more of a headache than a help, keep them occupied by assigning them to guard duty.")
ENDIF

IF(PLAYER1,TIMER1 >= 600)
	QUICK_INFORMATION(13,"Give attention to the doors and entryways. Locked or unlocked, an enemy door will keep you out. A locked door however, is likely keeping something in. Similarly, no one of stature would tolerate a mousy entrance, and no common rabble would afford a door of rippling magic.")
ENDIF



REM ######################################################
REM ######################################################
REM ### WIN CONDITION


IF(PLAYER0,ENTRANCE == 63)
	SET_TIMER(PLAYER0,TIMER0)
ENDIF


IF(PLAYER0,ENTRANCE == 63)
	IF(PLAYER0,TIMER0 > 200)
		QUICK_INFORMATION(6,"The Seven gateways into this realm are secured. A commendable performance, Keeper. Now rally the minions! It's time to see where these gateways lead.")
		WIN_GAME
	ENDIF
ENDIF




