LEVEL_VERSION(1)
SET_GENERATE_SPEED(400)
START_MONEY(ALL_PLAYERS,5000)
MAX_CREATURES(ALL_PLAYERS,7)

ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,BRIDGE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_POSSESS,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CAVE_IN,1,0)

TRAP_AVAILABLE(ALL_PLAYERS,BOULDER,1,0)

DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)

QUICK_OBJECTIVE(0,"LOGRAS: I haven't mastered all combat spells yet, so for now, Cobald, all hope rests on your traps.",PLAYER0)
SET_TIMER(PLAYER0,TIMER0)
IF(PLAYER0,TIMER0 >= 200)
	QUICK_OBJECTIVE(1,"COBALD: Of course! I trust the rest of you will back me up - just like old times.",PLAYER0)
ENDIF

REM --------------------------- Other

IF(PLAYER0,BILE_DEMON == 1)
	QUICK_OBJECTIVE(2,"FAT JOE: Thank ye for the rescue! Name's Fat Joe. The Moth tossed me in a cage after I told that bastard no! But now? Oh, I'll pay him back in blood. Got a... particular knack for trap-makin'. Say the wordwe'll rig this place to blow faster'n you can spit!.",PLAYER0)
ENDIF

IF_SLAB_TYPE(43,35,PATH)
	QUICK_OBJECTIVE(3,"LOGRAS: Careful! I smell a curse on this warlock. Let's gut him - but only when the traps are ripe.",PLAYER0)
ENDIF

REM --------------------------- Open road to tample

IF_SLAB_OWNER(40,22,PLAYER0)
	QUICK_OBJECTIVE(4,"LOGRAS: These runes whisper of a sanctuary raised by the Failed Scholar - the fool we once mocked. Find the temple, and the tunnel's guardian will grant us passage.",PLAYER0)
	CHANGE_SLAB_OWNER(71,8,PLAYER0)
	CHANGE_SLAB_OWNER(72,8,PLAYER0)
	CHANGE_SLAB_OWNER(73,8,PLAYER0)
	CHANGE_SLAB_OWNER(71,9,PLAYER0)
	CHANGE_SLAB_OWNER(72,9,PLAYER0)
	CHANGE_SLAB_OWNER(73,9,PLAYER0)
	CHANGE_SLAB_OWNER(71,10,PLAYER0)
	CHANGE_SLAB_OWNER(72,10,PLAYER0)
	CHANGE_SLAB_OWNER(73,10,PLAYER0)
	REVEAL_MAP_RECT(PLAYER0,217,28,12,12)
ENDIF

IF(PLAYER0,TEMPLE >= 1)
	CHANGE_SLAB_TYPE(40,20,PATH)
	QUICK_OBJECTIVE(5,"LOGRAS: The secret passage is open!",PLAYER0)
ENDIF

REM --------------------------- Knights wave

IF(PLAYER_GOOD,WIZARD < 1)
	CHANGE_SLAB_TYPE(50,11,PATH)
	QUICK_OBJECTIVE(6,"LOGRAS: Just as I feared - the cursed warlock's death gifted us a surprise. That wall's rubble now invites unwelcome guests.",PLAYER0)
ENDIF

REM --------------------------- Logras dead and win

IF(PLAYER0,SORCEROR < 1)
	QUICK_OBJECTIVE(100,"Oh no! My mission!..",PLAYER0)
	LOSE_GAME
ENDIF

IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
	QUICK_OBJECTIVE(101,"FAT JOE: Well then, the hour of parting is upon us. I wish you a speedy victory over the Moth! Good luck!",PLAYER0)
	SET_TIMER(PLAYER0,TIMER1)
	IF(PLAYER0,TIMER1 >= 200)
		QUICK_OBJECTIVE(102,"LOGRAS: And to you, my friend!",PLAYER0)
		WIN_GAME
	ENDIF
ENDIF