REM Bens Campaign level 1

LEVEL_VERSION(1)

SET_GENERATE_SPEED(400)
MAX_CREATURES(PLAYER0,12)
START_MONEY(PLAYER0,8000)

ADD_CREATURE_TO_POOL(BILE_DEMON,5)
ADD_CREATURE_TO_POOL(DARK_PRIEST,5)
ADD_CREATURE_TO_POOL(GOBLIN,2)

CREATURE_AVAILABLE(PLAYER0,BILE_DEMON,1,0)
CREATURE_AVAILABLE(PLAYER0,DARK_PRIEST,1,0)
CREATURE_AVAILABLE(PLAYER0,GOBLIN,1,0)

ROOM_AVAILABLE(PLAYER0,TREASURE,1,1)
ROOM_AVAILABLE(PLAYER0,GARDEN,1,1)
ROOM_AVAILABLE(PLAYER0,LAIR,1,1)
ROOM_AVAILABLE(PLAYER0,TRAINING,1,0)
ROOM_AVAILABLE(PLAYER0,BRIDGE,1,0)
ROOM_AVAILABLE(PLAYER0,RESEARCH,1,1)

MAGIC_AVAILABLE(PLAYER0,POWER_HAND,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_SLAP,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_IMP,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_SPEED,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_heal_creature,1,0)


DOOR_AVAILABLE(PLAYER0,WOOD,1,1)

CREATE_PARTY(ONE)
	ADD_TO_PARTY(ONE,FLYING_TERROR,7,500,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(ONE,FLYING_TERROR,7,500,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(ONE,FLYING_TERROR,7,500,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(TWO)
	ADD_TO_PARTY(TWO,SKELEMAGE,7,600,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(TWO,SKELEMAGE,7,400,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(TWO,TAURUS,7,400,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(TWO,TAURUS,7,800,ATTACK_ENEMIES,0)

CREATE_PARTY(THREE)
	ADD_TO_PARTY(THREE,TAURUS,8,1000,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(THREE,TAURUS,8,1000,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(THREE,VAMPIRE,7,800,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(THREE,VAMPIRE,7,800,ATTACK_ENEMIES,0)

CREATE_PARTY(FOUR)
	ADD_TO_PARTY(FOUR,SAMURAI,10,1000,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(FOUR,SAMURAI,10,1000,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(FOUR,SAMURAI,10,1000,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(FOUR,SAMURAI,10,1000,ATTACK_ENEMIES,0)

CREATE_PARTY(FINAL)
	ADD_TO_PARTY(FINAL,ARCHER,10,1000,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(FINAL,ARCHER,10,1000,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(FINAL,GIANT,10,2000,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(FINAL,GIANT,10,2000,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(FINAL,BARBARIAN,10,2000,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(FINAL,BARBARIAN,10,2000,ATTACK_DUNGEON_HEART,0)

SET_GAME_RULE(ImpWorkExperience,254)

SET_CREATURE_PROPERTY(GUARD,NO_IMPRISONMENT,1)

SET_CREATURE_CONFIGURATION(DARK_MISTRESS,HungerRate,0)
SET_CREATURE_CONFIGURATION(DARK_MISTRESS,LairSize,0)
SET_CREATURE_CONFIGURATION(DARK_MISTRESS,Sleep,0)
SET_CREATURE_CONFIGURATION(DARK_MISTRESS,Pay,0)

REM "This realm is ruled by King Arthur and his Son Tyrael. You'll have to fight hard to gain any advantages. Capture and convert his son to conquer this Kingdom, we'll need him for our further ambitions. The first way to go is to the Portal, make sure you can attract the right creatures from the start."
DISPLAY_OBJECTIVE(1,ALL_PLAYERS)

IF_ACTION_POINT(1,PLAYER0)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ONE,-3,DUNGEON,0,2,600)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvlspe03.mp3")
ENDIF

IF_ACTION_POINT(2,PLAYER0)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,THREE,-5,DUNGEON,0,2,600)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvlspe11.mp3")
ENDIF

IF_ACTION_POINT(4,PLAYER0)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvlspe30.mp3")
ENDIF

IF_ACTION_POINT(5,PLAYER0)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,FOUR,-2,DUNGEON,0,2,600)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvlspe27.mp3")
ENDIF

IF_ACTION_POINT(7,player0)
	SET_TIMER(PLAYER0,TIMER0)
  	PLAY_MESSAGE(PLAYER0,SPEECH,"lvlspe01.mp3")
ENDIF

IF_ACTION_POINT(8,player0)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvlspe29.mp3")
	SET_TIMER(PLAYER0,TIMER1)
ENDIF

IF(PLAYER0,TIMER0 == 210)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TWO,-1,DUNGEON,0,2,600)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvlspe02.mp3")
ENDIF

IF(PLAYER0,TIMER1 == 210)
  	PLAY_MESSAGE(PLAYER0,SPEECH,"lvlspe31.mp3")
ENDIF

IF_ACTION_POINT(3,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,final,8,1)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvlspe26.mp3")
ENDIF

IF(PLAYER_GOOD, KNIGHT == 0)
	IF(PLAYER0, KNIGHT == 0)
			REM "Prince Tyrael died."
			DISPLAY_OBJECTIVE(2,ALL_PLAYERS)
		lose_game
	ENDIF
ENDIF

IF(PLAYER0, KNIGHT == 1)
	PLAY_MESSAGE(PLAYER0,SPEECH,"hello.mp3")
ENDIF

USE_POWER_AT_LOCATION(PLAYER0,9,POWER_SIGHT,7,1)

IF(PLAYER_GOOD, GUARD == 0)
	IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
		IF(PLAYER0, KNIGHT == 1)
			REM "Well done. You have destroyed the heart and converted Prince Tyrael, he will follow us into the next Realm."
			DISPLAY_OBJECTIVE(3,ALL_PLAYERS)
			WIN_GAME
		ENDIF
	ENDIF
ENDIF
