


REM ######################################################
REM ######################################################


REM ACTION POINT 1 - PLAYER PORTAL (INTRODUCTION)
REM ACTION POINT 2 - HERO DUNGEON HEART (REVEAL INCENTIVE)
REM ACTION POINT 3 - HERO STOREROOM (BOULDER SCHEMATIC CHECK)
REM ACTION POINT 4 - MULTIPLY CREATURE (REVEAL INCENTIVE)
REM ACTION POINT 5 - HERO PRISON (REVEAL INCENTIVE)
REM ACTION POINT 6 - GEM CAVERN (REVEAL INCENTIVE)
REM ACTION POINT 7 - DRUID (CREATURE POSSE SPAWN)
REM ACTION POINT 8 - HERO LIBRARY (REVEAL INCENTIVE + RANDOMIZED DEFAULT SPECIAL)
REM ACTION POINT 9 - HERO WORKSHOP (BOULDER SCHEMATIC MESSAGE)
REM ACTION POINT 10 - IMPRISONED GIANT (REVEAL INCENTIVE)
REM ACTION POINT 11 - HERO DUNGEON HEART (TUNNELLER ENTRY - GETS STUCK IF SPAWNED ON AP2)
REM ACTION POINT 12 - HERO WORKSHOP (RANDOMIZED SPECIAL BOX + REVEAL INCENTIVE)
REM ACTION POINT 13 - TEMPLE (RANDOMIZED STATIONARY GUARDS)
REM ACTION POINT 14 - LOWER HERO FORTRESS (CUSTOM SPECIAL BOX SPAWN + HERO PARTY)
REM ACTION POINT 15 - TOP-RIGHT MOSSY TUNNELS (UNDEAD LOTTERY SPAWN)
REM ACTION POINT 16 - DRAGON ROOM (RANDOMIZED DEFAULT SPECIAL)
REM ACTION POINT 17 - REVEAL MAP (TILE CLAIM)
REM ACTION POINT 18 - TOP-RIGHT MOSSY TUNNELS (UNDEAD LOTTERY SPAWN)
REM ACTION POINT 19 - TOP-RIGHT MOSSY TUNNELS (UNDEAD LOTTERY SPAWN)


REM HERO GATE 1 - NORTH-WEST CASTLE
REM HERO GATE 2 - WEST CANDLE ROOM
REM HERO GATE 3 - SOUTH-WEST TEMPLE
REM HERO GATE 4 - SOUTH-WEST MINING CAMP
REM HERO GATE 5 - SOUTH-WEST MINING CAMP
REM HERO GATE 6 - SOUTH-EAST LAVA POOL
REM HERO GATE 7 - CENTER GUARD POSTS
REM HERO GATE 8 - EAST PRISON BARRACKS
REM HERO GATE 9 - NORTH-EAST FORT


REM MESSAGE 1 - LEVEL INTRODUCTION
REM MESSAGE 2 - DRUID MAP REVEAL
REM MESSAGE 3 - GOT BOULDER SCHEMATIC
REM MESSAGE 4 - FINAL WAVE COMING
REM MESSAGE 5 - FINAL WAVE
REM MESSAGE 6 - VICTORY
REM MESSAGE 7 - FIRST TUNNEL PARTY ALERT + MAIN OBJECTIVE
REM MESSAGE 8 - HINT #1
REM MESSAGE 9 - HINT #2
REM MESSAGE 10 - HINT #3
REM MESSAGE 11 - HINT #4
REM MESSAGE 12 - HINT #5


REM TIMER P0 T0 - MAIN PARTY SPAWN TIMER
REM TIMER P0 T1 - UNDERWORLD ARMISTICE
REM TIMER P0 T2 - TURNCOATS
REM TIMER P0 T3 - CIRCE'S
REM TIMER P0 T4 - CIRCE'S
REM TIMER P0 T5 - REVEAL MAP TUNNEL
REM TIMER P0 T6 - IMP RESPAWNER

REM TIMER PG T7 - HINTS

REM FLAG P0 F0 - BOULDER SCHEMATIC
REM FLAG P0 F1 - RANDOMIZE CUSTOM SPECIALS
REM FLAG P0 F2 - RANDOMIZE CUSTOM SPECIALS
REM FLAG P0 F3 - TURNCOATS BASIC
REM FLAG P0 F4 - TURNCOATS, HORNY EXCEPTION


REM BOX0 - UNDERWORLD ARMISTICE
REM BOX1 - TURNCOATS
REM BOX2 - CIRCE'S CONTEMPT
REM BOX3 - COUSIN ROMAN



REM ######################################################
REM ######################################################


LEVEL_VERSION(1)

SET_GENERATE_SPEED(300)

START_MONEY(PLAYER0,15000)

MAX_CREATURES(PLAYER0,25)

SET_TEXTURE(PLAYER0,SNAKE_KEY)



REM ######################################################
REM ######################################################
REM ### NO HORNY, SKELETON, GHOST, VAMPIRE.


ADD_CREATURE_TO_POOL(FLY,20)
ADD_CREATURE_TO_POOL(BUG,20)
ADD_CREATURE_TO_POOL(SPIDER,20)
ADD_CREATURE_TO_POOL(SORCEROR,20)
ADD_CREATURE_TO_POOL(DRUID,20)
ADD_CREATURE_TO_POOL(TROLL,20)
ADD_CREATURE_TO_POOL(ORC,10)
ADD_CREATURE_TO_POOL(TENTACLE,20)
ADD_CREATURE_TO_POOL(DEMONSPAWN,20)
ADD_CREATURE_TO_POOL(HELL_HOUND,10)
ADD_CREATURE_TO_POOL(DRAGON,10)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,8)
ADD_CREATURE_TO_POOL(BILE_DEMON,6)



REM ######################################################
REM ######################################################
REM ### NO HORNY, SKELETON, GHOST, VAMPIRE.
REM ### DRUID MADE AVAILABLE AFTER INTRO.


CREATURE_AVAILABLE(ALL_PLAYERS,FLY,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,BUG,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SPIDER,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,ORC,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,TENTACLE,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,HELL_HOUND,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DRAGON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DARK_MISTRESS,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,0)



REM ######################################################
REM ######################################################
REM ### NO BRIDGE, PRISON FOUND IN MAP.


ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GRAVEYARD,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,SCAVENGER,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,0)



REM ######################################################
REM ######################################################


DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)



REM ######################################################
REM ######################################################
REM ### NO LAVA.
REM ### BOULDER FOUND IN MAP.


TRAP_AVAILABLE(ALL_PLAYERS,ALARM,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,WORD_OF_POWER,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)



REM ######################################################
REM ######################################################
REM ### NO CAVE_IN, ARMAGEDDON.
REM ### CONCEAL, HEAL AND LIGHTNING FOUND IN MAP.


MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SIGHT,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_OBEY,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CHICKEN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DISEASE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DESTROY_WALLS,1,0)



REM ######################################################
REM ######################################################
REM ### TUNNELLING PARTIES.


REM ### FIRST TUNNEL - HERO GATE 5 - SOUTH-WEST MINING CAMP ###
CREATE_PARTY(TUN1)
ADD_TO_PARTY(TUN1,TUNNELLER,3,200,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN1,TUNNELLER,2,150,ATTACK_ENEMIES,150)


REM ### SECOND TUNNEL - HERO GATE 7 - CENTER GUARD POSTS ###
CREATE_PARTY(TUN2)
ADD_TO_PARTY(TUN2,ARCHER,3,150,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN2,ARCHER,3,150,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN2,BARBARIAN,2,125,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN2,DWARFA,2,75,ATTACK_ENEMIES,150)


REM ### THIRD TUNNEL - HERO GATE 3 - SOUTH-WEST TEMPLE ###
CREATE_PARTY(TUN3)
ADD_TO_PARTY(TUN3,FAIRY,4,75,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN3,FAIRY,4,75,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN3,FAIRY,3,75,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN3,MONK,3,150,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN3,MONK,2,150,ATTACK_ENEMIES,150)


REM ### FOURTH TUNNEL - HERO GATE 2 - WEST CANDLE ROOM ###
CREATE_PARTY(TUN4)
ADD_TO_PARTY(TUN4,WITCH,6,150,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN4,SORCEROR,5,250,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN4,SORCEROR,5,250,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN4,WIZARD,5,150,ATTACK_ENEMIES,150)


REM ### FIFTH TUNNEL - HERO GATE 8 - EAST PRISON BARRACKS ###
CREATE_PARTY(TUN5)
ADD_TO_PARTY(TUN5,ORC,6,450,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN5,ORC,5,450,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN5,TROLL,4,450,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN5,TROLL,4,450,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN5,BARBARIAN,4,300,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN5,BARBARIAN,4,300,ATTACK_ENEMIES,150)


REM ### SIXTH TUNNEL - HERO GATE 1 - NORTH-WEST CASTLE ###
CREATE_PARTY(TUN6)
ADD_TO_PARTY(TUN6,WIZARD,9,450,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN6,KNIGHT,8,500,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN6,SAMURAI,7,350,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN6,SAMURAI,7,350,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN6,MONK,7,350,ATTACK_ENEMIES,150)


REM ### SEVENTH TUNNEL - PLAYER_GOOD - HERO DUNGEON HEART ###
CREATE_PARTY(TUN7)
ADD_TO_PARTY(TUN7,WIZARD,10,450,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN7,SAMURAI,10,450,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN7,GIANT,10,550,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN7,ARCHER,10,450,ATTACK_ENEMIES,150)
ADD_TO_PARTY(TUN7,DWARFA,10,450,ATTACK_ENEMIES,150)



REM ######################################################
REM ######################################################
REM ### REGULAR PARTIES.


CREATE_PARTY(GUARDPOSTS1)
ADD_TO_PARTY(GUARDPOSTS1,THIEF,7,250,ATTACK_ENEMIES,150)
ADD_TO_PARTY(GUARDPOSTS1,BARBARIAN,6,200,ATTACK_ENEMIES,150)
ADD_TO_PARTY(GUARDPOSTS1,BARBARIAN,6,200,ATTACK_ENEMIES,150)
ADD_TO_PARTY(GUARDPOSTS1,ARCHER,5,150,ATTACK_ENEMIES,150)
ADD_TO_PARTY(GUARDPOSTS1,ARCHER,5,150,ATTACK_ENEMIES,150)


CREATE_PARTY(LAVAGATE1)
ADD_TO_PARTY(LAVAGATE1,DRAGON,5,300,ATTACK_ENEMIES,150)
ADD_TO_PARTY(LAVAGATE1,DRAGON,4,250,ATTACK_ENEMIES,150)
ADD_TO_PARTY(LAVAGATE1,DEMONSPAWN,4,0,ATTACK_ENEMIES,150)
ADD_TO_PARTY(LAVAGATE1,DEMONSPAWN,4,0,ATTACK_ENEMIES,150)
ADD_TO_PARTY(LAVAGATE1,DEMONSPAWN,3,0,ATTACK_ENEMIES,150)


CREATE_PARTY(SOUTHTEMPLE1)
ADD_TO_PARTY(SOUTHTEMPLE1,WITCH,8,300,ATTACK_ENEMIES,150)
ADD_TO_PARTY(SOUTHTEMPLE1,FAIRY,8,100,ATTACK_ENEMIES,150)
ADD_TO_PARTY(SOUTHTEMPLE1,MONK,7,200,ATTACK_ENEMIES,150)
ADD_TO_PARTY(SOUTHTEMPLE1,TENTACLE,5,0,ATTACK_ENEMIES,150)
ADD_TO_PARTY(SOUTHTEMPLE1,TENTACLE,5,0,ATTACK_ENEMIES,150)
ADD_TO_PARTY(SOUTHTEMPLE1,TENTACLE,5,0,ATTACK_ENEMIES,150)


CREATE_PARTY(HEROPRISON2)
ADD_TO_PARTY(HEROPRISON2,ORC,8,250,ATTACK_ENEMIES,150)
ADD_TO_PARTY(HEROPRISON2,ORC,8,250,ATTACK_ENEMIES,150)
ADD_TO_PARTY(HEROPRISON2,TROLL,6,200,ATTACK_ENEMIES,150)
ADD_TO_PARTY(HEROPRISON2,TROLL,6,200,ATTACK_ENEMIES,150)
ADD_TO_PARTY(HEROPRISON2,TROLL,6,200,ATTACK_ENEMIES,150)


CREATE_PARTY(CANDLEROOM)
ADD_TO_PARTY(CANDLEROOM,GIANT,8,400,ATTACK_ENEMIES,150)
ADD_TO_PARTY(CANDLEROOM,BILE_DEMON,8,400,ATTACK_ENEMIES,150)
ADD_TO_PARTY(CANDLEROOM,SORCEROR,8,350,ATTACK_ENEMIES,150)
ADD_TO_PARTY(CANDLEROOM,DARK_MISTRESS,7,450,ATTACK_ENEMIES,150)
ADD_TO_PARTY(CANDLEROOM,DARK_MISTRESS,7,450,ATTACK_ENEMIES,150)



REM ######################################################
REM ######################################################
REM ### SPECIAL PARTIES.


CREATE_PARTY(BURGLARS)
ADD_TO_PARTY(BURGLARS,THIEF,8,0,STEAL_GOLD,300)
ADD_TO_PARTY(BURGLARS,THIEF,7,0,STEAL_GOLD,300)
ADD_TO_PARTY(BURGLARS,THIEF,7,0,STEAL_GOLD,300)


CREATE_PARTY(TERMITES)
ADD_TO_PARTY(TERMITES,BUG,10,0,ATTACK_ROOMS,0)
ADD_TO_PARTY(TERMITES,BUG,10,0,ATTACK_ROOMS,0)
ADD_TO_PARTY(TERMITES,BUG,8,0,ATTACK_ROOMS,0)


CREATE_PARTY(IMPHUNTERS)
ADD_TO_PARTY(IMPHUNTERS,FAIRY,6,0,STEAL_GOLD,0)
ADD_TO_PARTY(IMPHUNTERS,FAIRY,6,0,STEAL_GOLD,0)


CREATE_PARTY(BOOKWORMS1)
ADD_TO_PARTY(BOOKWORMS1,DRAWFROM(WIZARD,SORCEROR,TIME_MAGE,DRUID),7,0,STEAL_SPELLS,0)
ADD_TO_PARTY(BOOKWORMS1,DRAWFROM(WIZARD,SORCEROR,TIME_MAGE,DRUID),7,0,STEAL_SPELLS,0)


CREATE_PARTY(BOOKWORMS2)
ADD_TO_PARTY(BOOKWORMS2,DRAWFROM(WIZARD,SORCEROR,TIME_MAGE,DRUID),7,0,STEAL_SPELLS,0)
ADD_TO_PARTY(BOOKWORMS2,DRAWFROM(WIZARD,SORCEROR,TIME_MAGE,DRUID),7,0,STEAL_SPELLS,0)



REM ######################################################
REM ######################################################
REM ### STATIONARY PARTY GUARDING THE SPECIAL BOX, AP14.


CREATE_PARTY(ANUNLIKELYTEAM)
ADD_TO_PARTY(ANUNLIKELYTEAM,SAMURAI,6,0,DEFEND_LOCATION,0)
ADD_TO_PARTY(ANUNLIKELYTEAM,DARK_MISTRESS,6,0,DEFEND_LOCATION,0)
ADD_TO_PARTY(ANUNLIKELYTEAM,SORCEROR,6,0,DEFEND_LOCATION,0)
ADD_TO_PARTY(ANUNLIKELYTEAM,VAMPIRE,6,1000,DEFEND_LOCATION,0)
ADD_TO_PARTY(ANUNLIKELYTEAM,HELL_HOUND,6,0,DEFEND_LOCATION,0)
ADD_TO_PARTY(ANUNLIKELYTEAM,DEMONSPAWN,6,0,DEFEND_LOCATION,0)


IF(PLAYER0,TIMER0 >= 10)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ANUNLIKELYTEAM,14,1)
ENDIF



REM ######################################################
REM ######################################################
REM ### RANDOMIZE DRUID'S STARTING POSSE.


IF(PLAYER0,DRUID >= 1)
	ADD_CREATURE_TO_LEVEL(PLAYER0,DRAWFROM(FLY,BUG,SPIDER,TENTACLE),7,1,DRAWFROM(1,2,3,4),0)
	ADD_CREATURE_TO_LEVEL(PLAYER0,DRAWFROM(FLY,BUG,SPIDER,TENTACLE),7,1,DRAWFROM(1,2,3,4),0)
	ADD_CREATURE_TO_LEVEL(PLAYER0,DRAWFROM(FLY,BUG,SPIDER,TENTACLE),7,1,DRAWFROM(1,2,3,4),0)
	ADD_CREATURE_TO_LEVEL(PLAYER0,DRAWFROM(FLY,BUG,SPIDER,TENTACLE),7,1,DRAWFROM(1,2,3,4),0)
	ADD_CREATURE_TO_LEVEL(PLAYER0,DRAWFROM(FLY,BUG,SPIDER,TENTACLE),7,1,DRAWFROM(1,2,3,4),0)
ENDIF



REM ######################################################
REM ######################################################
REM ### LOW-LEVEL SOMEWHAT RANDOMIZED UNDEAD IN TOP-RIGHT CORNER THAT WON'T MOVE TOO FAR.


CREATE_PARTY(UNDEADLOTTERY1)
ADD_TO_PARTY(UNDEADLOTTERY1,DRAWFROM(VAMPIRE,GHOST,SKELETON),DRAWFROM(1~3),0,DEFEND_LOCATION,10000)

CREATE_PARTY(UNDEADLOTTERY2)
ADD_TO_PARTY(UNDEADLOTTERY2,DRAWFROM(VAMPIRE,GHOST,SKELETON),DRAWFROM(1~3),0,DEFEND_LOCATION,10000)

CREATE_PARTY(UNDEADLOTTERY3)
ADD_TO_PARTY(UNDEADLOTTERY3,DRAWFROM(VAMPIRE,GHOST,SKELETON),DRAWFROM(1~3),0,DEFEND_LOCATION,10000)

CREATE_PARTY(UNDEADLOTTERY4)
ADD_TO_PARTY(UNDEADLOTTERY4,DRAWFROM(VAMPIRE,GHOST,SKELETON),DRAWFROM(1~3),0,DEFEND_LOCATION,10000)

CREATE_PARTY(UNDEADLOTTERY5)
ADD_TO_PARTY(UNDEADLOTTERY5,DRAWFROM(GHOST,SKELETON),DRAWFROM(1~3),0,DEFEND_LOCATION,10000)

CREATE_PARTY(UNDEADLOTTERY6)
ADD_TO_PARTY(UNDEADLOTTERY6,DRAWFROM(GHOST,SKELETON),DRAWFROM(1~3),0,DEFEND_LOCATION,10000)

CREATE_PARTY(JUSTSKELLIES1)
ADD_TO_PARTY(JUSTSKELLIES1,SKELETON,DRAWFROM(1,2),0,DEFEND_LOCATION,10000)

CREATE_PARTY(JUSTSKELLIES2)
ADD_TO_PARTY(JUSTSKELLIES2,SKELETON,DRAWFROM(1,2),0,DEFEND_LOCATION,10000)


IF(PLAYER0,TIMER0 >= 10)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,UNDEADLOTTERY1,DRAWFROM(15,18,19),1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,UNDEADLOTTERY2,DRAWFROM(15,18,19),1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,UNDEADLOTTERY3,DRAWFROM(15,18,19),1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,UNDEADLOTTERY4,DRAWFROM(15,18,19),1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,UNDEADLOTTERY5,DRAWFROM(15,18,19),1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,UNDEADLOTTERY6,DRAWFROM(15,18,19),1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,JUSTSKELLIES1,DRAWFROM(15,18,19),2)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,JUSTSKELLIES2,DRAWFROM(15,18,19),2)
ENDIF



REM ######################################################
REM ######################################################
REM ### MONKS WITH RANDOM LEVELS IN TOP-RIGHT CORNER.


CREATE_PARTY(CHERUBS1)
ADD_TO_PARTY(CHERUBS1,WITCH,DRAWFROM(3~7),0,DEFEND_HEART,10000)

CREATE_PARTY(CHERUBS2)
ADD_TO_PARTY(CHERUBS2,MONK,DRAWFROM(3~7),0,DEFEND_HEART,10000)

CREATE_PARTY(CHERUBS3)
ADD_TO_PARTY(CHERUBS3,MONK,DRAWFROM(3~6),0,DEFEND_HEART,10000)

CREATE_PARTY(CHERUBS4)
ADD_TO_PARTY(CHERUBS4,MONK,DRAWFROM(3~5),0,DEFEND_HEART,10000)

CREATE_PARTY(CHERUBS5)
ADD_TO_PARTY(CHERUBS5,MONK,DRAWFROM(3,4),0,DEFEND_HEART,10000)


IF(PLAYER0,TIMER0 >= 10)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHERUBS1,13,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHERUBS2,13,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHERUBS3,13,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHERUBS4,13,2)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CHERUBS5,13,2)
ENDIF

	
	
REM ######################################################
REM ######################################################


SET_TIMER(PLAYER0,TIMER0)


IF(PLAYER0,TIMER0 > 5500)
	QUICK_OBJECTIVE(7,"Well! It would seem we aren't welcome here; The local Lord has sent some of his cronies to evict us. If we are not wanted then we shall leave of our own accord, but not before we run this Lord through, and smash his pretty little Heart as well.",PLAYER_GOOD)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TUN1,-5,DUNGEON_HEART,0,3,100)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,-4,2,2,100)
	PLAY_MESSAGE(PLAYER0,SPEECH,125)
ENDIF


IF(PLAYER0,TIMER0 > 8000)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,-4,2,4,100)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DWARFA,-4,1,2,100)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,-4,2,2,100)
ENDIF


IF(PLAYER0,TIMER0 > 12000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TUN2,-7,DUNGEON_HEART,0,3,100)
ENDIF


IF(PLAYER0,TIMER0 > 16000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TUN3,-3,DUNGEON_HEART,0,4,150)
ENDIF


IF(PLAYER0,TIMER0 > 20000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LAVAGATE1,-6,1)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,-7,4,3,100)
ENDIF


IF(PLAYER0,TIMER0 > 25000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TUN4,-2,DUNGEON_HEART,0,5,200)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,TROLL,-8,2,6,150)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DRAGON,-6,2,6,250)
ENDIF


IF(PLAYER0,TIMER0 > 28000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TUN5,-8,DUNGEON_HEART,0,6,150)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TUN3,-3,1)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,HELL_HOUND,-6,3,5,0)
ENDIF


IF(PLAYER0,TIMER0 > 32000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LAVAGATE1,-6,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GUARDPOSTS1,-7,1)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,VAMPIRE,-9,1,7,500)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GHOST,-9,2,8,0)
ENDIF


IF(PLAYER0,TIMER0 > 37000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAWFROM(TERMITES,BURGLARS,IMPHUNTERS,BOOKWORMS1,BOOKWORMS2),DRAWFROM(-2,-3,-4,-7,-9),1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAWFROM(TERMITES,BURGLARS,IMPHUNTERS,BOOKWORMS1,BOOKWORMS2),DRAWFROM(-2,-3,-4,-7,-9),1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAWFROM(TERMITES,BURGLARS,IMPHUNTERS,BOOKWORMS1,BOOKWORMS2),DRAWFROM(-2,-3,-4,-7,-9),1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAWFROM(TERMITES,BURGLARS,IMPHUNTERS,BOOKWORMS1,BOOKWORMS2),DRAWFROM(-2,-3,-4,-7,-9),1)
ENDIF


IF(PLAYER0,TIMER0 > 41000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,HEROPRISON2,-8,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SOUTHTEMPLE1,-3,1)
ENDIF


IF(PLAYER0,TIMER0 > 48000)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TUN6,-1,DUNGEON_HEART,0,8,250)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SKELETON,-8,4,8,300)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GHOST,-9,4,8,0)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SPIDER,-8,2,10,0)
ENDIF


IF(PLAYER0,TIMER0 > 54000)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SKELETON,-8,2,10,300)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GHOST,-9,2,10,0)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DRAGON,-6,1,10,800)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,-2,1,10,500)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,TENTACLE,-3,2,10,0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAWFROM(BURGLARS,IMPHUNTERS),-5,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DRAWFROM(TERMITES,BOOKWORMS1,BOOKWORMS2),-7,1)
ENDIF


IF(PLAYER0,TIMER0 > 60000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SOUTHTEMPLE1,-3,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TUN6,-1,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LAVAGATE1,-6,1)
ENDIF


IF(PLAYER0,TIMER0 > 65000)
	QUICK_OBJECTIVE(4,"The din of a hundred clanking boots. It's the sound of their final muster, fast approaching. Either shore up the defences, set the boulders and cash in the relics, or push now, gut their Champion and shatter the Heart, before the reinforcements come flooding in. It's your decision to make, Keeper, but make it quick.",PLAYER_GOOD)
ENDIF


IF(PLAYER0,TIMER0 > 72000)
	QUICK_INFORMATION(5,"Their Champion approaches.",PLAYER_GOOD)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TUN7,11,DUNGEON_HEART,0,10,250)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CANDLEROOM,-2,1)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,-3,1,10,800)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DARK_MISTRESS,-2,2,10,400)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,VAMPIRE,-9,1,10,800)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,HORNY,-6,1,8,700)
ENDIF



REM ######################################################
REM ######################################################
REM ### GIVE PLAYER BOULDER SCHEMATICS FOR CLAIMING HERO WORKSHOP AND VISITING TRAP STOREROOM.


SET_FLAG(PLAYER0,FLAG0,0)

IF_ACTION_POINT(3,PLAYER0)
	SET_FLAG(PLAYER0,FLAG0,1)
ENDIF

IF(PLAYER_GOOD,WORKSHOP == 0)
	IF(PLAYER0,FLAG0 == 1)
		TRAP_AVAILABLE(PLAYER0,BOULDER,1,0)
		QUICK_INFORMATION(3,"Well done, Keeper. We possess both the tools and the plans to fashion our own supply of boulders. What terror they will feel when the very rock they themselves hewed comes thundering down the hall!",9)
	ENDIF
ENDIF



REM #######################################################
REM #######################################################
REM ### RANDOMLY SELECT INCREASE/RESURRECT/MAKE-SAFE, AP16 (DRAGON ROOM).
REM ### RANDOMLY SELECT INCREASE/RESURRECT/MAKE-SAFE, AP15 (LIBRARY).


IF(PLAYER0,TIMER0 >= 50)
	ADD_OBJECT_TO_LEVEL(DRAWFROM(SPECBOX_RESURCT,SPECBOX_INCLEV,SPECBOX_MKSAFE),16,1,PLAYER_NEUTRAL)
ENDIF

IF(PLAYER0,TIMER0 >= 50)
	ADD_OBJECT_TO_LEVEL(DRAWFROM(SPECBOX_RESURCT,SPECBOX_INCLEV,SPECBOX_MKSAFE),8,1,PLAYER_NEUTRAL)
ENDIF



REM ######################################################
REM ######################################################
REM ### CUSTOM SPECIALS SETUP.
REM ### GROUP1 = TURNCOATS // COUSIN ROMAN.
REM ### GROUP2 = UNDERWORLD ARMISTICE // CIRCE'S CONTEMPT


IF(PLAYER0,TIMER0 >= 50)
	RANDOMISE_FLAG(PLAYER0,FLAG1,2)
	RANDOMISE_FLAG(PLAYER0,FLAG2,2)
ENDIF



REM ######################################################
REM ######################################################
REM ### TURNCOATS BOX0.


SET_BOX_TOOLTIP(0,"TURNCOATS: Five enemy heroes unsheathe their weapons and attack their nearby friends. Surviving traitors, excluding Avatar and Horny, join your dungeon. Lose the ability to pick up any creature for 30 seconds.")

IF(PLAYER0,FLAG1 == 1)
	ADD_OBJECT_TO_LEVEL(SPECBOX_CUSTOM,14,0,PLAYER_NEUTRAL)
ENDIF

IF(PLAYER0,BOX0_ACTIVATED >= 1)
	SET_FLAG(PLAYER0,FLAG3,1)
	SET_TIMER(PLAYER0,TIMER2)
	PLAY_MESSAGE(PLAYER0,SPEECH,81)
	MAGIC_AVAILABLE(​PLAYER0,POWER_HAND,0,0)
ENDIF

IF(PLAYER0,FLAG3 >= 1)
	IF(PLAYER0,FLAG3 <= 3)
		IF(PLAYER0,TIMER2 >= 30)
			NEXT_COMMAND_REUSABLE
			CHANGE_CREATURE_OWNER(​PLAYER_GOOD,​ANY_CREATURE,ANYWHERE,PLAYER0)
			NEXT_COMMAND_REUSABLE
			ADD_TO_FLAG(PLAYER0,FLAG3,1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER0,FLAG3 >= 4)
	IF(PLAYER0,FLAG3 <= 5)
		IF(PLAYER0,TIMER2 >= 30)
			NEXT_COMMAND_REUSABLE
			CHANGE_CREATURE_OWNER(​PLAYER_GOOD,ANY_CREATURE,LEAST_EXPERIENCED,PLAYER0)
			NEXT_COMMAND_REUSABLE
			ADD_TO_FLAG(PLAYER0,FLAG3,1)
		ENDIF
	ENDIF
ENDIF



REM ######################################################
REM ######################################################
REM ### TURNCOATS BOX0 -- DISABLE HAND FOR 30 SECONDS.
REM ### IF PLAYER STEALS AVATAR, RETURN THEM TO HEROES AFTER 30 SECONDS.
REM ### IF PLAYER STEALS A HORNY, CHECK IF PLAYER_GOOD EVEN HAD A HORNY FIRST, AND THEN RETURN HORNY TO HEROES AFTERWARDS.


IF(PLAYER0,TIMER2 > 600)
	MAGIC_AVAILABLE(​PLAYER0,POWER_HAND,1,1)
ENDIF

IF(PLAYER0,TIMER2 >= 550)
	CHANGE_CREATURE_OWNER(​PLAYER0,AVATAR,ANYWHERE,PLAYER_GOOD)
ENDIF

IF(PLAYER0,TIMER2 >= 5)
	IF_CONTROLS(PLAYER_GOOD,HORNY >= 1)
		SET_FLAG(PLAYER0,FLAG4,1)
	ENDIF	
ENDIF	

IF(PLAYER0,TIMER2 >= 550)
	IF(PLAYER0,FLAG4 == 1)
		CHANGE_CREATURE_OWNER(​PLAYER0,HORNY,ANYWHERE,PLAYER_GOOD)
	ENDIF
ENDIF



REM ######################################################
REM ######################################################
REM ### COUSIN ROMAN BOX1.


SET_BOX_TOOLTIP(1,"COUSIN ROMAN: The druid invites his cousin to join the campaign; Recruit a dozen mid-level critters and one Warlock.")

IF(PLAYER0,FLAG1 == 2)
	ADD_OBJECT_TO_LEVEL(SPECBOX_CUSTOM,14,1,PLAYER_NEUTRAL)
ENDIF

IF(PLAYER0,BOX1_ACTIVATED >= 1)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRAWFROM(SPIDER,FLY,BUG,TENTACLE,DEMONSPAWN),​PLAYER0,​1,​​DRAWFROM(3~6),​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRAWFROM(SPIDER,FLY,BUG,TENTACLE,DEMONSPAWN),​PLAYER0,​1,​​DRAWFROM(3~6),​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRAWFROM(SPIDER,FLY,BUG,TENTACLE,DEMONSPAWN),​PLAYER0,​1,​​DRAWFROM(3~6),​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRAWFROM(SPIDER,FLY,BUG,TENTACLE,DEMONSPAWN),​PLAYER0,​1,​​DRAWFROM(3~6),​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRAWFROM(SPIDER,FLY,BUG,TENTACLE,DEMONSPAWN),​PLAYER0,​1,​​DRAWFROM(3~6),​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRAWFROM(SPIDER,FLY,BUG,TENTACLE,DEMONSPAWN),​PLAYER0,​1,​​DRAWFROM(3~6),​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRAWFROM(SPIDER,FLY,BUG,TENTACLE,DEMONSPAWN),​PLAYER0,​1,​​DRAWFROM(3~6),​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRAWFROM(SPIDER,FLY,BUG,TENTACLE,DEMONSPAWN),​PLAYER0,​1,​​DRAWFROM(3~6),​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRAWFROM(SPIDER,FLY,BUG,TENTACLE,DEMONSPAWN),​PLAYER0,​1,​​DRAWFROM(3~6),​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRAWFROM(SPIDER,FLY,BUG,TENTACLE,DEMONSPAWN),​PLAYER0,​1,​​DRAWFROM(3~6),​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRAWFROM(SPIDER,FLY,BUG,TENTACLE,DEMONSPAWN),​PLAYER0,​1,​​DRAWFROM(3~6),​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRAWFROM(SPIDER,FLY,BUG,TENTACLE,DEMONSPAWN),​PLAYER0,​1,​​DRAWFROM(3~6),​0)
	ADD_CREATURE_TO_LEVEL(​PLAYER0,DRUID,​PLAYER0,​1,​​DRAWFROM(5,6),​0)
	PLAY_MESSAGE(PLAYER0,SPEECH,75)
ENDIF



REM ######################################################
REM ######################################################
REM ### UNDERWORLD ARMISTICE BOX2.


SET_BOX_TOOLTIP(2,"UNDERWORLD ARMISTICE: Everyone throws down their weapons and embraces their old enemies as new-found friends.. For 45 seconds. Also delays future hero party attacks.")

IF(PLAYER0,FLAG2 == 1)
	ADD_OBJECT_TO_LEVEL(SPECBOX_CUSTOM,12,2,PLAYER_NEUTRAL)
ENDIF

IF(PLAYER0,BOX2_ACTIVATED >= 1)
	SET_TIMER(PLAYER0,TIMER1)
	ALLY_PLAYERS(PLAYER0,PLAYER_GOOD,3)
	ADD_TO_TIMER(PLAYER0,TIMER0,-2400)
	USE_POWER(PLAYER0,POWER_HOLD_AUDIENCE,1)
	PLAY_MESSAGE(PLAYER0,SPEECH,123)
ENDIF

IF(PLAYER0,TIMER1 >= 900)
	ALLY_PLAYERS(PLAYER0,PLAYER_GOOD,2)
ENDIF



REM ######################################################
REM ######################################################
REM ### CIRCE'S CONTEMPT BOX3.


SET_BOX_TOOLTIP(3,"CIRCE'S CONTEMPT: For 20 seconds, turn all enemy creatures within your territory to defenseless chickens.")

IF(PLAYER0,FLAG2 == 2)
	ADD_OBJECT_TO_LEVEL(SPECBOX_CUSTOM,12,3,PLAYER_NEUTRAL)
ENDIF

IF(PLAYER0,BOX3_ACTIVATED >= 1)
	SET_TIMER(PLAYER0,TIMER4)
	SET_TIMER(PLAYER0,TIMER3)
	PLAY_MESSAGE(PLAYER0,SPEECH,117)
ENDIF

IF(PLAYER0,TIMER4 >= 1)
	IF(PLAYER0,TIMER3 <= 400)
		NEXT_COMMAND_REUSABLE
		USE_SPELL_ON_CREATURE(PLAYER_GOOD,ANY_CREATURE,ON_ENEMY_GROUND,SPELL_CHICKEN,10)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER0,TIMER4)
	ENDIF
ENDIF



REM ######################################################
REM ######################################################
REM ### CHECK IF PLAYER HAS FOUND SECRET TUNNEL.
REM ### CHANGE SLAB WHEN PLAYER TOUCHES THE REVEAL MAP. 


IF_ACTION_POINT(17,PLAYER0)
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER0,TIMER5)
ENDIF

IF(PLAYER0,TIMER5 >= 50)
	NEXT_COMMAND_REUSABLE
	RESET_ACTION_POINT(17)
ENDIF

IF_SLAB_TYPE(​28,79,PATH)
	IF_ACTION_POINT(17,PLAYER0)
		CHANGE_SLAB_TYPE(​40,79,PRETTY_PATH)
		CHANGE_SLAB_OWNER(​40,79,PLAYER0)
		PLAY_MESSAGE(PLAYER0,SOUND,76)
	ENDIF
ENDIF

IF_SLAB_TYPE(​28,79,PRETTY_PATH)
	IF_ACTION_POINT(17,PLAYER0)
		CHANGE_SLAB_TYPE(​40,79,PRETTY_PATH)
		CHANGE_SLAB_OWNER(​40,79,PLAYER0)
		PLAY_MESSAGE(PLAYER0,SOUND,76)
	ENDIF
ENDIF



REM ######################################################
REM ######################################################
REM ### IMP RESPAWNER.

SET_TIMER(PLAYER0,TIMER6)
IF(PLAYER0,TIMER6 >= 500)
	IF(PLAYER0,IMP <= 3)
		NEXT_COMMAND_REUSABLE
		USE_POWER_AT_LOCATION(PLAYER0,PLAYER0,POWER_IMP,1,1)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER0,TIMER6)
	ENDIF
ENDIF



REM ####################################################################
REM ####################################################################
REM ### ANNOYINGLY GIVE PLAYERS ADVICE IF THEIR HEART GETS DESTROYED ###


RUN_AFTER_VICTORY(1)

IF(PLAYER0,DUNGEON_DESTROYED == 1)
	SET_TIMER(PLAYER_GOOD,TIMER7)
ENDIF

IF(PLAYER_GOOD,TIMER7 >= 100)
	QUICK_INFORMATION(8,"Be more afraid of staying still than of delving into the unknown. The nearby local gangs are weak and unprepared, and should prove no match for our new-found allies' herd of critters. Explore. Push back the veil of ignorance.")
ENDIF

IF(PLAYER_GOOD,TIMER7 >= 200)
	QUICK_INFORMATION(9,"Observe the points of interest on the map. Refine your strategy. An early prison would furnish your ranks with skeletons, or even potential converts. Well-placed boulder traps could stave off entire hero parties in one thundering onslaught. Hostaged creatures vengeful at their former jailors seek a new banner to rally under. Proactively acquire these boons, or be slowly overwhelmed.")
ENDIF

IF(PLAYER_GOOD,TIMER7 >= 300)
	QUICK_INFORMATION(10,"Mysterious boxes with curious abilities can be quick to turn the tide of battle. Be sure to read their inscriptions, as the winds of change are always blowing, and they may not be the same should you come around again.")
ENDIF

IF(PLAYER_GOOD,TIMER7 >= 400)
	QUICK_INFORMATION(11,"The beetles just want to eat your furniture; The magi love a good book; And the thieves know the chaos of battle is no better time to look for a score. They in themselves are a nuisance; But the Fairies? Keeper, do not underestimate the Fairies.")
ENDIF

IF(PLAYER_GOOD,TIMER7 >= 500)
	QUICK_INFORMATION(12,"If strength fails and cowardice prevails, you could try walling in the south and north-west castles. It would muffle the persistence of their attacks, at least partially, and provide some much needed time for respite.")
ENDIF



REM ######################################################
REM ######################################################
REM ### MESSAGES 


QUICK_OBJECTIVE(1,"Ahhh, do you hear it, Keeper? The patter of a hundred collective footsteps, moving to and fro; the distant moaning of the pious faithful, deep in prayer; the commotion of boisterous laughter reverberating from the taverns? Oh what delight it is to be in civilization again!",1)

REM ### SHOW LEVEL INCENTIVES WHEN PORTAL IS EXCAVATED ###
IF(PLAYER0,DRUID >= 1)
	CREATURE_AVAILABLE(ALL_PLAYERS,DRUID,1,0)
	QUICK_INFORMATION(2,"[You encounter a druid nursing a small hatch of assorted critters. You promise his brood safe sanctuary in exchange for his aid in your upcoming campaign, to which the druid nods delightedly. Prying loose a stone from the wall, the druid begins to etch a vague map into the cavern soil. After a time, the druid stands, pauses to stroke his beard, then circles some of the shapes and quietly hobbles away.]",PLAYER_GOOD)
	REVEAL_MAP_LOCATION(PLAYER0,2,18)
	REVEAL_MAP_LOCATION(PLAYER0,4,18)
	REVEAL_MAP_LOCATION(PLAYER0,6,18)
	REVEAL_MAP_LOCATION(PLAYER0,8,18)
	REVEAL_MAP_LOCATION(PLAYER0,10,18)
	REVEAL_MAP_LOCATION(PLAYER0,12,12)
	REVEAL_MAP_LOCATION(PLAYER0,14,18)
	REVEAL_MAP_LOCATION(PLAYER0,16,21)
ENDIF



REM ######################################################
REM ######################################################
REM ### WIN CONDITION ###


IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
	IF_CONTROLS(PLAYER_GOOD,AVATAR == 0)
		QUICK_INFORMATION(6,"You really know how to kill a party, Keeper. The ambient buzz of life once heard echoing through these halls has been replaced by the low buzz of flies crawling over its now dead and decaying inhabitants. It truly didn't have to be this way, but he forced our hand. So sad.",PLAYER_GOOD)
		WIN_GAME
	ENDIF
ENDIF

