REM ****************************************************************************
REM  Campaigns Consolidation Project for KeeperFX strategy game.
REM ****************************************************************************
REM  Script for Level Nevergrim
REM  Campaign: DK Original
REM  Authors:  based on Bullfrog script
REM            KeeperFX CCP Team
REM  Date:     17 Dec 1996 - 07 Sep 2014
REM  Copying and copyrights:
REM    This program is free software; you can redistribute it and/or modify
REM    it under the terms of the GNU General Public License as published by
REM    the Free Software Foundation; either version 2 of the License, or
REM    (at your option) any later version.
REM ****************************************************************************
LEVEL_VERSION(1)

REM New rooms for the player:
REM   SCAVENGER - researchable from start
REM New creatures for the player:
REM   DRAGON - able to attract from start
REM   HELL_HOUND - able to attract from start
REM New powers for the player:
REM   POWER_CAVE_IN - researchable from start
REM New manufacture for the player:
REM   TRAP_BOULDER - able to manufacture from start
REM Not introduced in this level:
REM   POWER_CHICKEN - introduced in level 11 to distribute new items equally amongst levels
REM   TRAP_ALARM - introduced in level 11 to distribute new items equally amongst levels
REM   TRAP_LAVA - introduced in level 12 to distribute new items equally amongst levels
REM   DOOR_MAGIC - introduced in level 13 to distribute new items equally amongst levels



SET_GENERATE_SPEED(350)
IF(PLAYER0,TOTAL_CREATURES < 10)
	NEXT_COMMAND_REUSABLE
	SET_GENERATE_SPEED(200)
ENDIF
IF(PLAYER0,TOTAL_CREATURES >= 10)
	NEXT_COMMAND_REUSABLE
	SET_GENERATE_SPEED(350)
ENDIF

REM very squished level, stops you losing traps on claim.
SET_ROOM_CONFIGURATION(WORKSHOP,TotalCapacity,slabs_all_wth_effcncy)

START_MONEY(PLAYER0,3500)
START_MONEY(PLAYER3,16000)

COMPUTER_PLAYER(PLAYER3,0)
REM Re-configure computer player
MAX_CREATURES(PLAYER0,15)
MAX_CREATURES(PLAYER3,25)

ADD_CREATURE_TO_POOL(BUG,20)
ADD_CREATURE_TO_POOL(SPIDER,20)
ADD_CREATURE_TO_POOL(SORCEROR,20)
ADD_CREATURE_TO_POOL(BILE_DEMON,10)
ADD_CREATURE_TO_POOL(DEMONSPAWN,12)
ADD_CREATURE_TO_POOL(TROLL,12)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,10)
ADD_CREATURE_TO_POOL(ORC,12)

REM	Creature availability
CREATURE_AVAILABLE(PLAYER0,BUG,1,0)
CREATURE_AVAILABLE(PLAYER0,SPIDER,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,DARK_MISTRESS,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS,ORC,1,0)
	
REM	Room availability
ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(PLAYER0,WORKSHOP,2,0)
ROOM_AVAILABLE(PLAYER3,WORKSHOP,1,1)
ROOM_AVAILABLE(PLAYER0,BARRACKS,4,0)
ROOM_AVAILABLE(PLAYER3,BARRACKS,1,0)
ROOM_AVAILABLE(PLAYER0,GUARD_POST,2,0)
ROOM_AVAILABLE(PLAYER0,PRISON,4,0)
ROOM_AVAILABLE(PLAYER0,TORTURE,4,0)
ROOM_AVAILABLE(PLAYER3,TORTURE,1,0)
ROOM_AVAILABLE(PLAYER0,TEMPLE,4,0)
ROOM_AVAILABLE(PLAYER3,TEMPLE,1,0)
REM ROOM_AVAILABLE(ALL_PLAYERS,GRAVEYARD,1,0)
REM ROOM_AVAILABLE(ALL_PLAYERS,SCAVENGER,1,0)
REM ROOM_AVAILABLE(PLAYER0,BRIDGE,1,0)

REM	Spells availability
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(PLAYER3,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(PLAYER3,POWER_SPEED,1,0)
MAGIC_AVAILABLE(PLAYER3,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CONCEAL,1,0)

REM	Doors and traps availability
REM DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
REM DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
TRAP_AVAILABLE(PLAYER0,BOULDER,1,0)

CREATE_PARTY(ALARMED_A)
	ADD_TO_PARTY(ALARMED_A,ARCHER,2,200,DEFEND_ROOMS,0)
	ADD_TO_PARTY(ALARMED_A,ARCHER,2,200,DEFEND_ROOMS,0)
	ADD_TO_PARTY(ALARMED_A,DWARFA,3,200,DEFEND_ROOMS,0)
	ADD_TO_PARTY(ALARMED_A,DWARFA,3,200,DEFEND_ROOMS,0)

CREATE_PARTY(ALARMED_B)
	ADD_TO_PARTY(ALARMED_B,THIEF,2,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ALARMED_B,THIEF,2,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ALARMED_B,DWARFA,3,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ALARMED_B,DWARFA,3,200,ATTACK_ENEMIES,0)

CREATE_PARTY(REINFORCEMENTS)
	ADD_TO_PARTY(REINFORCEMENTS,BARBARIAN,4,250,DEFEND_ROOMS,0)
	ADD_TO_PARTY(REINFORCEMENTS,BARBARIAN,4,250,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(REINFORCEMENTS,ARCHER,4,250,DEFEND_ROOMS,0)
	ADD_TO_PARTY(REINFORCEMENTS,ARCHER,4,250,ATTACK_ENEMIES,0)

CREATE_PARTY(EXTERMINATORS)
	ADD_TO_PARTY(EXTERMINATORS,FAIRY,5,500,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(EXTERMINATORS,GIANT,5,500,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(RANGERS)
	ADD_TO_PARTY(RANGERS,ARCHER,5,200,ATTACK_ENEMIES,0)
	REM ADD_TO_PARTY(RANGERS,SAMURAI,5,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(RANGERS,MONK,5,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(RANGERS,WIZARD,5,200,ATTACK_ENEMIES,0)

CREATE_PARTY(LANDLORD)
	ADD_TO_PARTY(LANDLORD,KNIGHT,7,1000,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,HELL_HOUND,6,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,DWARFA,5,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,DWARFA,5,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,DWARFA,5,200,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,DWARFA,5,200,ATTACK_ENEMIES,0)

REM ****************************************************************************

SET_PLAYER_COLOR(PLAYER1,WHITE)
SET_PLAYER_COLOR(PLAYER2,YELLOW)
COMPUTER_PLAYER(PLAYER5,ROAMING)
ALLY_PLAYERS(PLAYER2,PLAYER3,3)
ALLY_PLAYERS(PLAYER3,PLAYER5,3)
ALLY_PLAYERS(PLAYER3,PLAYER_GOOD,3)
ALLY_PLAYERS(PLAYER2,PLAYER_GOOD,3)

SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,ANY_CREATURE,7)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,IMP,7)
SET_CREATURE_PROPERTY(HELL_HOUND,EVENTFUL_DEATH,1)
SET_CREATURE_CONFIGURATION(HELL_HOUND,Health, 650)
SET_CREATURE_CONFIGURATION(HELL_HOUND,Defence,85)

REM Maybe add in custom bonus for "unlock bonus spells", if so, put Slow in first library, rebound and flight on the ones either side of the bridge, and freeze in DH.

QUICK_OBJECTIVE(4,"The Lord of this realm has grown prosperous, using the riches and heat below to power his factories. The previous tenants aren't too pleased, so his forces are trying to hold them back. They won't even see you coming.")

CONCEAL_MAP_RECT(PLAYER0,130,126,210,220,ALL)
CONCEAL_MAP_RECT(PLAYER0,25,19,15,15,ALL)
CONCEAL_MAP_RECT(PLAYER0,34,13,9,9,ALL)
CONCEAL_MAP_RECT(PLAYER0,16,25,3,3,ALL)
CONCEAL_MAP_RECT(PLAYER0,16,61,3,9,ALL)
CONCEAL_MAP_RECT(PLAYER0,22,109,9,9,ALL)
CONCEAL_MAP_RECT(PLAYER0,25,136,9,9,ALL)
CONCEAL_MAP_RECT(PLAYER0,13,202,9,9,ALL)
CONCEAL_MAP_RECT(PLAYER0,13,196,3,3,ALL)
CONCEAL_MAP_RECT(PLAYER0,71,240,2,2,ALL)
CONCEAL_MAP_RECT(PLAYER0,68,237,12,3,ALL)
CONCEAL_MAP_RECT(PLAYER0,115,244,15,2,ALL)
CONCEAL_MAP_RECT(PLAYER0,178,239,2,2,ALL)
CONCEAL_MAP_RECT(PLAYER0,173,238,2,2,ALL)

REVEAL_MAP_RECT(PLAYER0,127,64,21,21)
REVEAL_MAP_RECT(PLAYER0,163,64,9,9)

SET_ROOM_CONFIGURATION(BRIDGE,Properties,CANNOT_BE_SOLD,1)

SET_BOX_TOOLTIP(0, "Hint Crate")
SET_BOX_TOOLTIP(1, "Receive Imps")
ADD_OBJECT_TO_LEVEL(SPECBOX_CUSTOM,1,0,PLAYER_NEUTRAL)
SET_FLAG(PLAYER0,FLAG7,0)

REM If find all hounds, yay!
REM if more of them die than you have resurrect specials, play hound whimper sound and make the rest die or turn rogue

SET_TIMER(PLAYER0,TIMER0)

IF(PLAYER0,TIMER0 >= 2000)
	QUICK_INFORMATION(17,"The Lord's subterranean engine is behind the bolstered traps you've encountered. There are also many Workshops down here, so take them and use the Heroes' traps against them.",ALL_PLAYERS)
ENDIF
IF_ACTION_POINT(2,PLAYER0)
	ADD_CREATURE_TO_LEVEL(PLAYER0,HELL_HOUND,2,1,2,200)
	QUICK_INFORMATION(2,"You have found a Hellhound. He'll serve you well, but keep him safe - he has a habit of running off...",2)
	PLAY_MESSAGE(PLAYER0,SOUND,563)
ENDIF

IF(PLAYER0,TIMER0 >= 10000)
	SET_FLAG(PLAYER2,FLAG0,1)
ENDIF
IF_ACTION_POINT(11,PLAYER0)
	SET_FLAG(PLAYER2,FLAG0,1)
ENDIF
IF(PLAYER2,FLAG0 == 1)
		QUICK_OBJECTIVE(18,"The outposts of this realm are surprisingly well-stocked. No sense in doing your own work when you can simply take theirs.",ALL_PLAYERS)
ENDIF

REM Replace with APs just to confirm it.
IF(PLAYER0,HELL_HOUND == 1)
	SET_FLAG(PLAYER1,FLAG0,1)
ENDIF
IF(PLAYER0,HELL_HOUND == 2)
	QUICK_MESSAGE(7,"Hound found!",HELL_HOUND)
	PLAY_MESSAGE(PLAYER0,SOUND,563)
	SET_FLAG(PLAYER1,FLAG0,2)
ENDIF
IF(PLAYER0,HELL_HOUND == 3)
	QUICK_MESSAGE(8,"Hound found!",HELL_HOUND)
	PLAY_MESSAGE(PLAYER0,SOUND,563)
	SET_FLAG(PLAYER1,FLAG0,3)
ENDIF
IF(PLAYER0,HELL_HOUND == 4)
	QUICK_MESSAGE(9,"Hound found!",HELL_HOUND)
	PLAY_MESSAGE(PLAYER0,SOUND,563)
	SET_FLAG(PLAYER1,FLAG0,4)
ENDIF
IF(PLAYER0,HELL_HOUND == 5)
	QUICK_MESSAGE(10,"Hound found!",HELL_HOUND)
	PLAY_MESSAGE(PLAYER0,SOUND,563)
	SET_FLAG(PLAYER1,FLAG0,5)
ENDIF
IF(PLAYER0,HELL_HOUND == 6)
	QUICK_MESSAGE(11,"Hound found!",HELL_HOUND)
	PLAY_MESSAGE(PLAYER0,SOUND,563)
	SET_FLAG(PLAYER1,FLAG0,6)
	ADD_OBJECT_TO_LEVEL(SPECBOX_TRANSFR,10,1)
	QUICK_INFORMATION(14,"Well done, you've proven yourself a responsible pet owner. Hellhounds can now be recruited, and have been strengthened by your bond.",10)
	SET_FLAG(PLAYER1,CAMPAIGN_FLAG3,1)
ENDIF

IF(PLAYER0,HELL_HOUND < PLAYER1,FLAG0)
	QUICK_INFORMATION(3,"Maybe you weren't cut out to be a pet owner...",LAST_DEATH_EVENT[PLAYER0])
	PLAY_MESSAGE(PLAYER0,SOUND,562)
ENDIF

IF(PLAYER0,BOX0_ACTIVATED > 0)
	IF(PLAYER0,FLAG7 == 0)
		NEXT_COMMAND_REUSABLE
		QUICK_INFORMATION(1,"Bring the whole pack together.",ALL_PLAYERS,897)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER0,TIMER7)
		NEXT_COMMAND_REUSABLE
		SET_FLAG(PLAYER0,BOX0_ACTIVATED,0)
		NEXT_COMMAND_REUSABLE
		SET_FLAG(PLAYER0,FLAG7,1)
	ENDIF
ENDIF

IF(PLAYER0,BOX1_ACTIVATED > 0)
	NEXT_COMMAND_REUSABLE
	ADD_CREATURE_TO_LEVEL(PLAYER0,IMP,LAST_EVENT,4,3,500,JUMP)
	NEXT_COMMAND_REUSABLE
	PLAY_MESSAGE(PLAYER0,SOUND,488)
	NEXT_COMMAND_REUSABLE
	SET_FLAG(PLAYER0,BOX1_ACTIVATED,0)
ENDIF

IF(PLAYER0,TIMER7 >= 100)
	IF(PLAYER0,FLAG7 == 1)
		NEXT_COMMAND_REUSABLE
		CREATE_EFFECT(54,1)
		NEXT_COMMAND_REUSABLE
		ADD_OBJECT_TO_LEVEL(SPECBOX_CUSTOM, 1, 0)
		NEXT_COMMAND_REUSABLE
		SET_FLAG(PLAYER0,FLAG7,0)
	ENDIF
ENDIF

IF_ACTION_POINT(4,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ALARMED_A,3,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,ALARMED_B,4,1)
	QUICK_INFORMATION(16,"The heroes know you're here and have called for reinforcements.",ALL_PLAYERS)
ENDIF

IF_SLAB_TYPE(78,48,PRETTY_PATH)
	IF_AVAILABLE(PLAYER0,POWER_PROTECT == 0)
		ADD_OBJECT_TO_LEVEL(SPELLBOOK_PROT,12,1,PLAYER_GOOD)
	ENDIF
	IF_AVAILABLE(PLAYER0,POWER_CONCEAL == 0)
		ADD_OBJECT_TO_LEVEL(SPELLBOOK_CONCL,12,1,PLAYER_GOOD)
	ENDIF
ENDIF

IF_SLAB_TYPE(43,45,PATH)
	SET_FLAG(PLAYER0,FLAG4,1)
ENDIF
IF_SLAB_TYPE(42,44,PATH)
	SET_FLAG(PLAYER0,FLAG4,1)
ENDIF
IF_SLAB_TYPE(41,43,PATH)
	SET_FLAG(PLAYER0,FLAG4,1)
ENDIF
IF_SLAB_TYPE(40,43,PATH)
	SET_FLAG(PLAYER0,FLAG4,1)
ENDIF
IF_SLAB_TYPE(39,44,PATH)
	SET_FLAG(PLAYER0,FLAG4,1)
ENDIF
IF_SLAB_TYPE(38,45,PATH)
	SET_FLAG(PLAYER0,FLAG4,1)
ENDIF
IF_SLAB_TYPE(39,46,PATH)
	SET_FLAG(PLAYER0,FLAG4,1)
ENDIF
IF_SLAB_TYPE(40,47,PATH)
	SET_FLAG(PLAYER0,FLAG4,1)
ENDIF
IF_SLAB_TYPE(41,47,PATH)
	SET_FLAG(PLAYER0,FLAG4,1)
ENDIF
IF_SLAB_TYPE(42,46,PATH)
	SET_FLAG(PLAYER0,FLAG4,1)
ENDIF

IF(PLAYER0,FLAG4 == 1)
	QUICK_INFORMATION(5,"It seems this realm is home to a dragon, sealed inside the earth by the heroes who disturbed it. What was once a powerful beast has been driven mad, and you'll have to just put it down or let it cause havok. A shame, really.",13)
	REVEAL_MAP_RECT(PLAYER0,124,136,15,15)
ENDIF




IF(PLAYER0,TIMER0 >= 5000)
	IF_SLAB_OWNER(78,35,PLAYER0)
		IF_SLAB_OWNER(61,32,PLAYER_GOOD)
			NEXT_COMMAND_REUSABLE
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD,REINFORCEMENTS,-1,1)
		ENDIF
	ENDIF
	IF_SLAB_OWNER(55,45,PLAYER0)
		CREATURE_ENTRANCE_LEVEL(PLAYER0,2)
		IF_SLAB_OWNER(76,60,PLAYER1)
			NEXT_COMMAND_REUSABLE
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD,EXTERMINATORS,-4,1)
		ENDIF
	ENDIF
	IF_SLAB_OWNER(36,45,PLAYER0)
		IF_SLAB_OWNER(18,26,PLAYER_GOOD)
			NEXT_COMMAND_REUSABLE
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD,REINFORCEMENTS,-2,1)
			NEXT_COMMAND_REUSABLE
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD,EXTERMINATORS,-2,1)
		ENDIF
	ENDIF
	IF_SLAB_OWNER(8,57,PLAYER0)
		CREATURE_ENTRANCE_LEVEL(PLAYER0,3)
		IF_SLAB_OWNER(21,52,PLAYER_GOOD)
			NEXT_COMMAND_REUSABLE
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD,REINFORCEMENTS,-3,1)
			NEXT_COMMAND_REUSABLE
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD,EXTERMINATORS,-3,1)
		ENDIF
	ENDIF
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER0,TIMER0)
ENDIF

IF_ACTION_POINT(6,PLAYER0)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,RANGERS,7,1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,RANGERS,8,1)
ENDIF

IF_ACTION_POINT(5,PLAYER0)
	REVEAL_MAP_RECT(PLAYER0,16,29,9,9)
ENDIF

IF_SLAB_OWNER(61,32,PLAYER0)
	HIDE_HERO_GATE(1,1)
	ADD_TO_FLAG(PLAYER0,FLAG5,1)
ENDIF
IF_SLAB_OWNER(18,26,PLAYER0)
	HIDE_HERO_GATE(2,1)
	ADD_TO_FLAG(PLAYER0,FLAG5,1)
ENDIF
IF_SLAB_OWNER(21,52,PLAYER0)
	HIDE_HERO_GATE(3,1)
	ADD_TO_FLAG(PLAYER0,FLAG5,1)
ENDIF
IF_SLAB_OWNER(76,60,PLAYER0)
	HIDE_HERO_GATE(4,1)
	ADD_TO_FLAG(PLAYER0,FLAG5,1)
ENDIF
IF(PLAYER0,FLAG5 == 1)
	ADD_TO_PARTY(REINFORCEMENTS,BARBARIAN,5,250,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(REINFORCEMENTS,ARCHER,5,250,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(EXTERMINATORS,FAIRY,5,500,ATTACK_ENEMIES,0)
ENDIF
IF(PLAYER0,FLAG5 == 2)
	ADD_TO_PARTY(REINFORCEMENTS,BARBARIAN,5,250,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(REINFORCEMENTS,ARCHER,5,250,ATTACK_ENEMIES,0)
	REM ADD_TO_PARTY(EXTERMINATORS,FAIRY,6,500,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(EXTERMINATORS,GIANT,6,500,ATTACK_DUNGEON_HEART,0)
ENDIF
IF(PLAYER0,FLAG5 == 3)
	ADD_TO_PARTY(EXTERMINATORS,WITCH,6,500,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(EXTERMINATORS,WITCH,6,500,ATTACK_DUNGEON_HEART,0)
ENDIF

IF_ACTION_POINT(9,PLAYER0)
	QUICK_OBJECTIVE(15,"Behold, the engine powering the factories of this land. It's just begging to be destoyed.",9)
ENDIF

IF(PLAYER_GOOD,DUNGEON_DESTROYED == 1)
	SET_TIMER(PLAYER0,TIMER3)
	IF(PLAYER0,TIMER3 > 200)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,LANDLORD,9,1)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,EXTERMINATORS,9,1)
		QUICK_OBJECTIVE(6,"The Lord himself has come to stop whoever has ground his factories to a halt. Oh look, and he brought a dog of his own! Crush him.",9)
	ENDIF
	IF(PLAYER_GOOD,KNIGHT == 0)
		QUICK_OBJECTIVE(12,"The Lord is dead and the engine destroyed. The silence has alerted reinforcements from above as well as the other Keeper, so best you tidy that up too.")
		IF_SLAB_OWNER(61,32,PLAYER_GOOD)
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD,EXTERMINATORS,-1,1)
		ENDIF
		IF_SLAB_OWNER(18,26,PLAYER_GOOD)
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD,EXTERMINATORS,-2,1)
		ENDIF
		IF_SLAB_OWNER(21,52,PLAYER_GOOD)
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD,EXTERMINATORS,-3,1)
		ENDIF
		IF_SLAB_OWNER(76,60,PLAYER1)
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD,EXTERMINATORS,-4,1)
		ENDIF
	ENDIF
ENDIF

IF_SLAB_OWNER(7,78,PLAYER0)
	QUICK_INFORMATION(13,"You've found the Lord's designs for reinforced bridges. Find your enemy and close any remaining Hero Gates, unless you think you can all get along?",ALL_PLAYERS)
	ROOM_AVAILABLE(ALL_PLAYERS,BRIDGE,1,1)
	MAGIC_AVAILABLE(PLAYER3,POWER_CALL_TO_ARMS,1,1)
	TUTORIAL_FLASH_BUTTON(18,-1)
	CHANGE_SLAB_OWNER(20,76,PLAYER3,MATCH)
	CHANGE_SLAB_OWNER(20,74,PLAYER3,MATCH)
	CHANGE_SLAB_OWNER(22,68,PLAYER3,MATCH)
	CHANGE_SLAB_OWNER(41,58,PLAYER3,MATCH)
	CHANGE_SLAB_OWNER(60,76,PLAYER3,MATCH)
	SET_ROOM_CONFIGURATION(BRIDGE,Properties,CANNOT_BE_SOLD,0)
ENDIF

IF(PLAYER0,ALL_DUNGEONS_DESTROYED == 1)
	IF(PLAYER0,FLAG5 < 4)
		QUICK_OBJECTIVE(19,"Now you've sent him packing, all that's left is to shut down any remaining Hero Gates.",ALL_PLAYERS)
	ENDIF
	IF(PLAYER0,FLAG5 == 4)
		WIN_GAME
	ENDIF
ENDIF

REM ****************************************************************************
