REM ****************************************************************************
REM  Campaigns Consolidation Project for KeeperFX strategy game.
REM ****************************************************************************
REM  Script for Level Tickle
REM  Campaign: DK Original
REM  Authors:  based on Bullfrog script
REM            KeeperFX CCP Team
REM  Date:     17 Dec 1996 - 27 Feb 2018
REM  Copying and copyrights:
REM    This program is free software; you can redistribute it and/or modify
REM    it under the terms of the GNU General Public License as published by
REM    the Free Software Foundation; either version 2 of the License, or
REM    (at your option) any later version.
REM ****************************************************************************

REM New rooms for the player:
REM   TEMPLE - researchable from start
REM New creatures for the player:
REM   HORNY - possible to summon with sacrifices
REM New powers for the player:
REM   POWER_PROTECT - researchable from start
REM   POWER_CONCEAL - researchable from start
REM New manufacture for the player:
REM   STEEL - able to manufacture as soon as have WORKSHOP

REM PLAYER_GOOD
REM   FLAG0 - 0 when Green alive, used for constant hero waves
REM   FLAG1 - 0 when haven't reached Green, used for secret behind-the-scenes setup
REM   FLAG2 - Flag for constant waves, spin round 0,1,2,3
REM   FLAG4 - No. heroes at LOTL spawn.
REM   FLAG5 - Set to 1 when game won. Just in case RUN_AFTER_VICTORY needed.
REM   FLAG6 - Custom sacrifice
REM   FLAG7 - Skeleton chance
REM
REM PLAYER0
REM   FLAG7 - Spawn the hint crate

REM   TIMER0 - Hero waves on Green
REM   TIMER1 - Trigger LOTL after Green killed


SET_GENERATE_SPEED(400)

REM Computer Player stuff
COMPUTER_PLAYER(PLAYER2,2)
SET_COMPUTER_PROCESS(PLAYER2,"DIG TO CLOSE GOLD",0,1000,400,5,50)

START_MONEY(PLAYER0,4000)
START_MONEY(PLAYER2,9000)

MAX_CREATURES(PLAYER0,25)
MAX_CREATURES(PLAYER2,30)

ADD_CREATURE_TO_POOL(FLY,20)
ADD_CREATURE_TO_POOL(DEMONSPAWN,20)
ADD_CREATURE_TO_POOL(TROLL,20)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,8)
ADD_CREATURE_TO_POOL(SORCEROR,20)
ADD_CREATURE_TO_POOL(BILE_DEMON,8)
ADD_CREATURE_TO_POOL(ORC,12)

REM	Creature availability
CREATURE_AVAILABLE(ALL_PLAYERS,FLY,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DARK_MISTRESS,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,ORC,1,0)

SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,IMP,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,BUG,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,FLY,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,SPIDER,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,TROLL,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,DEMONSPAWN,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,SORCEROR,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,BILE_DEMON,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,SKELETON,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,GHOST,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,DARK_MISTRESS,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,ORC,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,THIEF,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,ARCHER,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,DWARFA,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,FAIRY,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,BARBARIAN,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,WIZARD,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,GIANT,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,MONK,6)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,KNIGHT,6)

REM	Room availability
ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,0)
ROOM_AVAILABLE(PLAYER0,BRIDGE,1,0)
ROOM_AVAILABLE(PLAYER2,BRIDGE,4,0)
ROOM_AVAILABLE(ALL_PLAYERS,PRISON,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,0)
ROOM_AVAILABLE(PLAYER0,TEMPLE,4,0)

REM	Spells availability
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(PLAYER2,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_CONCEAL,1,0)

REM	Doors and traps availability
DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)

CREATE_PARTY(ENEMYSETUPA)
	ADD_TO_PARTY(ENEMYSETUPA,DWARFA,2,300,ATTACK_ENEMIES,2)
 	ADD_TO_PARTY(ENEMYSETUPA,THIEF,2,300,ATTACK_ENEMIES,2)   

CREATE_PARTY(ENEMYSETUPB)
	ADD_TO_PARTY(ENEMYSETUPB,ARCHER,2,300,ATTACK_ENEMIES,2)
 	ADD_TO_PARTY(ENEMYSETUPB,BARBARIAN,2,300,ATTACK_ENEMIES,2)

CREATE_PARTY(ENEMYSETUPC)
	ADD_TO_PARTY(ENEMYSETUPC,FAIRY,2,300,ATTACK_ENEMIES,2)
 	ADD_TO_PARTY(ENEMYSETUPC,WIZARD,2,300,ATTACK_ENEMIES,2)

CREATE_PARTY(ENEMYSETUPD)
	ADD_TO_PARTY(ENEMYSETUPD,GIANT,2,300,ATTACK_ENEMIES,2)
	ADD_TO_PARTY(ENEMYSETUPD,MONK,2,300,ATTACK_ENEMIES,2)

CREATE_PARTY(FAIRIESA)
	ADD_TO_PARTY(FAIRIESA,FAIRY,3,300,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(FAIRIESA,FAIRY,3,300,ATTACK_ENEMIES,0)

CREATE_PARTY(FAIRIESB)
	ADD_TO_PARTY(FAIRIESB,FAIRY,4,300,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(FAIRIESB,FAIRY,4,300,ATTACK_ENEMIES,0)

CREATE_PARTY(HOUSEPARTY)
	ADD_TO_PARTY(HOUSEPARTY,WIZARD,5,300,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(HOUSEPARTY,GIANT,5,300,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(HOUSEPARTY,FAIRY,5,300,ATTACK_ENEMIES,0)

CREATE_PARTY(LANDLORD)
	ADD_TO_PARTY(LANDLORD,KNIGHT,7,1000,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,MONK,6,500,ATTACK_ENEMIES,0) 
    ADD_TO_PARTY(LANDLORD,MONK,6,500,ATTACK_ENEMIES,0) 
 	ADD_TO_PARTY(LANDLORD,ARCHER,6,500,ATTACK_ENEMIES,0) 
    ADD_TO_PARTY(LANDLORD,ARCHER,6,500,ATTACK_ENEMIES,0)    

REM ****************************************************************************
LEVEL_VERSION(1)
RUN_AFTER_VICTORY(1)

REM - (but easy enough that he handily wins and increases his forces)
REM - Add other standard balances, stuff like having an Archer allows Arrow traps
REM - and having a Wizard allows Freeze traps.
REM - Add hero parties
REM - Occasionally secretly slip converted heroes to Green?

QUICK_OBJECTIVE(1,"Your rival has been steadily gaining power in this land, capturing and subverting any local Heroes he can get his claws on. Overpower him with your own converted force and crush the Lord of this land.",ALL_PLAYERS)


SET_BOX_TOOLTIP(0, "Hint Crate")
ADD_OBJECT_TO_LEVEL(SPECBOX_CUSTOM, 10, 0)
SET_FLAG(PLAYER0,FLAG7,0)


IF(PLAYER0,BOX0_ACTIVATED > 0)
	IF(PLAYER0,FLAG7 == 0)
		NEXT_COMMAND_REUSABLE
		QUICK_INFORMATION(25,"There are whispers of a hidden Temple. Find it and make the sacrifice.",ALL_PLAYERS,897)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER0,TIMER7)
		NEXT_COMMAND_REUSABLE
		SET_FLAG(PLAYER0,BOX0_ACTIVATED,0)
		NEXT_COMMAND_REUSABLE
		SET_FLAG(PLAYER0,FLAG7,1)
	ENDIF
ENDIF

IF(PLAYER0,TIMER7 >= 100)
	IF(PLAYER0,FLAG7 == 1)
		NEXT_COMMAND_REUSABLE
		CREATE_EFFECT(54,10)
		NEXT_COMMAND_REUSABLE
		ADD_OBJECT_TO_LEVEL(SPECBOX_CUSTOM, 10, 0)
		NEXT_COMMAND_REUSABLE
		SET_FLAG(PLAYER0,FLAG7,0)
	ENDIF
ENDIF





SET_COMPUTER_EVENT(PLAYER2, "EVENT MOANING PRISONER",100,2,9,5,0)

IF_AVAILABLE(PLAYER0,ARROW >= 1)
	IF(PLAYER0,ARCHER > 0)
		TRAP_AVAILABLE(PLAYER0,ARROW,1,0)
	ENDIF
ENDIF

IF_AVAILABLE(PLAYER0,HAIL >= 1)
	IF(PLAYER0,WIZARD > 0)
		TRAP_AVAILABLE(PLAYER0, HAIL,1,0)
	ENDIF
ENDIF

SET_TIMER(PLAYER_GOOD,TIMER0)

IF(PLAYER_GOOD,FLAG7 == 1)
    SET_GAME_RULE( PrisonSkeletonChance, 90 )
ENDIF
IF(PLAYER_GOOD,FLAG7 == 2)
    SET_GAME_RULE( PrisonSkeletonChance, 75 )
ENDIF
IF(PLAYER_GOOD,FLAG7 == 3)
    SET_GAME_RULE( PrisonSkeletonChance, 60 )
ENDIF
IF(PLAYER_GOOD,FLAG7 == 4)
    SET_GAME_RULE( PrisonSkeletonChance, 50 )
ENDIF

IF(PLAYER_GOOD,FLAG7 == 0)
    IF( PLAYER0, SKELETON > 3 )
        SET_FLAG(PLAYER_GOOD,FLAG7,1)
    ENDIF
    IF( PLAYER2, SKELETON > 3 )
        SET_FLAG(PLAYER_GOOD,FLAG7,1)
    ENDIF
ENDIF
IF(PLAYER_GOOD,FLAG7 == 1)
    IF( PLAYER0, SKELETON > 6 )
        SET_FLAG(PLAYER_GOOD,FLAG7,2)
    ENDIF
    IF( PLAYER2, SKELETON > 6 )
        SET_FLAG(PLAYER_GOOD,FLAG7,2)
    ENDIF
ENDIF
IF(PLAYER_GOOD,FLAG7 == 2)
    IF( PLAYER0, SKELETON > 9 )
        SET_FLAG(PLAYER_GOOD,FLAG7,3)
    ENDIF
    IF( PLAYER2, SKELETON > 9 )
        SET_FLAG(PLAYER_GOOD,FLAG7,3)
    ENDIF
ENDIF
IF(PLAYER_GOOD,FLAG7 == 3)
    IF( PLAYER0, SKELETON > 12 )
        SET_FLAG(PLAYER_GOOD,FLAG7,4)
    ENDIF
    IF( PLAYER2, SKELETON > 12 )
        SET_FLAG(PLAYER_GOOD,FLAG7,4)
    ENDIF
ENDIF


IF( PLAYER0,GHOST > 2 )
    SET_GAME_RULE( GhostConvertChance, 70 )
ENDIF
IF( PLAYER0,GHOST > 4 )
    SET_GAME_RULE( GhostConvertChance, 40 )
ENDIF
IF( PLAYER0,GHOST > 6 )
    SET_GAME_RULE( GhostConvertChance, 10 )
ENDIF


IF( PLAYER0, CREATURES_CONVERTED > 4 )
    SET_GAME_RULE( TortureDeathChance, 80 )
ENDIF
IF( PLAYER0, CREATURES_CONVERTED > 7 )
    SET_GAME_RULE( TortureDeathChance, 60 )
ENDIF
IF( PLAYER0,CREATURES_CONVERTED > 10 )
    SET_GAME_RULE( TortureDeathChance, 40 )
ENDIF

IF(PLAYER2,PRISON >= 9)
	SET_CREATURE_TENDENCIES(PLAYER2,IMPRISON,1)
ENDIF

REM - Fairy ambushes
IF_ACTION_POINT(1,PLAYER0)
    IF(PLAYER_GOOD,FLAG5 == 0)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRIESA,1,1)
    ENDIF 
ENDIF
IF_ACTION_POINT(2,PLAYER0)
    IF(PLAYER_GOOD,FLAG5 == 0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRIESB,2,1)
    ENDIF 
ENDIF
IF_ACTION_POINT(3,PLAYER0)
    IF(PLAYER_GOOD,FLAG5 == 0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRIESA,3,1)
    ENDIF 
ENDIF
IF_ACTION_POINT(4,PLAYER0)
    IF(PLAYER_GOOD,FLAG5 == 0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRIESB,4,1)
    ENDIF
ENDIF
IF_ACTION_POINT(5,PLAYER0)
    IF(PLAYER_GOOD,FLAG5 == 0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRIESB,5,1)
    ENDIF 
ENDIF
IF_ACTION_POINT(6,PLAYER0)
    IF(PLAYER_GOOD,FLAG5 == 0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FAIRIESB,6,1)
    ENDIF
ENDIF

REM - When close enough to Green's base, hide secret stuff so it doesn't break immersion.
IF_ACTION_POINT(6,PLAYER0)
    SET_FLAG(PLAYER_GOOD,FLAG1,1)
ENDIF

REM Constantish Hero waves and backdoor setup

IF(PLAYER_GOOD,FLAG0 == 0)
	IF(PLAYER_GOOD,TIMER0 > 4000)
        IF(PLAYER_GOOD,FLAG2 == 0)
		NEXT_COMMAND_REUSABLE
		ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ENEMYSETUPA,-1,DUNGEON,2,2,300)
        NEXT_COMMAND_REUSABLE
        SET_FLAG(PLAYER_GOOD,FLAG2,1)
        ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG0 == 0)
	IF(PLAYER_GOOD,TIMER0 > 5000)
        IF(PLAYER_GOOD,FLAG1 == 0)
            IF(PLAYER_GOOD,FLAG2 == 1)
		    NEXT_COMMAND_REUSABLE
		    ADD_CREATURE_TO_LEVEL(PLAYER2,DRAWFROM(DWARFA,THIEF),9,1,2,300)
            NEXT_COMMAND_REUSABLE
            SET_FLAG(PLAYER_GOOD,FLAG2,2)
            ENDIF
        ENDIF
    ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG0 == 0)
	IF(PLAYER_GOOD,TIMER0 > 8000)
        IF(PLAYER_GOOD,FLAG2 == 2)
		NEXT_COMMAND_REUSABLE
        ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ENEMYSETUPB,-2,DUNGEON,2,2,300)
        NEXT_COMMAND_REUSABLE
        SET_FLAG(PLAYER_GOOD,FLAG2,3)
        ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG0 == 0)
	IF(PLAYER_GOOD,TIMER0 > 9000)
        IF(PLAYER_GOOD,FLAG1 == 0)
            IF(PLAYER_GOOD,FLAG2 == 3)
		    NEXT_COMMAND_REUSABLE
		    ADD_CREATURE_TO_LEVEL(PLAYER2,DRAWFROM(ARCHER,BARBARIAN),9,1,2,300)
            NEXT_COMMAND_REUSABLE
            SET_FLAG(PLAYER_GOOD,FLAG2,4)
            ENDIF
        ENDIF
    ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG0 == 0)
	IF(PLAYER_GOOD,TIMER0 > 12000)
        IF(PLAYER_GOOD,FLAG2 == 4)
		NEXT_COMMAND_REUSABLE
        ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ENEMYSETUPC,-3,DUNGEON,2,2,300)
        NEXT_COMMAND_REUSABLE
        SET_FLAG(PLAYER_GOOD,FLAG2,5)
        ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG0 == 0)
	IF(PLAYER_GOOD,TIMER0 > 13000)
        IF(PLAYER_GOOD,FLAG1 == 0)
            IF(PLAYER_GOOD,FLAG2 == 5)
		    NEXT_COMMAND_REUSABLE
		    ADD_CREATURE_TO_LEVEL(PLAYER2,DRAWFROM(FAIRY,WIZARD),9,1,2,300)
            NEXT_COMMAND_REUSABLE
            SET_FLAG(PLAYER_GOOD,FLAG2,6)
            ENDIF
        ENDIF
    ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG0 == 0)
	IF(PLAYER_GOOD,TIMER0 > 16000)
        IF(PLAYER_GOOD,FLAG2 == 6)
		NEXT_COMMAND_REUSABLE
        ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ENEMYSETUPD,-4,DUNGEON,2,2,300)
        NEXT_COMMAND_REUSABLE
        SET_FLAG(PLAYER_GOOD,FLAG2,7)
        REM COMPUTER_DIG_TO_LOCATION(PLAYER2,10,11)
        ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG0 == 0)
	IF(PLAYER_GOOD,TIMER0 > 17000)
        IF(PLAYER_GOOD,FLAG1 == 0)
            IF(PLAYER_GOOD,FLAG2 == 7)
		    NEXT_COMMAND_REUSABLE
		    ADD_CREATURE_TO_LEVEL(PLAYER2,DRAWFROM(GIANT,MONK),9,1,2,300)
            NEXT_COMMAND_REUSABLE
            SET_FLAG(PLAYER_GOOD,FLAG2,0)
            NEXT_COMMAND_REUSABLE
		    SET_TIMER(PLAYER_GOOD,TIMER0)
            ENDIF
        ENDIF
    ENDIF
ENDIF




IF(PLAYER2,DUNGEON_DESTROYED >= 1)
	SET_FLAG(PLAYER_GOOD,FLAG0,1)
    SET_TIMER(PLAYER_GOOD,TIMER1)
	QUICK_OBJECTIVE(2, "That pretender and his forces were no match for your own and now his forces lie in the dirt. The foolish Lord of this realm likely assumes his Heroes dealt the final blow and is coming to reward them. Give him what he truly deserves.", 8)
ENDIF

IF(PLAYER_GOOD,TIMER1 >= 600)
    REM COMPUTE_FLAG(PLAYER_GOOD, FLAG4, SET, PLAYER_GOOD, TOTAL_CREATURES,1)
	REM DISPLAY_VARIABLE(PLAYER_GOOD, FLAG4, TOTAL_CREATURES, 1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LANDLORD,-1,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,HOUSEPARTY,-2,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,HOUSEPARTY,-3,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,HOUSEPARTY,-4,1)
	SET_TIMER(PLAYER_GOOD,TIMER1)
ENDIF

IF(PLAYER_GOOD,TIMER1 >= 800)
	IF_CONTROLS(PLAYER_GOOD,KNIGHT <= 0)
        SET_FLAG(PLAYER_GOOD,FLAG5,1)
		WIN_GAME
	ENDIF
ENDIF

REMOVE_SACRIFICE_RECIPE(GHOST)
SET_SACRIFICE_RECIPE(CUSTOMREWARD, FLAG6, BUG, HELL_HOUND,GHOST)
IF(PLAYER0,FLAG6 >= 1)
    QUICK_INFORMATION(3, "The dark gods have rewarded you.", 8)
    PLAY_MESSAGE(PLAYER0,SOUND,159)
    ADD_OBJECT_TO_LEVEL(SPECBOX_TRANSFR,8,0)
    IF(PLAYER2,CAMPAIGN_FLAG2 == 0)
	SET_FLAG(PLAYER2,CAMPAIGN_FLAG2,2)
    ENDIF
    IF(PLAYER2,CAMPAIGN_FLAG2 == 1)
        SET_FLAG(PLAYER2,CAMPAIGN_FLAG2,3)
    ENDIF
    IF(PLAYER2,CAMPAIGN_FLAG2 == 4)
        SET_FLAG(PLAYER2,CAMPAIGN_FLAG2,6)
    ENDIF
    IF(PLAYER2,CAMPAIGN_FLAG2 == 5)
        SET_FLAG(PLAYER2,CAMPAIGN_FLAG2,7)
    ENDIF
    SET_FLAG(PLAYER0,FLAG6,0)
ENDIF



REM ****************************************************************************
