LEVEL_VERSION(1)

REM -------------------------------------------------------------------------------------------------------------------------------------------

SET_GENERATE_SPEED(600)

COMPUTER_PLAYER(PLAYER3,2)

START_MONEY(ALL_PLAYERS,1000)

MAX_CREATURES(PLAYER1,8)
MAX_CREATURES(PLAYER3,12)

ALLY_PLAYERS(PLAYER1,PLAYER3,1)

QUICK_MESSAGE(0, "Blue Tempest, I submit to your cause.", PLAYER3)

ADD_HEART_HEALTH(PLAYER1,-15000,0)

SET_CREATURE_HEALTH(GIANT,2000)

SET_PLAYER_MODIFIER(PLAYER3,Health,50)

ADD_CREATURE_TO_POOL(TROLL,20)
ADD_CREATURE_TO_POOL(DEMONSPAWN,20)
ADD_CREATURE_TO_POOL(FLY,20)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,1)
ADD_CREATURE_TO_POOL(SORCEROR,20)
ADD_CREATURE_TO_POOL(BUG,10)
ADD_CREATURE_TO_POOL(SPIDER,10)
ADD_CREATURE_TO_POOL(HELL_HOUND,4)

CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,FLY,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,BUG,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DARK_MISTRESS,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SPIDER,1,0)
CREATURE_AVAILABLE(PLAYER3,HELL_HOUND,1,0)

SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,IMP,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,TROLL,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,DEMONSPAWN,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,FLY,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,BUG,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,DARK_MISTRESS,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,SORCEROR,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,SPIDER,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,HELL_HOUND,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,THIEF,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,ARCHER,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,DWARFA,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,FAIRY,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,WIZARD,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,MONK,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,GIANT,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,BARBARIAN,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,WITCH,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,GHOST,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,TENTACLE,5)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,DRAGON,7)
SET_CREATURE_MAX_LEVEL(PLAYER_GOOD,KNIGHT,6)

REM CREATURES FEAR
SET_CREATURE_FEAR_WOUNDED(FLY,35)
SET_CREATURE_FEAR_WOUNDED(BUG,35)
SET_CREATURE_FEAR_WOUNDED(TROLL,35)
SET_CREATURE_FEAR_WOUNDED(DEMONSPAWN,35)
SET_CREATURE_FEAR_WOUNDED(SORCEROR,35)
SET_CREATURE_FEAR_WOUNDED(DARK_MISTRESS,35)
SET_CREATURE_FEAR_WOUNDED(SPIDER,35)
SET_CREATURE_FEAR_WOUNDED(HELL_HOUND,35)
SET_CREATURE_FEAR_WOUNDED(TENTACLE,35)
SET_CREATURE_FEAR_WOUNDED(DRAGON,35)

ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)

DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,ALARM,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)

MAGIC_AVAILABLE(PLAYER3,POWER_SIGHT,1,1)
MAGIC_AVAILABLE(PLAYER3,POWER_CALL_TO_ARMS,1,1)
MAGIC_AVAILABLE(PLAYER1,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_POSSESS,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(PLAYER1,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HOLD_AUDIENCE,1,0)

REM -------------------------------------------------------------------------------------------------------------------------------------------

CREATE_PARTY(FIRST_GIANT1)
    ADD_TO_PARTY(FIRST_GIANT1,GIANT,2,250,ATTACK_DUNGEON_HEART,1000)

CREATE_PARTY(FIRST_GIANT2)
    ADD_TO_PARTY(FIRST_GIANT2,GIANT,3,250,ATTACK_ENEMIES,20000)

CREATE_PARTY(FIRST_GIANT3)
    ADD_TO_PARTY(FIRST_GIANT3,GIANT,2,250,ATTACK_ROOMS,10000)

CREATE_PARTY(FAIRY_GUARD4)
    ADD_TO_PARTY(FAIRY_GUARD4,FAIRY,4,150,DEFEND_LOCATION,10000)

CREATE_PARTY(GIANT_GUARD4)
	ADD_TO_PARTY(GIANT_GUARD4,GIANT,4,250,DEFEND_LOCATION,10000)

CREATE_PARTY(GIANT_SABOTEUR)
	    ADD_TO_PARTY(GIANT_SABOTEUR,GIANT,4,250,ATTACK_ROOMS,0)

CREATE_PARTY(GIANT_SNIPER)
	    ADD_TO_PARTY(GIANT_SNIPER,GIANT,4,250,SNIPE_DUNGEON_HEART,0)

CREATE_PARTY(DEFENDERS)
    ADD_TO_PARTY(DEFENDERS,GIANT,4,200,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(DEFENDERS,GIANT,4,200,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(DEFENDERS,ARCHER,5,100,DEFEND_PARTY,0)

CREATE_PARTY(LORD)
    ADD_TO_PARTY(LORD,WIZARD,5,500,STEAL_SPELLS,1500)
    ADD_TO_PARTY(LORD,KNIGHT,6,5000,ATTACK_DUNGEON_HEART,1500)
    ADD_TO_PARTY(LORD,MONK,5,400,STEAL_GOLD,1500)
    ADD_TO_PARTY(LORD,ARCHER,5,300,DEFEND_PARTY,1500)
    ADD_TO_PARTY(LORD,GIANT,5,200,ATTACK_ROOMS,1500)
    ADD_TO_PARTY(LORD,GIANT,5,200,ATTACK_ROOMS,1500)

CREATE_PARTY(TITAN)
    ADD_TO_PARTY(TITAN,GIANT,10,2500,DEFEND_HEART,1000)

REM -------------------------------------------------------------------------------------------------------------------------------------------

REM Music

RANDOMISE_FLAG(PLAYER_NEUTRAL,FLAG1,7)

IF(PLAYER_NEUTRAL,FLAG0 == 0)
	IF(PLAYER_NEUTRAL,FLAG1 == 1)
		IF(PLAYER1,ACTIVE_BATTLES >= 1)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("battle01.mp3")
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_NEUTRAL,TIMER0)
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER_NEUTRAL,FLAG0,1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_NEUTRAL,FLAG0 == 0)
	IF(PLAYER_NEUTRAL,FLAG1 == 2)
		IF(PLAYER1,ACTIVE_BATTLES >= 1)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("battle02.mp3")
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_NEUTRAL,TIMER0)
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER_NEUTRAL,FLAG0,1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_NEUTRAL,FLAG0 == 0)
	IF(PLAYER_NEUTRAL,FLAG1 == 3)
		IF(PLAYER1,ACTIVE_BATTLES >= 1)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("battle03.mp3")
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_NEUTRAL,TIMER0)
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER_NEUTRAL,FLAG0,1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_NEUTRAL,FLAG0 == 0)
	IF(PLAYER_NEUTRAL,FLAG1 == 4)
		IF(PLAYER1,ACTIVE_BATTLES >= 1)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("battle04.mp3")
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_NEUTRAL,TIMER0)
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER_NEUTRAL,FLAG0,1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_NEUTRAL,FLAG0 == 0)
	IF(PLAYER_NEUTRAL,FLAG1 == 5)
		IF(PLAYER1,ACTIVE_BATTLES >= 1)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("01. Theme.mp3")
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_NEUTRAL,TIMER0)
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER_NEUTRAL,FLAG0,1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_NEUTRAL,FLAG0 == 0)
	IF(PLAYER_NEUTRAL,FLAG1 == 6)
		IF(PLAYER1,ACTIVE_BATTLES >= 1)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("05. Outro Fail.mp3")
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_NEUTRAL,TIMER0)
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER_NEUTRAL,FLAG0,1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_NEUTRAL,FLAG0 == 0)
	IF(PLAYER_NEUTRAL,FLAG1 == 7)
		IF(PLAYER1,ACTIVE_BATTLES >= 1)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("06. Outro Win.mp3")
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_NEUTRAL,TIMER0)
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER_NEUTRAL,FLAG0,1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_NEUTRAL,FLAG0 == 1)
	IF(PLAYER_NEUTRAL,TIMER0 >= 600)
		IF(PLAYER1,ACTIVE_BATTLES == 0)	
			NEXT_COMMAND_REUSABLE
			RANDOMISE_FLAG(PLAYER_NEUTRAL,FLAG1,7)
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER_NEUTRAL,FLAG0,0)
			NEXT_COMMAND_REUSABLE
			RANDOMISE_FLAG(PLAYER_NEUTRAL,FLAG2,4)
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_NEUTRAL,TIMER1)
			NEXT_COMMAND_REUSABLE
			ADD_TO_TIMER(PLAYER_NEUTRAL,TIMER1,6600)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_NEUTRAL,FLAG0 == 0)
	IF(PLAYER_NEUTRAL,FLAG2 == 1)
		IF(PLAYER_NEUTRAL,TIMER1 >= 6600)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC(3)
			NEXT_COMMAND_REUSABLE
			ADD_TO_FLAG(PLAYER_NEUTRAL,FLAG2,1)
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_NEUTRAL,TIMER1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_NEUTRAL,FLAG0 == 0)
	IF(PLAYER_NEUTRAL,FLAG2 == 2)
		IF(PLAYER_NEUTRAL,TIMER1 >= 6600)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC(4)
			NEXT_COMMAND_REUSABLE
			ADD_TO_FLAG(PLAYER_NEUTRAL,FLAG2,1)
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_NEUTRAL,TIMER1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_NEUTRAL,FLAG0 == 0)
	IF(PLAYER_NEUTRAL,FLAG2 == 3)
		IF(PLAYER_NEUTRAL,TIMER1 >= 6600)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC(5)
			NEXT_COMMAND_REUSABLE
			ADD_TO_FLAG(PLAYER_NEUTRAL,FLAG2,1)
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_NEUTRAL,TIMER1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_NEUTRAL,FLAG0 == 0)
	IF(PLAYER_NEUTRAL,FLAG2 == 4)
		IF(PLAYER_NEUTRAL,TIMER1 >= 6600)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC(6)
			NEXT_COMMAND_REUSABLE
			ADD_TO_FLAG(PLAYER_NEUTRAL,FLAG2,-3)
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_NEUTRAL,TIMER1)
		ENDIF
	ENDIF
ENDIF

REM -------------------------------------------------------------------------------------------------------------------------------------------

IF(PLAYER1,HEART_HEALTH >= 20000)
	NEXT_COMMAND_REUSABLE
	ADD_HEART_HEALTH(PLAYER1,-1,0)
ENDIF

IF(PLAYER1,GAME_TURN > 100)
	QUICK_OBJECTIVE(​1,​"Welcome to Flameburgh. You are off to a good start, for the local Keeper Mara wants to become your vassal. It is rather unusual for a Keeper, even a minor one, to readily submit. So I can only imagine your reputation precedes you.",PLAYER1)
ENDIF

IF(PLAYER1,GAME_TURN > 300)
	QUICK_INFORMATION(2,​"Some of your forces from Brittledenn have arrived in the south west.",8)
ENDIF

IF(PLAYER1,GAME_TURN > 600)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FIRST_GIANT1,1,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FIRST_GIANT2,1,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FIRST_GIANT3,1,1)
	QUICK_MESSAGE(3, "Blue Tempest, I require your assistance!", PLAYER3)
	ADD_HEART_HEALTH(PLAYER3,-22500,0)
ENDIF

IF(PLAYER1,GAME_TURN > 750)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,8,1,1,0)
	ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,9,1,2,0)
	QUICK_OBJECTIVE(4,​"This realm is protected by powerful giants, so prepare for a tough conflict. For instance, observe Keeper Mara now.",PLAYER3)
	REVEAL_MAP_LOCATION(PLAYER1,PLAYER3,21)
	ZOOM_TO_LOCATION(PLAYER1,PLAYER3)
ENDIF

IF(PLAYER1,GAME_TURN > 1000)
	QUICK_INFORMATION(5,​"Summerland At War Status: Heroic forces are holding steady and winning in key locations. ",PLAYER1)
ENDIF

IF(PLAYER1,TIMES_LEVELUP_CREATURE >= 5)
	IF(PLAYER1,ENTRANCE == 18)
		SET_TIMER(PLAYER_GOOD,TIMER0)
		SET_FLAG(PLAYER_GOOD,FLAG0,1)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRY_GUARD4,-3,2)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRY_GUARD4,3,2)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRY_GUARD4,19,2)
	ENDIF
ENDIF

IF(PLAYER1, HELL_HOUND >= 1)
	CREATURE_AVAILABLE(PLAYER1,HELL_HOUND,1,0)
	QUICK_INFORMATION(6,​"(In this campaign Hell Hounds can be attracted by Guard Posts) ",PLAYER1)
ENDIF

IF(PLAYER1, TENTACLE >= 1)
	QUICK_INFORMATION(7,​"(In this campaign Tentacles can be attracted by a sufficiently sized Lair and Hacthery. No additional Tentacles can be attracted in this level)",PLAYER1)
ENDIF

IF(PLAYER3,DUNGEON_DESTROYED == 1)
	QUICK_OBJECTIVE(​8,​"It would seem Keeper Mara really was in need of protection. Oh well, better to let others take the fall than you. Take over Mara's dungeon. A path towards it can be found north of your current location.",PLAYER1)
	QUICK_INFORMATION(9,​"Your Creatures dread fighting the Giants. They are more likely to retreat when the odds are against them.",PLAYER1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_GUARD4,10,1)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,10,1,4,0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_GUARD4,4,1)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,5,1,4,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,6,1,4,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,7,1,3,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,12,1,5,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,11,1,3,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,13,1,4,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,14,1,5,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,14,1,4,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,17,1,4,0)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,18,1,5,0)
ENDIF

IF(PLAYER1,ENTRANCE == 18)
	QUICK_OBJECTIVE(​10,​"You have taken over Mara's dungeon. From here start the search for the hidden fortress of the Heroes and giants defending Flameburgh.",PLAYER1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_GUARD4,20,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_GUARD4,-2,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_GUARD4,2,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_GUARD4,13,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_GUARD4,19,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_GUARD4,14,1)
	MAX_CREATURES(PLAYER1,10)	
	SET_CREATURE_HEALTH(GIANT,850)
ENDIF

IF(PLAYER1,ENTRANCE == 27)
    MAX_CREATURES(PLAYER1,12)
ENDIF

IF(PLAYER1,GAME_TURN > 15000)
	QUICK_INFORMATION(11,​"The Warrior King and his army are now a good distance away from you. You will face no danger from him.",PLAYER1)
ENDIF

IF(PLAYER1,GAME_TURN > 30000)
	QUICK_INFORMATION(12,​"Rumor from Glorydale is that the Mage Lord and Witch Queen are bickering with the High King on the cause of the Sleepers' awakening and the deployment of their forces on how to deal with this threat. This means the local lords have to make their own decisions, very fortunate. ",PLAYER1)
ENDIF

IF(PLAYER1,GAME_TURN > 50000)
	QUICK_INFORMATION(13,​"More news from the outside world. Keeper Kroneus clashed with the Warrior King and has been defeated but managed to escape. More closer to your position: the White Horde have utterly destroyed the Heroic force send against them. Perhaps this faction warrants your attention.",PLAYER1)
ENDIF

IF(PLAYER_GOOD,TIMER0 >= 8000)
    SET_TIMER(PLAYER_GOOD,TIMER1)
    SET_TIMER(PLAYER_GOOD,TIMER2)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_SABOTEUR,-3,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_SABOTEUR,3,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_SNIPER,DRAWFROM(-3,3),1)
ENDIF

IF(PLAYER_GOOD,TIMER1 >= 8000)
    IF(PLAYER_GOOD,FLAG0 == 1)
        NEXT_COMMAND_REUSABLE
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_SABOTEUR,-3,1)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_SABOTEUR,3,1)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,GIANT_SNIPER,DRAWFROM(-3,3),1)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER_GOOD,TIMER1)
    ENDIF
ENDIF

IF_ACTION_POINT(5,PLAYER1)
	ADD_TO_PARTY(GIANT_SABOTEUR,GIANT,3,400,ATTACK_ROOMS,0)
ENDIF

IF(PLAYER_GOOD,TIMER2 >= 12500)
    IF(PLAYER_GOOD,FLAG0 == 1)
        NEXT_COMMAND_REUSABLE
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,FAIRY,3,1,3,100)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER_GOOD,TIMER2)
    ENDIF
ENDIF

IF_ACTION_POINT(15,PLAYER1)
    SET_FLAG(PLAYER_GOOD,FLAG0,2)
    SET_TIMER(PLAYER_GOOD,TIMER3)
	QUICK_INFORMATION(​14,​"You are getting close to the stronghold of the Heroes. Reduce it to rubble. ",PLAYER3)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DEFENDERS,-2,1)
ENDIF

IF(PLAYER_GOOD,TIMER3 >= 4000)
    IF(PLAYER_GOOD,FLAG0 >= 2)
        IF(PLAYER_GOOD,TOTAL_CREATURES <= 10)
			IF_SLAB_OWNER(​72,​66,​PLAYER_GOOD)
				IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
					NEXT_COMMAND_REUSABLE
					ADD_PARTY_TO_LEVEL(PLAYER_GOOD,DEFENDERS,-2,1)
					NEXT_COMMAND_REUSABLE
					SET_TIMER(PLAYER_GOOD,TIMER3)
				ENDIF
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF_SLAB_OWNER(​72,​66,​PLAYER1)
	HIDE_HERO_GATE(-2,1)
ENDIF


IF_ACTION_POINT(16,PLAYER1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LORD,-1,1)
	SET_FLAG(PLAYER_GOOD,FLAG0,3)
ENDIF


IF_ACTION_POINT(16,PLAYER1)
    IF(PLAYER1,DRAGON >= 1)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TITAN,-1,1)
		SET_FLAG(PLAYER1,CAMPAIGN_FLAG0,1)
    ENDIF
ENDIF

IF(PLAYER1,HEART_HEALTH <= 2500)
	ALLY_PLAYERS(PLAYER1,PLAYER_GOOD,3)
	ALLY_PLAYERS(PLAYER1,PLAYER3,3)
	LOSE_GAME
ENDIF

IF(PLAYER_GOOD,FLAG0 == 3)
	IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
		IF(PLAYER_GOOD,KNIGHT == 0)
			QUICK_OBJECTIVE(​15,​"I have heard the terrified local inhabitants already refer to you as The Giant Killer, most appropiate.",PLAYER3)
			HIDE_HERO_GATE(-1,1)
			WIN_GAME
		ENDIF
	ENDIF
ENDIF
