LEVEL_VERSION(1)
SET_GENERATE_SPEED(400)
START_MONEY(ALL_PLAYERS,1500)
MAX_CREATURES(ALL_PLAYERS,20)

REM TIMER0: Give some time to think how to acces the Destroy Walls spell before guiding to the Mage.
REM TIMER1: Triggers Hero Gates after finding the Mage
REM TIMER2: Triggers Hero Gates after claiming the Tempel
REM TIMER3: Triggers Hero Gates tu punish using Workshop as income.
REM TIMER4: Triggers a final wave for revenge after enemy heart is destroyed.

ADD_CREATURE_TO_POOL(BUG,2)
ADD_CREATURE_TO_POOL(DEMONSPAWN,5)
ADD_CREATURE_TO_POOL(TROLL,10)
ADD_CREATURE_TO_POOL(SPIDER,20)
ADD_CREATURE_TO_POOL(DRUID,10)
ADD_CREATURE_TO_POOL(ORC,10)
ADD_CREATURE_TO_POOL(BILE_DEMON,2)
ADD_CREATURE_TO_POOL(DRAGON,2)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,2)

CREATURE_AVAILABLE(ALL_PLAYERS,BUG,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SPIDER,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,ORC,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DRAGON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DARK_MISTRESS,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DRUID,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,0)

ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_POSSESS,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)

TRAP_AVAILABLE(ALL_PLAYERS,ALARM,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)

DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)

REM ----------------------------------------
CREATE_PARTY(CUSTOMERS)
	ADD_TO_PARTY(CUSTOMERS,GIANT,10,1000,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(CUSTOMERS,GIANT,10,1000,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(CUSTOMERS,GIANT,8,500,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(CUSTOMERS,BARBARIAN,8,300,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(CUSTOMERS,BARBARIAN,8,300,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(MAGE)
	ADD_TO_PARTY(MAGE,Wizard,8,150,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(MAGE,Wizard,8,150,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(MAGE,Fairy,8,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(MAGE,WITCH,8,0,ATTACK_ENEMIES,0)
	
CREATE_PARTY(TEMPLE)
	ADD_TO_PARTY(TEMPLE,MONK,10,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(TEMPLE,MONK,10,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(TEMPLE,MONK,10,0,ATTACK_ENEMIES,0)
	
CREATE_PARTY(HORNIES)
	ADD_TO_PARTY(HORNIES,HORNY,8,0,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(HORNIES,HORNY,8,0,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(HORNIES,HORNY,8,0,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(HORNIES,HORNY,8,0,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(REVEAL)
	ADD_TO_PARTY(REVEAL,HORNY,10,1500,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(LANDLORD)
	ADD_TO_PARTY(LANDLORD,KNIGHT,10,2500,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,SAMURAI,10,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,SAMURAI,10,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,FAIRY,10,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,GIANT,10,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,GIANT,10,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,BARBARIAN,10,0,ATTACK_ENEMIES,0)

CREATE_PARTY(SNEAKY)
	ADD_TO_PARTY(SNEAKY,THIEF,10,1000,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(SNEAKY,THIEF,10,1000,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(SNEAKY,THIEF,10,1000,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(SNEAKY,ARCHER,10,400,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(SNEAKY,ARCHER,10,400,ATTACK_DUNGEON_HEART,0)
	
CREATE_PARTY(REVENGE)
	ADD_TO_PARTY(REVENGE,KNIGHT,10,1000,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(REVENGE,GIANT,8,0,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(REVENGE,BARBARIAN,8,0,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(REVENGE,SAMURAI,8,0,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(REVENGE,MONK,8,0,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(REVENGE,FAIRY,8,0,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(REVENGE,WIZARD,8,0,ATTACK_DUNGEON_HEART,0)
	
CREATE_PARTY(ROOM1)
	ADD_TO_PARTY(ROOM1,THIEF,10,250,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM1,THIEF,10,250,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM1,THIEF,10,250,ATTACK_ENEMIES,0)
	
CREATE_PARTY(ROOM2)
	ADD_TO_PARTY(ROOM2,DWARFA,8,250,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM2,DWARFA,8,250,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM2,DWARFA,8,250,ATTACK_ENEMIES,0)
	
CREATE_PARTY(ROOM3)
	ADD_TO_PARTY(ROOM3,GIANT,8,250,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM3,GIANT,8,250,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM3,GIANT,8,250,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM3,SAMURAI,8,450,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM3,SAMURAI,8,450,ATTACK_ENEMIES,0)
	
CREATE_PARTY(ROOM4)
	ADD_TO_PARTY(ROOM4,BARBARIAN,8,150,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM4,BARBARIAN,8,150,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM4,BARBARIAN,10,150,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM4,BARBARIAN,10,150,ATTACK_ENEMIES,0)	
	ADD_TO_PARTY(ROOM4,FAIRY,8,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM4,FAIRY,8,0,ATTACK_ENEMIES,0)

CREATE_PARTY(ROOM5)
	ADD_TO_PARTY(ROOM5,BARBARIAN,6,100,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM5,BARBARIAN,6,100,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM5,SAMURAI,6,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM5,SAMURAI,6,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM5,SAMURAI,6,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM5,WIZARD,6,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM5,WIZARD,6,0,ATTACK_ENEMIES,0)

CREATE_PARTY(ROOM_HEAL)
	ADD_TO_PARTY(ROOM_HEAL,WIZARD,6,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM_HEAL,WIZARD,6,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM_HEAL,FAIRY,6,0,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ROOM_HEAL,FAIRY,6,0,ATTACK_ENEMIES,0)

CREATE_PARTY(SNEAKY_SMALL)
	ADD_TO_PARTY(SNEAKY_SMALL,THIEF,5,500,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(SNEAKY_SMALL,THIEF,5,500,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(SNEAKY_SMALL,THIEF,5,500,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(SNEAKY_SMALL,ARCHER,3,250,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(SNEAKY_SMALL,ARCHER,3,250,ATTACK_ENEMIES,0)
REM----------------------------------------

QUICK_OBJECTIVE(1,"You have heard some weird noises for a couple of days now, but as a group of Thiefs stole your gold, things has gone to far. One of your minions saw them running off to the east and you realise it's time to find out what's happening outside. We have to make sure this land is ours!",PLAYER0)

IF(PLAYER0,RESEARCH>=20)
	QUICK_INFORMATION(2,"'Meh... a Library... it has been AGES since we have read a book... so oldschool... those druids from the local woods above, want to do some research for you, whatever...', were you thinking. Since nobody in your realm is interested in books, their is no budget assigned to Library expansion or repairs.",Player0)
	ADD_CREATURE_TO_LEVEL(PLAYER0,DRUID,PLAYER0,3,4,0)
ENDIF

IF_ACTION_POINT(6,PLAYER0)
	QUICK_INFORMATION(17,"While you were busy slaughtering those enemies, one of your minions heard them talking about a mage they were looking for. They build a Fortress with a few outposts scattered over the land in their mission to find him. While you are not interested in such news, rumour says he was last seen in a far cave deep under these woods in the South West where he vanished.",PLAYER0)
ENDIF
	
IF_ACTION_POINT(1,PLAYER0)
	QUICK_INFORMATION(3,"Your imps have returned to let you know that they found a Destroy Walls spell in the east, but they can't reach it.",3)
	set_timer(PLAYER0,TIMER0)
ENDIF
	
IF(PLAYER0,TIMER0>=500)
	QUICK_INFORMATION(4,"I've figured it out! If the mage we heard about is real, maybe he could help us to get access! Wait, do you remember where he was last seen?",3)
ENDIF

IF(PLAYER0,TIMER0>=1000)
	QUICK_OBJECTIVE(20,"Find the mage and ask his help, remember that he is hard to find. It seems likely that he has used some magical tricks to stay hidden.",3)
ENDIF

IF(PLAYER0,TIME_MAGE>=1)
	ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
	CHANGE_SLAB_OWNER(82,48,PLAYER0)
	set_timer(PLAYER0,TIMER1)
	QUICK_OBJECTIVE(5,"We've found the mage! It turns out he does have some magic tricks. 'I'll give you the access you asked for', he says. Waiting for a bridge to appear something strange has happend just in front of you! Did the soil just changed colour? 'Well since you did ask acces and I was in for a prank, I didn't do it the easy way ;-)!' he winked. If nobody can get it for you, then sometimes you have to take over and do it yourself apparently... Maybe you should reconsider everyones wages!",3)
ENDIF

IF_SLAB_OWNER(20,71,PLAYER0)
	IF_SLAB_OWNER(78,49,PLAYER_GOOD)
		QUICK_OBJECTIVE(8,"Hmm.. a dead end... We have to find another way in. Actually, somebody really must invent some kind of spell to Destroy Walls or something! Life would be so much easier for a lazy keeper like you.",2)
	ENDIF
	IF_AVAILABLE(PLAYER0,POWER_DESTROY_WALLS>0)
		QUICK_OBJECTIVE(7,"Good job we did find the Destroy Walls spell! Enter this fortress, so we can end this once and for all!",2)
	ENDIF
ENDIF		

IF_SLAB_OWNER(22,71,PLAYER0)
	QUICK_INFORMATION(15,"Nooo!! You let your spelbook fall into the lava, you idiot...",2)
	MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DESTROY_WALLS,0,0)
ENDIF

IF(PLAYER0,TEMPLE>=1)
	ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,1)
	set_timer(Player0,TIMER2)
ENDIF

IF(PLAYER0,GRAVEYARD>=1)
	ROOM_AVAILABLE(ALL_PLAYERS,GRAVEYARD,1,1)
ENDIF

IF(PLAYER0,TORTURE>=1)
	ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,1)
ENDIF

IF(PLAYER0,PRISON>=1)
	ROOM_AVAILABLE(ALL_PLAYERS,PRISON,1,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SNEAKY_SMALL,-1,2)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SNEAKY_SMALL,-2,2)
ENDIF

IF(PLAYER0,MANUFACTURE_GOLD>=10000)
	QUICK_INFORMATION(9,"'Today and only today, 50 percent off on the door of your dreams!'... Really Keeper, don't you have anything else to do? This realm isn't a store...",Player0)
ENDIF

IF(PLAYER0,MANUFACTURE_GOLD>=20000)
	QUICK_INFORMATION(10,"Well, look at you! Growing into a real businessman after all! And I thought you were the most wicked thing alive! Well, what is a businessman without..... CUSTOMERS?",Player0)
	set_timer(PLAYER0,TIMER3)
ENDIF

IF(PLAYER0,MANUFACTURE_GOLD>=40000)
	QUICK_INFORMATION(19,"What is that? Black Friday again?",Player0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CUSTOMERS,-1,3)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CUSTOMERS,-2,1)
ENDIF		

IF(PLAYER0,TIMER1 >= 800)
	QUICK_INFORMATION(12,"News will spread soon that you're the one who find the mage, they will try to search your dungeon to finish him off! ",Player0)
ENDIF

IF(PLAYER0,TIMER1 >= 1500)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MAGE,-1,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,MAGE,-3,1)
ENDIF

IF(PLAYER0,TIMER1 >= 2500)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SNEAKY,-2,1)
ENDIF
	
IF(PLAYER0,TIMER2 >= 250)
	QUICK_INFORMATION(14,"Seems like they are not amused and they do want that Temple back.. Wonder what they were worshipping?",Player0)
ENDIF

IF(PLAYER0,TIMER2 >= 600)	
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TEMPLE,-2,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TEMPLE,-3,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TEMPLE,4,1)
ENDIF

IF(PLAYER0,TIMER2 >= 1250)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SNEAKY,-1,1)
ENDIF

IF(PLAYER0,TIMER2 >= 2750)
	QUICK_INFORMATION(13,"Watch out! Seems like something is rising from that dark Temple we've found!",Player0)
ENDIF

IF(PLAYER0,TIMER2 >= 2900)	
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,HORNIES,4,1)
ENDIF

IF(PLAYER0,TIMER3 >= 350)
	QUICK_INFORMATION(11,"Ach Black Friday has begun, even the Giants are on their way. BIG guys = BIG doors = BIG profit for you Keeper! Oh wait... they aren't here to buy! Ah well they are just jealous of your doors...",Player0)
ENDIF

IF(PLAYER0,TIMER3 >= 750)	
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CUSTOMERS,-1,1)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CUSTOMERS,-2,2)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,CUSTOMERS,-3,1)
ENDIF

IF(PLAYER0,TIMER3 >= 3000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SNEAKY,-1,1)
ENDIF
		
IF_ACTION_POINT(5,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LANDLORD,-4,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TEMPLE,-4,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SNEAKY,-1,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SNEAKY,-5,1)
ENDIF

IF (PLAYER_GOOD,DUNGEON_DESTROYED == 1)
	SET_TIMER(PLAYER0,TIMER4)
	QUICK_OBJECTIVE(16,"Enemy Heart is down! Was this all you've got?!",Player0)
ENDIF

IF (Player0,TIMER4>600)
	QUICK_INFORMATION(18,"Oh no what is this noise? Enemies??? Looks like that Landlord has some siblings and they want revenge! And they brought many friends!",Player0)
ENDIF

IF (Player0,TIMER4>1000)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,REVENGE,-2,1)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TEMPLE,-3,1)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ROOM2,-1,1)
ENDIF

IF(PLAYER0,TIMER4>1500)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,REVENGE,-3,1)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SNEAKY_SMALL,-1,2)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ROOM2,-5,2)
ENDIF

IF(PLAYER0,TIMER4>2000)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,REVENGE,-4,1)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SNEAKY,-1,1)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ROOM5,-4,1)
ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ROOM5,-2,1)
ENDIF

IF_ACTION_POINT(8,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,REVEAL,8,2)
ENDIF

IF_ACTION_POINT(9,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ROOM1,9,2)
ENDIF

IF_ACTION_POINT(10,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ROOM3,10,1)
ENDIF

IF_ACTION_POINT(11,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ROOM2,11,4)
ENDIF

IF_ACTION_POINT(12,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ROOM4,12,1)
ENDIF

IF_ACTION_POINT(13,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ROOM3,13,1)
ENDIF

IF_ACTION_POINT(14,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ROOM_HEAL,14,1)
ENDIF

IF_ACTION_POINT(15,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ROOM2,7,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SNEAKY_SMALL,-1,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SNEAKY_SMALL,-3,1)
ENDIF

IF (PLAYER_GOOD,DUNGEON_DESTROYED == 1)
	IF(Player0,TIMER4>2000)
		If(Player_Good,TOTAL_CREATURES == 0)
			QUICK_INFORMATION(30,"Well you did it, this land is yours and you've made a new alliance with those druids. For bookwurms they did help you a lot! Perhaps you should read more books from now on. And don't forget, the druids did invite you to the next barbecue, so they can show you the woods above where they live! Thank you for playing, hope you enjoyed my very first map. Made by Crokydriver",Player0)
			WIN_GAME
		ENDIF	
	ENDIF
ENDIF

IF (PLAYER0,DUNGEON_DESTROYED == 1)
	LOSE_GAME
ENDIF