LEVEL_VERSION(1)

SET_GAME_RULE(MaxThingsInHand,32)
SET_GAME_RULE(ImpWorkExperience,300)

SET_GENERATE_SPEED(300)

SET_PLAYER_COLOR(PLAYER0,ORANGE)

START_MONEY(PLAYER0,20000)

MAX_CREATURES(PLAYER0,20)

ADD_CREATURE_TO_POOL(FLY,20)
ADD_CREATURE_TO_POOL(BUG,20)
ADD_CREATURE_TO_POOL(DEMONSPAWN,20)
ADD_CREATURE_TO_POOL(TROLL,20)
ADD_CREATURE_TO_POOL(SPIDER,20)
ADD_CREATURE_TO_POOL(SORCEROR,20)
ADD_CREATURE_TO_POOL(ORC,20)
ADD_CREATURE_TO_POOL(BILE_DEMON,20)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,20)

CREATURE_AVAILABLE(ALL_PLAYERS,FLY,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,BUG,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SPIDER,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,HELL_HOUND,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,ORC,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DRAGON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DARK_MISTRESS,1,0)

ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,BRIDGE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,PRISON,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GRAVEYARD,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,SCAVENGER,1,0)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_POSSESS,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DESTROY_WALLS,1,0)

TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,WORD_OF_POWER,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)

CREATE_PARTY(JILLIE)
ADD_TO_PARTY(JILLIE,MONK,4,4000,STEAL_SPELLS,0)
ADD_TO_PARTY(JILLIE,GIANT,4,4000,DEFEND_PARTY,0)
ADD_TO_PARTY(JILLIE,SAMURAI,4,4000,DEFEND_PARTY,0)
ADD_TO_PARTY(JILLIE,WIZARD,4,4000,STEAL_SPELLS,0)

CREATE_PARTY(VANILLIE)
ADD_TO_PARTY(VANILLIE,THIEF,6,6000,STEAL_GOLD,0)
ADD_TO_PARTY(VANILLIE,DWARFA,6,6000,STEAL_GOLD,0)
ADD_TO_PARTY(VANILLIE,ARCHER,6,6000,DEFEND_PARTY,0)
ADD_TO_PARTY(VANILLIE,MONK,6,6000,STEAL_SPELLS,0)

CREATE_PARTY(JHAMMY)
ADD_TO_PARTY(JHAMMY,WIZARD,8,8000,STEAL_SPELLS,0)
ADD_TO_PARTY(JHAMMY,TIME_MAGE,8,8000,STEAL_SPELLS,0)
ADD_TO_PARTY(JHAMMY,FAIRY,8,8000,STEAL_SPELLS,0)
ADD_TO_PARTY(JHAMMY,BARBARIAN,8,8000,DEFEND_PARTY,0)

CREATE_PARTY(WHAMMY)
ADD_TO_PARTY(WHAMMY,ARCHER,10,10000,ATTACK_ENEMIES,0)
ADD_TO_PARTY(WHAMMY,BARBARIAN,10,10000,ATTACK_ENEMIES,0)
ADD_TO_PARTY(WHAMMY,WIZARD,10,10000,STEAL_SPELLS,0)
ADD_TO_PARTY(WHAMMY,DWARFA,10,10000,STEAL_GOLD,0)

CREATE_PARTY(TENTIES)
ADD_TO_PARTY(TENTIES,TENTACLE,10,0,ATTACK_ENEMIES,0)
ADD_TO_PARTY(TENTIES,TENTACLE,10,0,ATTACK_ENEMIES,0)
ADD_TO_PARTY(TENTIES,TENTACLE,10,0,ATTACK_ENEMIES,0)

CREATE_PARTY(NUSCHA)
ADD_TO_PARTY(NUSCHA,GIANT,10,10000,DEFEND_PARTY,0)
ADD_TO_PARTY(NUSCHA,SAMURAI,10,10000,DEFEND_PARTY,0)
ADD_TO_PARTY(NUSCHA,WITCH,10,10000,STEAL_SPELLS,0)
ADD_TO_PARTY(NUSCHA,KNIGHT,10,100000,ATTACK_DUNGEON_HEART,0)

QUICK_OBJECTIVE(0,"Es gibt nur ein Ziel: Alle Helden vernichten und ihr Dungeon-Herz zum Schweigen bringen.",PLAYER_GOOD)

SET_FLAG(PLAYER_GOOD,FLAG0,0)

IF(PLAYER0,GAME_TURN>1000)
	QUICK_INFORMATION(1,"Ihr habt maximal 20 Kreaturen als Armee. Ihr wollt vielleicht einige Helden gefangennehmen und foltern, um Zuwachs zu bekommen.")
ENDIF

IF(PLAYER0,GAME_TURN>8000)
	QUICK_OBJECTIVE(2,"Die ersten Helden sind im Anmarsch. Bereitet Euch auf einen Durchbruch vor!",PLAYER_GOOD)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,JILLIE,-1,DUNGEON,0,4,4000)
ENDIF

IF(PLAYER0,GAME_TURN>13000)
	QUICK_OBJECTIVE(3,"Eine weitere Gruppe von Helden ist angekommen. Aufgepasst, Keeper!")
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,VANILLIE,-1,DUNGEON,0,6,6000)
ENDIF

IF(PLAYER0,GAME_TURN>18000)
	QUICK_OBJECTIVE(4,"Und noch eine Welle, diese ist noch erfahrener als die letzte. Seid auf der Hut, Meister!")
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,JHAMMY,-1,DUNGEON,0,8,8000)
ENDIF

IF(PLAYER0,GAME_TURN>23000)
	QUICK_OBJECTIVE(5,"Der Ritter ist bereits auf dem Weg hierher. Er schickt eine weitere Welle voraus.")	
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,WHAMMY,-1,DUNGEON,0,10,10000)
ENDIF

IF(PLAYER0,GAME_TURN>28000)
	QUICK_OBJECTIVE(6,"Es ist soweit. Bereitet dem Ritter und seiner Leibwache einen schnellen Tod!")	
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,NUSCHA,-1,DUNGEON,0,10,10000)
	SET_FLAG(PLAYER_GOOD,FLAG0,1)
ENDIF

IF(PLAYER0,TENTACLE>0)
	QUICK_INFORMATION(7,"Ein wildes Tentakel! Wo eins ist, sind vielleicht noch andere, aber vielleicht sind Euch nicht alle freundlich gesinnt ... Augen auf!")
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TENTIES,2,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TENTIES,3,1)
ENDIF

IF_ACTION_POINT(1,PLAYER0)
	QUICK_INFORMATION(8,"Das Dungeon-Herz der Helden liegt direkt vor Euch. Macht es dem Erdboden gleich, Herr der Schatten!")
ENDIF

IF(PLAYER0,ALL_DUNGEONS_DESTROYED==1)
	QUICK_OBJECTIVE(9,"Nur der Ritter steht zwischen Euch und dem totalen Erfolg. Bereitet euch auf seine Ankunft vor.")
ENDIF

IF(PLAYER_GOOD,FLAG0==1)
	IF(PLAYER_GOOD,KNIGHT==0)
	QUICK_OBJECTIVE(10,"Der Ritter stellt keine Gefahr mehr dar. Das Dungeon-Herz der Helden leuchtet aber nach wie vor. Knipst das Licht aus!")
	ENDIF
ENDIF

IF(PLAYER0,ALL_DUNGEONS_DESTROYED==1)
	IF(PLAYER_GOOD,FLAG0==1)
		IF(PLAYER_GOOD,KNIGHT==0)
			QUICK_INFORMATION(11,"Hervorragend! Der Ritter ist Geschichte und das Dungeon-Herz der Helden ist erstummt. Gute Arbeit, Meister!")
			WIN_GAME
		ENDIF
	ENDIF
ENDIF