REM ********************************************
REM *                                          *
REM *                Ashfordania               *
REM *                                Tim Daish *
REM ********************************************


REM **********     SETUP COMMANDS     **********


REM ***** Set the Generation Speed of the  *****
REM ***** Entrances                        *****

SET_GENERATE_SPEED(670)


REM ***** Set the computer player going   *****

REM		Player		Player Type

COMPUTER_PLAYER(PLAYER1, 10)

ALLY_PLAYERS(PLAYER0, PLAYER1)


REM ***** Set the maximum number of        *****
REM ***** creatures each player can have   *****

REM		Player		Number of creatures

MAX_CREATURES(	PLAYER0,	34)
MAX_CREATURES(	PLAYER1,	38)

SET_CREATURE_MAX_LEVEL(PLAYER0, TROLL, 5)
SET_CREATURE_MAX_LEVEL(PLAYER0, DEMONSPAWN, 9)
SET_CREATURE_MAX_LEVEL(PLAYER0, SORCEROR, 7)
SET_CREATURE_MAX_LEVEL(PLAYER0, DARK_MISTRESS, 6)
SET_CREATURE_MAX_LEVEL(PLAYER0, HELL_HOUND, 7)
SET_CREATURE_MAX_LEVEL(PLAYER0, IMP, 5)
SET_CREATURE_FEAR(IMP, 220)

REM ***** Set the amount of gold each      *****
REM ***** player starts with               *****

REM		Player		Amount of gold

START_MONEY(	PLAYER0,	17000)
START_MONEY(	PLAYER1,	28000)




REM **********       SET MAGIC        **********
REM **********     AND CREATURES      **********

REM ***** Setup the creature pool          *****

REM			Creature Name	Number of creatures

ADD_CREATURE_TO_POOL(	BUG,		4)
ADD_CREATURE_TO_POOL(	FLY,		5)
ADD_CREATURE_TO_POOL(	SPIDER,		6)
ADD_CREATURE_TO_POOL(	SORCEROR,	11)
ADD_CREATURE_TO_POOL(	DEMONSPAWN,	9)
ADD_CREATURE_TO_POOL(	DRAGON,		9)
ADD_CREATURE_TO_POOL(	TROLL,		7)
ADD_CREATURE_TO_POOL(	ORC,		8)
ADD_CREATURE_TO_POOL(	HELL_HOUND,	6)
ADD_CREATURE_TO_POOL(	DARK_MISTRESS,	7)
ADD_CREATURE_TO_POOL(	BILE_DEMON,	7)


REM ***** Enable each player to recieve    *****
REM ***** creatures from pool              *****
REM ***** except bile demon                *****

REM			Player		Creatures	Can be available	Is available

CREATURE_AVAILABLE(	ALL_PLAYERS,	BUG,		1,			1)
CREATURE_AVAILABLE(	ALL_PLAYERS,	FLY,		1,			1)
CREATURE_AVAILABLE(	ALL_PLAYERS,	SPIDER,		1,			1)
CREATURE_AVAILABLE(	PLAYER1,	SORCEROR,	1,			1)
CREATURE_AVAILABLE(	ALL_PLAYERS,	DEMONSPAWN,	1,			1)
CREATURE_AVAILABLE(	ALL_PLAYERS,	DRAGON,		1,			1)
CREATURE_AVAILABLE(	ALL_PLAYERS,	TROLL,		1,			1)
CREATURE_AVAILABLE(	ALL_PLAYERS,	ORC,		1,			1)
CREATURE_AVAILABLE(	ALL_PLAYERS,	HELL_HOUND,	1,			1)
CREATURE_AVAILABLE(	ALL_PLAYERS,	DARK_MISTRESS,	1,			1)
CREATURE_AVAILABLE(	PLAYER1,	BILE_DEMON,	1,			1)


REM ***** Set the rooms available to each  *****
REM ***** player                           *****

REM			Player		Room type	Can be available	Is available

ROOM_AVAILABLE(		ALL_PLAYERS,	TREASURE,	1,			1)
ROOM_AVAILABLE(		ALL_PLAYERS,	LAIR,		1,			1)
ROOM_AVAILABLE(		ALL_PLAYERS,	GARDEN,		1,			1)
ROOM_AVAILABLE(		ALL_PLAYERS,	TRAINING,	1,			1)
ROOM_AVAILABLE(		PLAYER1,	RESEARCH,	1,			1)
ROOM_AVAILABLE(		ALL_PLAYERS,	BRIDGE,		1,			0)
ROOM_AVAILABLE(		ALL_PLAYERS,	GUARD_POST,	1,			0)
ROOM_AVAILABLE(		PLAYER1,	WORKSHOP,	1,			0)
ROOM_AVAILABLE(		ALL_PLAYERS,	BARRACKS,	1,			0)
ROOM_AVAILABLE(		ALL_PLAYERS,	PRISON,		1,			0)
ROOM_AVAILABLE(		ALL_PLAYERS,	TORTURE,	1,			0)
ROOM_AVAILABLE(		ALL_PLAYERS,	TEMPLE,		1,			0)
ROOM_AVAILABLE(		PLAYER1, 	GRAVEYARD,	1,			0)
ROOM_AVAILABLE(		ALL_PLAYERS,	SCAVENGER,	1,			0)

REM ***** Set the doors available to each  *****
REM ***** player                           *****

REM			Player		Door type		Can be available	Is available

DOOR_AVAILABLE(		ALL_PLAYERS,	WOOD,			0,			0)
DOOR_AVAILABLE(		ALL_PLAYERS,	BRACED,			1,			0)
DOOR_AVAILABLE(		ALL_PLAYERS,	STEEL,			1,			0)
DOOR_AVAILABLE(		ALL_PLAYERS,	MAGIC,			1,			0)


REM ***** Set the traps available to each  *****
REM ***** player                           *****

REM			Player		Trap type		Can be available	Is available

TRAP_AVAILABLE(		ALL_PLAYERS,	BOULDER,		0,			0)
TRAP_AVAILABLE(		ALL_PLAYERS,	ALARM,			1,			0)
TRAP_AVAILABLE(		ALL_PLAYERS,	POISON_GAS,		1,			0)
TRAP_AVAILABLE(		ALL_PLAYERS,	LIGHTNING,		1,			0)
TRAP_AVAILABLE(		ALL_PLAYERS,	WORD_OF_POWER,		1,			0)
TRAP_AVAILABLE(		ALL_PLAYERS,	LAVA,			1,			0)


REM ***** Set the spells available to each *****
REM ***** player                           *****

REM			Player		Spell type		Can be available	Is available

MAGIC_AVAILABLE(	PLAYER1,	POWER_IMP,		1,			1)
MAGIC_AVAILABLE(	ALL_PLAYERS,	POWER_OBEY,		1,			0)
MAGIC_AVAILABLE(	PLAYER1,	POWER_SIGHT,		0,			0)
MAGIC_AVAILABLE(	ALL_PLAYERS,	POWER_CALL_TO_ARMS,	1,			0)
MAGIC_AVAILABLE(	ALL_PLAYERS,	POWER_CAVE_IN,		1,			0)
MAGIC_AVAILABLE(	PLAYER1,	POWER_HEAL_CREATURE,	1,			0)
MAGIC_AVAILABLE(	ALL_PLAYERS,	POWER_HOLD_AUDIENCE,	1,			0)
MAGIC_AVAILABLE(	PLAYER1,	POWER_LIGHTNING,	1,			0)
MAGIC_AVAILABLE(	PLAYER1,	POWER_SPEED,		1,			0)
MAGIC_AVAILABLE(	PLAYER1,	POWER_PROTECT,		1,			0)
MAGIC_AVAILABLE(	PLAYER1,	POWER_CONCEAL,		1,			0)
MAGIC_AVAILABLE(	PLAYER1,	POWER_CHICKEN,		1,			0)
MAGIC_AVAILABLE(	PLAYER1,	POWER_DESTROY_WALLS,	1,			0)





REM **********  ADJUST ANY CREATURE   **********
REM ********** OR RESEARCH STATISTICS **********

REM		Player		Research Type	Room or Spell		Research Value

RESEARCH(	ALL_PLAYERS,	ROOM,		BRIDGE,			9600)
RESEARCH(	ALL_PLAYERS,	MAGIC,		POWER_OBEY,		6000)
RESEARCH(	ALL_PLAYERS,	ROOM,		GUARD_POST,		11700)
RESEARCH(	ALL_PLAYERS,	MAGIC,		POWER_HEAL_CREATURE,	14000)
RESEARCH(	ALL_PLAYERS,	ROOM,		WORKSHOP,		77000)
RESEARCH(	ALL_PLAYERS,	MAGIC,		POWER_PROTECT,		15000)
RESEARCH(	ALL_PLAYERS,	MAGIC,		POWER_CONCEAL,		9400)
RESEARCH(	ALL_PLAYERS,	ROOM,		BARRACKS,		32000)
RESEARCH(	ALL_PLAYERS,	MAGIC,		POWER_CALL_TO_ARMS,	7400)
RESEARCH(	ALL_PLAYERS,	ROOM,		PRISON,			45000)
RESEARCH(	ALL_PLAYERS,	MAGIC,		POWER_SPEED,		5700)
RESEARCH(	ALL_PLAYERS,	ROOM,		TORTURE,		49000)
RESEARCH(	ALL_PLAYERS,	MAGIC,		POWER_HOLD_AUDIENCE,	11000)
RESEARCH(	ALL_PLAYERS,	ROOM,		TEMPLE,			55000)
RESEARCH(	ALL_PLAYERS,	MAGIC,		POWER_CAVE_IN,		25000)
RESEARCH(	ALL_PLAYERS,	ROOM,		GRAVEYARD,		65000)
RESEARCH(	ALL_PLAYERS,	MAGIC,		POWER_LIGHTNING,	35000)
RESEARCH(	ALL_PLAYERS,	ROOM,		SCAVENGER,		57500)
RESEARCH(	ALL_PLAYERS,	MAGIC,		POWER_CHICKEN,		20000)
RESEARCH(	PLAYER1,	MAGIC,		POWER_DESTROY_WALLS,	730000)



REM ***** Set up FLAGS and set to 0     *****

REM		Player		Flag Name	Flag's number

SET_FLAG(	PLAYER0,	FLAG0,		0)
SET_FLAG(	PLAYER0,	FLAG1,		0)
SET_FLAG(	PLAYER_GOOD,	FLAG1,		0)
SET_FLAG(       PLAYER1,        FLAG0,          0)
SET_FLAG(       PLAYER1,        FLAG1,          0)


REM ***** Set up TIMERS                    *****

REM		Player		Timer Name

SET_TIMER(	PLAYER0,	TIMER0)


REM ************* PARTIES ***************

CREATE_PARTY(ATTACK1)
ADD_TO_PARTY(ATTACK1, THIEF, 9, 250, ATTACK_ROOMS, 0)
ADD_TO_PARTY(ATTACK1, ARCHER, 10, 150, DEFEND_PARTY, 0)
ADD_TO_PARTY(ATTACK1, THIEF, 9, 250, ATTACK_ROOMS, 0)
ADD_TO_PARTY(ATTACK1, ARCHER, 10, 150, DEFEND_PARTY, 0)
ADD_TO_PARTY(ATTACK1, THIEF, 9, 250, ATTACK_ROOMS, 0)
ADD_TO_PARTY(ATTACK1, THIEF, 9, 250, ATTACK_ROOMS, 0)

CREATE_PARTY(THEBOYS1)
ADD_TO_PARTY(THEBOYS1, BARBARIAN, 9, 400, ATTACK_ROOMS,0)
ADD_TO_PARTY(THEBOYS1, BARBARIAN, 9, 400, ATTACK_ROOMS,0)
ADD_TO_PARTY(THEBOYS1, SAMURAI, 9, 700, DEFEND_PARTY,0)
ADD_TO_PARTY(THEBOYS1, THIEF, 9, 200, STEAL_SPELLS,0)
ADD_TO_PARTY(THEBOYS1, THIEF, 7, 900, ATTACK_ENEMIES,0)
ADD_TO_PARTY(THEBOYS1, THIEF, 6, 500, ATTACK_ENEMIES,0)

CREATE_PARTY(THEBOYS2)
ADD_TO_PARTY(THEBOYS2, ARCHER, 9, 700, ATTACK_ENEMIES,0)


CREATE_PARTY(HEROES1)
ADD_TO_PARTY(HEROES1, BARBARIAN, 10, 400, DEFEND_PARTY, 0)
ADD_TO_PARTY(HEROES1, BARBARIAN, 10, 400, ATTACK_ROOMS, 0)
ADD_TO_PARTY(HEROES1, SAMURAI, 10, 700, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(HEROES1, WIZARD, 10, 900, ATTACK_ROOMS, 0)
ADD_TO_PARTY(HEROES1, THIEF, 10, 200, STEAL_GOLD,0)
ADD_TO_PARTY(HEROES1, MONK, 10, 900, ATTACK_ROOMS, 0)

CREATE_PARTY(HEROES2)
ADD_TO_PARTY(HEROES2, WIZARD, 10, 500, ATTACK_ROOMS, 0)

CREATE_PARTY(HEROES3)
ADD_TO_PARTY(HEROES3, GIANT, 10, 400, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(HEROES3, WITCH, 10, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(HEROES3, DWARFA, 10, 100, DEFEND_PARTY,  0)
ADD_TO_PARTY(HEROES3, DWARFA, 10, 100, DEFEND_PARTY,  0)
ADD_TO_PARTY(HEROES3, SAMURAI, 10, 650, ATTACK_ROOMS,  0)
ADD_TO_PARTY(HEROES3, SAMURAI, 10, 650, ATTACK_ROOMS,  0)
ADD_TO_PARTY(HEROES3, SAMURAI, 10, 650, ATTACK_ROOMS,  0)

CREATE_PARTY(HEROES4)
ADD_TO_PARTY(HEROES4, WIZARD, 10, 530, ATTACK_ROOMS,  0)
ADD_TO_PARTY(HEROES4, WIZARD, 10, 660, ATTACK_ROOMS,  0)
ADD_TO_PARTY(HEROES4, WIZARD, 10, 660, ATTACK_ENEMIES,  0)
ADD_TO_PARTY(HEROES4, MONK, 10, 350, DEFEND_PARTY,  0)
ADD_TO_PARTY(HEROES4, MONK, 10, 350, ATTACK_ROOMS,  0)
ADD_TO_PARTY(HEROES4, MONK, 10, 350, ATTACK_ROOMS,  0)


CREATE_PARTY(HEROES5)
ADD_TO_PARTY(HEROES5, SAMURAI, 10, 650, ATTACK_ROOMS,  0)
ADD_TO_PARTY(HEROES5, GIANT, 10, 250, ATTACK_ROOMS,  0)
ADD_TO_PARTY(HEROES5, THIEF, 10, 350, STEAL_SPELLS,  0)
ADD_TO_PARTY(HEROES5, THIEF, 10, 100, STEAL_SPELLS,  0)
ADD_TO_PARTY(HEROES5, THIEF, 10, 100, STEAL_SPELLS,  0)
ADD_TO_PARTY(HEROES5, BARBARIAN, 10, 250, DEFEND_PARTY,  0)

CREATE_PARTY(HEROES6)
ADD_TO_PARTY(HEROES6, SAMURAI, 10, 650, ATTACK_ENEMIES,  0)
ADD_TO_PARTY(HEROES6, SAMURAI, 10, 650, ATTACK_ENEMIES,  0)
ADD_TO_PARTY(HEROES6, SAMURAI, 10, 750, ATTACK_ENEMIES,  0)
ADD_TO_PARTY(HEROES6, WITCH, 10, 450, ATTACK_ENEMIES,  0)
ADD_TO_PARTY(HEROES6, WITCH, 10, 450, ATTACK_ENEMIES,  0)
ADD_TO_PARTY(HEROES6, WITCH, 10, 450, ATTACK_ENEMIES,  0)
ADD_TO_PARTY(HEROES6, KNIGHT, 10, 900, ATTACK_ENEMIES,  0)

CREATE_PARTY(HEROES7)
ADD_TO_PARTY(HEROES7, GIANT, 10, 350, ATTACK_ENEMIES,  0)
ADD_TO_PARTY(HEROES7, BARBARIAN, 10, 350, ATTACK_ENEMIES,  0)
ADD_TO_PARTY(HEROES7, WITCH, 10, 350, ATTACK_DUNGEON_HEART,  0)
ADD_TO_PARTY(HEROES7, MONK, 10, 350, ATTACK_DUNGEON_HEART,  0)
ADD_TO_PARTY(HEROES7, DWARFA, 10, 350, ATTACK_DUNGEON_HEART,  0)
ADD_TO_PARTY(HEROES7, DWARFA, 10, 550, ATTACK_DUNGEON_HEART,  0)
ADD_TO_PARTY(HEROES7, KNIGHT, 10, 950, ATTACK_DUNGEON_HEART,  0)

CREATE_PARTY(HEROES8)
ADD_TO_PARTY(HEROES8, ARCHER, 10, 350, ATTACK_ENEMIES,  0)
ADD_TO_PARTY(HEROES8, WIZARD, 10, 350, ATTACK_ENEMIES,  0)
ADD_TO_PARTY(HEROES8, WIZARD, 10, 350, ATTACK_DUNGEON_HEART,  0)
ADD_TO_PARTY(HEROES8, WITCH, 10, 550, ATTACK_DUNGEON_HEART,  0)
ADD_TO_PARTY(HEROES8, SAMURAI, 10, 560, ATTACK_DUNGEON_HEART,  0)
ADD_TO_PARTY(HEROES8, SAMURAI, 10, 750, ATTACK_DUNGEON_HEART,  0)
ADD_TO_PARTY(HEROES8, KNIGHT, 10, 950, ATTACK_DUNGEON_HEART,  0)


REM **********      MAIN SCRIPT       **********


REM **********      IF COMMANDS       *******


IF(PLAYER0, TOTAL_CREATURES >= 50)
  MAGIC_AVAILABLE( PLAYER0, POWER_LIGHTNING, 1, 0)
ENDIF


IF(PLAYER0, BATTLES_WON > 50)
  SET_CREATURE_MAX_LEVEL(PLAYER0, IMP, 10)
  SET_CREATURE_MAX_LEVEL(PLAYER0, DARK_MISTRESS, 10)
  SET_CREATURE_MAX_LEVEL(PLAYER0, TROLL, 8)
  SET_CREATURE_MAX_LEVEL(PLAYER0, HELL_HOUND, 10)
  SET_CREATURE_MAX_LEVEL(PLAYER0, DEMONSPAWN ,10)
ENDIF


REM ** send in the boys to cause trouble
IF( PLAYER0, TIMER1 >= 19500)
  ADD_PARTY_TO_LEVEL(PLAYER_GOOD, THEBOYS1, -2, 1)
  ADD_PARTY_TO_LEVEL(PLAYER_GOOD, THEBOYS2, -2, 6)
  ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, THEBOYS1, -4, DUNGEON, 0, 8, 500)
ENDIF

IF(PLAYER0, WORKSHOP >  1)
  ROOM_AVAILABLE( PLAYER0, WORKSHOP, 1, 1)
  SET_CREATURE_FEAR(ARCHER ,20)
  SET_CREATURE_STRENGTH(ARCHER, 50)
ENDIF


IF(PLAYER0, BATTLES_LOST >= 15)
  SET_CREATURE_MAX_LEVEL(PLAYER0, HELL_HOUND, 10)
  SET_CREATURE_MAX_LEVEL(PLAYER0, SORCEROR, 10)
  SET_CREATURE_MAX_LEVEL(PLAYER0, BILE_DEMON, 10)
  SET_CREATURE_MAX_LEVEL(PLAYER0, DRAGON, 10)
ENDIF



IF(PLAYER0, RESEARCH > 4)
     ROOM_AVAILABLE(PLAYER0, RESEARCH, 1, 1)
ENDIF


REM ********** ACTION POINTS *********

IF_ACTION_POINT(4, PLAYER0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES1, -4, 1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES1, -3, 1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES2, -2, 7)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES3, -1, 1)
ENDIF

REM ***** PLAYER0 has triggered an action point at the rival keeper's heart *****
IF_ACTION_POINT(5, PLAYER0)
  SET_TIMER( PLAYER0, TIMER1)
  ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, SAMURAI, -3, 3, 9, 850)
ENDIF

IF_ACTION_POINT(7, PLAYER0)
   SET_FLAG( PLAYER0, FLAG1, 1)
ENDIF

IF_ACTION_POINT(7, PLAYER_GOOD)
   SET_FLAG( PLAYER_GOOD, FLAG1, 1)
ENDIF

IF_ACTION_POINT(10, PLAYER0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES6, 10, 1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES2, 14, 7)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES3, -5, 2)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES4, -4, 2)
    SET_TIMER(PLAYER0, TIMER2)
ENDIF

IF(PLAYER0,TIMER2>=1500)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES7, -3, 1)
ENDIF

IF(PLAYER0,TIMER2>=2750)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES8, -2, 1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES1, -1, 1)
ENDIF

IF_ACTION_POINT(11, PLAYER0)
  SET_CREATURE_MAX_LEVEL(PLAYER0, IMP, 9)
ENDIF


IF_ACTION_POINT(13, PLAYER0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, THEBOYS1, -2, 1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, THEBOYS2, -2, 6)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, THEBOYS1, -1, 1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, THEBOYS2, -1, 3)
ENDIF

IF_ACTION_POINT(14, PLAYER0)
    SET_CREATURE_FEAR(WITCH, 5)
    SET_CREATURE_FEAR(WIZARD, 5)
    SET_CREATURE_ARMOUR(DWARFA, 70)
    SET_CREATURE_ARMOUR(WITCH, 50)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, THEBOYS1, -4, 1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, THEBOYS2, -1, 6)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK1, -5, DUNGEON, 0, 9, 300)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES4, -3, DUNGEON, 0, 7, 230)
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES5, -1, DUNGEON, 0, 8, 330)
ENDIF


IF_ACTION_POINT(16, PLAYER0)
  ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK1, -1, DUNGEON, 0, 9, 300)
ENDIF



REM **********     OBJECTIVES AND     **********
REM **********      INFORMATION       **********

REM ******************* OBJECTIVE RELATED STATEMENTS ***************

REM ***** Starting objective               *****

REM	Objective Number	Objective Text (must be within quotes)	Player

QUICK_OBJECTIVE(0, "The Heroes in Ashfordania want to crush you to death. Find some willing creatures to join you in your quest. Beat a path to the hero's door, and make him beg for mercy, Oh Dark One!", PLAYER0)

IF(PLAYER0, GAME_TURN > 100)
  QUICK_INFORMATION(16, "You might find a little 'help' from the fellows to the East, but beware!")
ENDIF


REM **********      WIN AND LOSE      **********
REM ** WIN CRITERIA **

IF(PLAYER0, ALL_DUNGEONS_DESTROYED == 1)
   QUICK_OBJECTIVE(13, "Your minions have served you well, and you have led them to a glorious victory in Ashfordania. They surely deserve a bonus, and a rest before your next conquest!", PLAYER0)
   WIN_GAME
ENDIF

REM ******************* INFORMATION RELATED STATEMENTS *************

REM ***** PLAYER0 has reached the found the imps in the NW room *****
IF_ACTION_POINT(3, PLAYER0)
  QUICK_INFORMATION(1, "You might regret this little venture Westwards! Curb you explorations or else!")
  ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, SAMURAI, -1, 3, 7, 250)
  ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, THIEF, -1, 2, 8, 100)
  ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, THIEF, -1, 2, 8, 100)
  ADD_CREATURE_TO_LEVEL(PLAYER_GOOD, THIEF, -1, 2, 8, 100)
  SET_TIMER(PLAYER0, TIMER3)
ENDIF

IF(PLAYER0,TIMER3 >= 7200)
  ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES5, -1, DUNGEON, 0, 7, 500)
ENDIF

REM ***** Start timer when blue dungeon has built a workshop *****
IF(PLAYER1, WORKSHOP >= 1)
REM  QUICK_INFORMATION(2, "Blue dungeon has workshop")
  SET_TIMER( PLAYER1, TIMER1)
ENDIF

IF(PLAYER0,TIMER0 >= 15000)
  QUICK_INFORMATION(3, "The Heroes are forming quite an army. Prepare yourself well, Keeper.")
ENDIF

IF(PLAYER1,TIMER1 >= 2000)
  QUICK_INFORMATION(4, "Information has come to light that your allies have begun laying traps.")
ENDIF

REM ***** Send in the boys to defeat the blue dungeon if not conquered by red keeper *****
REM *****
IF( PLAYER1, TIMER1 >= 23500)
  IF( PLAYER0, FLAG1 == 0)
    QUICK_INFORMATION(6, "The Heroes are attacking your ally. Go over there and and give some support before it is too late!")
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, THEBOYS1, -2, 2)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, THEBOYS2, -4, 6)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, HEROES2, -2, 1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD, ATTACK1, -2, 1)
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD, -4, DUNGEON_HEART, 1, 9, 400)
  ENDIF
ENDIF

IF(PLAYER_GOOD, FLAG1 == 1)
  IF(PLAYER0, FLAG1 == 0)
    IF(PLAYER1, DUNGEON_DESTROYED == 1)
      QUICK_OBJECTIVE(15, "The Heroes have vanquished the other Keeper. Get over there now and try to salvage what you can before it is all destroyed.", PLAYER0)
    ENDIF
  ENDIF
ENDIF

IF_ACTION_POINT(15, PLAYER0)
  QUICK_OBJECTIVE(7, "You appear to have stumbled upon an old scroll containing the instructions for making a boulder trap. Set your creatures to work immediately,and use them well!", PLAYER0)
  TRAP_AVAILABLE(PLAYER0, BOULDER, 1, 0)
ENDIF

IF_ACTION_POINT(12, PLAYER0)
  QUICK_OBJECTIVE(8, "One of your creatures got bored and ate all of the instructions for making the traps! Pray you have laid enough traps already.", PLAYER0)
  TRAP_AVAILABLE(PLAYER0, BOULDER, 0, 0)
  TRAP_AVAILABLE(PLAYER0, LAVA, 0, 0)
  TRAP_AVAILABLE(PLAYER0, ALARM, 0, 0)
  TRAP_AVAILABLE(PLAYER0, POISON_GAS, 0, 0)
  TRAP_AVAILABLE(PLAYER0, LIGHTNING, 0, 0)
  TRAP_AVAILABLE(PLAYER0, WORD_OF_POWER, 0, 0)
ENDIF

IF_ACTION_POINT(6, PLAYER0)
  QUICK_INFORMATION(9, "You have found several imps willing to join your cause!")
ENDIF

REM this is an example of a correct IF_AVAILABLE statement
IF_AVAILABLE(PLAYER0, PRISON, ==, 1)
    QUICK_INFORMATION(10, "There's talk of many Heroes massing nearby. Make sure your prison is big enough to handle the influx.")
    ROOM_AVAILABLE(PLAYER0,GRAVEYARD,1,0)
ENDIF

IF_AVAILABLE(PLAYER0, POWER_IMP, ==, 0)
  IF(PLAYER0, TOTAL_IMPS == 0)
    QUICK_INFORMATION(12, "Your imps have not survived the onslaught! Be more careful with these 3 who have heard of your plight and come to join you.")
    NEXT_COMMAND_REUSABLE
    ADD_CREATURE_TO_LEVEL(PLAYER0, IMP, 7, 3, 4, 0)
  ENDIF
ENDIF


REM ***** Make power to create imp available, as a reward for defeating the enemy keeper *****
REM ***** Also power to build workshop, but not if heroes destroyed blue dungeon *****
IF(PLAYER0, FLAG1 == 1)
  IF( PLAYER1, TIMER1 < 33500)
    IF(PLAYER1, DUNGEON_DESTROYED == 1)
      IF_AVAILABLE(PLAYER0, POWER_IMP, ==, 0)
        MAGIC_AVAILABLE( PLAYER0, POWER_IMP, 1, 1)
        QUICK_INFORMATION(14, "Well done! As a little reward for turning upon your so-called friends, you have been given the power to create Imps. Keep them under control, or suffer the consequences.")
      ENDIF
    ENDIF
  ENDIF
ENDIF
