LEVEL_VERSION(1)
RUN_AFTER_VICTORY(1)
SET_GENERATE_SPEED(200)
START_MONEY(ALL_PLAYERS,100000)
MAX_CREATURES(ALL_PLAYERS,20)

COMPUTER_PLAYER(PLAYER1,0)
COMPUTER_PLAYER(PLAYER2,1)
COMPUTER_PLAYER(PLAYER3,10)
COMPUTER_PLAYER(PLAYER4,0)
COMPUTER_PLAYER(PLAYER5,10)
COMPUTER_PLAYER(PLAYER6,1)

ADD_CREATURE_TO_POOL(DRUID,20)
ADD_CREATURE_TO_POOL(BUG,20)
ADD_CREATURE_TO_POOL(DEMONSPAWN,20)
ADD_CREATURE_TO_POOL(TROLL,20)
ADD_CREATURE_TO_POOL(SPIDER,20)
ADD_CREATURE_TO_POOL(TENTACLE,20)
ADD_CREATURE_TO_POOL(SORCEROR,20)
ADD_CREATURE_TO_POOL(ORC,20)
ADD_CREATURE_TO_POOL(BILE_DEMON,20)
ADD_CREATURE_TO_POOL(DRAGON,20)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,20)

CREATURE_AVAILABLE(ALL_PLAYERS,DRUID,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,BUG,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SPIDER,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,TENTACLE,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,ORC,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DRAGON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DARK_MISTRESS,1,0)

ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(PLAYER0,BRIDGE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GRAVEYARD,1,0)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_POSSESS,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CAVE_IN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CHICKEN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DISEASE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_TIME_BOMB,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLOW,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_FREEZE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_REBOUND,1,0)

TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,WORD_OF_POWER,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,TNT,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,BOULDER,1,0)

DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)

SET_CREATURE_PROPERTY(AVATAR,LORD,0)

CREATE_PARTY(ONE)
    ADD_TO_PARTY(ONE,DWARFA,4,500,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(ONE,DWARFA,4,500,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(ONE,DWARFA,4,500,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(ONE,DWARFA,4,500,ATTACK_DUNGEON_HEART,0)
    
CREATE_PARTY(LORD)
    ADD_TO_PARTY(LORD,KNIGHT,10,5000,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(LORD,GIANT,10,500,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(LORD,GIANT,10,500,ATTACK_DUNGEON_HEART,0)
    ADD_TO_PARTY(LORD,WIZARD,10,500,ATTACK_DUNGEON_HEART,0)

SET_FLAG(PLAYER_GOOD,FLAG0,0)
SET_FLAG(PLAYER_GOOD,FLAG1,0)
SET_FLAG(PLAYER_GOOD,FLAG2,0)
SET_FLAG(PLAYER_GOOD,FLAG3,0)
SET_FLAG(PLAYER_GOOD,FLAG4,0)
SET_FLAG(PLAYER_GOOD,FLAG5,0)
SET_FLAG(PLAYER0,FLAG0,0)

DISPLAY_OBJECTIVE(1,PLAYER0)

IF_ACTION_POINT(1,PLAYER0)
    SET_FLAG(PLAYER_GOOD,FLAG1,1)
ENDIF

IF_ACTION_POINT(2,PLAYER0)
    SET_FLAG(PLAYER_GOOD,FLAG1,1)
ENDIF

IF_ACTION_POINT(3,PLAYER0)
    SET_FLAG(PLAYER_GOOD,FLAG1,1)
ENDIF

IF_ACTION_POINT(4,PLAYER0)
    SET_FLAG(PLAYER_GOOD,FLAG1,1)
ENDIF

IF_ACTION_POINT(10,PLAYER0)
    DISPLAY_INFORMATION(5,10)
ENDIF

IF_ACTION_POINT(9,PLAYER0)
    SET_FLAG(PLAYER0,FLAG0,1)
ENDIF

IF_ACTION_POINT(11,PLAYER0)
    SET_FLAG(PLAYER0,FLAG0,1)
ENDIF

IF(PLAYER_GOOD,FLAG1 == 1)
    IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
        DISPLAY_INFORMATION(2,ALL_PLAYERS)
        ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ONE,1,DUNGEON_HEART,0,1,500)
        ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ONE,2,DUNGEON_HEART,0,1,500)
        ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ONE,3,DUNGEON_HEART,0,1,500)
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,4,5,4,500)
        ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,FAIRY,-1,5,5,500)
    ENDIF
ENDIF

IF(PLAYER0,TOTAL_CREATURES >= 15)
    SET_TIMER(PLAYER_GOOD,TIMER0)
    SET_TIMER(PLAYER_GOOD,TIMER1)
    SET_TIMER(PLAYER_GOOD,TIMER2)
    SET_TIMER(PLAYER_GOOD,TIMER3)
    SET_TIMER(PLAYER_GOOD,TIMER4)
ENDIF

IF(PLAYER_GOOD,TIMER0 >= 3500)
    SET_FLAG(PLAYER_GOOD,FLAG1,1)
ENDIF

IF(PLAYER_GOOD,FLAG4 == 0)
    IF(PLAYER_GOOD,TIMER1 >= 6000)
        IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
            DISPLAY_INFORMATION(8,ALL_PLAYERS)
            NEXT_COMMAND_REUSABLE
            ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,5,5,4,500)
            NEXT_COMMAND_REUSABLE
            SET_TIMER(PLAYER_GOOD,TIMER1)
        ENDIF
    ENDIF
    IF(PLAYER_GOOD,TIMER2 >= 7000)
        IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
            NEXT_COMMAND_REUSABLE
            ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DWARFA,6,5,4,500)
            NEXT_COMMAND_REUSABLE
            SET_TIMER(PLAYER_GOOD,TIMER2)
        ENDIF
    ENDIF
    IF(PLAYER_GOOD,TIMER3 >= 8500)
        IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
            NEXT_COMMAND_REUSABLE
            ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,7,5,2,500)
            NEXT_COMMAND_REUSABLE
            SET_TIMER(PLAYER_GOOD,TIMER3)
        ENDIF
    ENDIF
    IF(PLAYER_GOOD,TIMER4 >= 10000)
        IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
            NEXT_COMMAND_REUSABLE
            ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SAMURAI,8,5,5,500)
            NEXT_COMMAND_REUSABLE
            ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,FAIRY,-1,3,5,500)
            NEXT_COMMAND_REUSABLE
            ADD_TO_FLAG(PLAYER_GOOD,FLAG2,1)
            NEXT_COMMAND_REUSABLE
            SET_TIMER(PLAYER_GOOD,TIMER4)
        ENDIF
    ENDIF
ENDIF

IF(PLAYER_GOOD,HEART_HEALTH < 30000)
    IF(PLAYER_GOOD,FLAG5 == 0)
        DISPLAY_INFORMATION(7,ALL_PLAYERS)
    ENDIF
    SET_FLAG(PLAYER_GOOD,FLAG0,1)
ENDIF

IF(PLAYER_GOOD,FLAG2 == 4)
    IF(PLAYER_GOOD,FLAG0 == 0)
        DISPLAY_INFORMATION(4,ALL_PLAYERS)
        SET_TIMER(PLAYER_GOOD,TIMER5)
        IF(PLAYER_GOOD,TIMER5 >= 5000)
            DISPLAY_INFORMATION(9,ALL_PLAYERS)
        ENDIF
    ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG2 >= 5)
    SET_FLAG(PLAYER_GOOD,FLAG0,1)
    SET_FLAG(PLAYER_GOOD,FLAG4,1)
ENDIF

IF(PLAYER_GOOD,FLAG0 == 1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LORD,7,1)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SAMURAI,5,8,7,500)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,GIANT,6,8,10,500)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,8,5,10,500)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,AVATAR,5,1,10,5000)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,FAIRY,9,3,10,500)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,FAIRY,11,3,10,500)
    SET_DOOR(UNLOCKED,24,150)
    SET_DOOR(UNLOCKED,89,141)
    SET_DOOR(UNLOCKED,96,141)
    SET_DOOR(UNLOCKED,114,145)
    SET_DOOR(UNLOCKED,118,162)
    SET_FLAG(PLAYER_GOOD,FLAG3,1)
    SET_FLAG(PLAYER_GOOD,FLAG5,1)
ENDIF

IF(PLAYER_GOOD,FLAG3 == 1)
    IF(PLAYER_GOOD,DUNGEON_DESTROYED == 0)
        IF_CONTROLS(PLAYER_GOOD,SAMURAI <= 0)
            NEXT_COMMAND_REUSABLE
            ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,SAMURAI,5,8,7,500)
        ENDIF
    ENDIF
ENDIF

IF(PLAYER0,FLAG0 > 0)
    DISPLAY_INFORMATION(6,PLAYER_GOOD)
ENDIF

IF(PLAYER0,PRISON > 0)
    ROOM_AVAILABLE(PLAYER0,PRISON,1,1)
ENDIF

IF_CONTROLS(PLAYER_GOOD,AVATAR > 0)
    DISPLAY_INFORMATION(11,ALL_PLAYERS)
ENDIF

IF(PLAYER_GOOD,ALL_DUNGEONS_DESTROYED == 1)
    DISPLAY_OBJECTIVE(10,ALL_PLAYERS)
ENDIF

IF(PLAYER0,ALL_DUNGEONS_DESTROYED == 1)
    IF_CONTROLS(PLAYER_GOOD,TOTAL_CREATURES <= 0)
        DISPLAY_OBJECTIVE(3,ALL_PLAYERS)
        WIN_GAME
    ENDIF
ENDIF
