LEVEL_VERSION(1)

REM Flags used:
REM   PLAYER_GOOD,FLAG0 - Continuous spawning of parties FIRST-FOURTH; 0-spawn; 1-stop spawning.
REM   PLAYER0,FLAG0 - bonus objective flag: 1 if successful, 2 if failed.
REM   PLAYER0,FLAG1 - midas door seen.
REM   PLAYER0,FLAG2 - seen any hero forts.
REM   PLAYER0,FLAG7 - hint crate respawn.
REM Timers used:
REM   PLAYER_GOOD,TIMER1 - Counter for continuous spawning of party FIRST
REM   PLAYER_GOOD,TIMER2 - Counter for continuous spawning of party SECOND
REM   PLAYER_GOOD,TIMER3 - Counter for continuous spawning of party THIRD
REM   PLAYER_GOOD,TIMER4 - Counter for continuous spawning of party FOURTH
REM   PLAYER0,TIMER1 - Starts counting after first wave of heroes (parties FIRST-FOURTH) are killed
REM   PLAYER0,TIMER2 - Starts counting after Lord of the Land appearance

REM ---------------------------------------------

RUN_AFTER_VICTORY(1)

REM just a silly workaround for midas door
SET_PLAYER_COLOR(PLAYER1,WHITE)
COMPUTER_PLAYER(PLAYER1,ROAMING)
COMPUTER_PLAYER(PLAYER5,ROAMING)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER1,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER5,3)

SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,ANY_CREATURE,7)
SET_CREATURE_MAX_LEVEL(ALL_PLAYERS,IMP,7)

SET_CREATURE_PROPERTY(TENTACLE,NO_IMPRISONMENT,1)
SET_CREATURE_PROPERTY(TENTACLE,NO_STEAL_HERO,1)

REM kind on player if they start to lose, as losing momentum is particularly painful on this map.
SET_GENERATE_SPEED(300)
IF_CONTROLS(PLAYER0,TOTAL_CREATURES <= 6)
	NEXT_COMMAND_REUSABLE
	SET_GENERATE_SPEED(150)
ENDIF
IF_CONTROLS(PLAYER0,TOTAL_CREATURES > 6)
	NEXT_COMMAND_REUSABLE
	SET_GENERATE_SPEED(300)
ENDIF

REM very squished level, stops you losing traps on claim.
SET_ROOM_CONFIGURATION(WORKSHOP,TotalCapacity,slabs_mul2_wth_effcncy)

START_MONEY(PLAYER0,1700)
START_MONEY(PLAYER_GOOD,1000000)

MAX_CREATURES(PLAYER0,20)

ADD_CREATURE_TO_POOL(BUG,20)
ADD_CREATURE_TO_POOL(FLY,20)
ADD_CREATURE_TO_POOL(SPIDER,20)
ADD_CREATURE_TO_POOL(DEMONSPAWN,20)
ADD_CREATURE_TO_POOL(SORCEROR,30)
ADD_CREATURE_TO_POOL(TROLL,20)
ADD_CREATURE_TO_POOL(BILE_DEMON,10)
ADD_CREATURE_TO_POOL(HELL_HOUND,30)
ADD_CREATURE_TO_POOL(ORC,15)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,20)

REM	Creature availability

CREATURE_AVAILABLE(PLAYER0,BUG,1,0)
CREATURE_AVAILABLE(PLAYER0,FLY,1,0)
CREATURE_AVAILABLE(PLAYER0,SPIDER,1,0)
CREATURE_AVAILABLE(PLAYER0,DEMONSPAWN,1,0)
CREATURE_AVAILABLE(PLAYER0,SORCEROR,1,0)
CREATURE_AVAILABLE(PLAYER0,TROLL,1,0)
CREATURE_AVAILABLE(PLAYER0,BILE_DEMON,1,0)
CREATURE_AVAILABLE(PLAYER0,HELL_HOUND,1,0)
CREATURE_AVAILABLE(PLAYER0,ORC,1,0)
CREATURE_AVAILABLE(PLAYER0,DARK_MISTRESS,1,0)
	
REM	Room availability
ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,2,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BRIDGE,4,0)
ROOM_AVAILABLE(ALL_PLAYERS,PRISON,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,0)

REM	Spells availability
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HOLD_AUDIENCE,1,0)

REM	Doors and traps availability
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,BOULDER,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,ALARM,1,0)

CREATE_PARTY(FIRST)
	ADD_TO_PARTY(FIRST,BARBARIAN,2,500,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(FIRST,GIANT,2,500,ATTACK_ENEMIES,0)

CREATE_PARTY(SECOND)
	ADD_TO_PARTY(SECOND,MONK,3,500,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(SECOND,MONK,3,500,ATTACK_ENEMIES,0)

CREATE_PARTY(THIRD)
	ADD_TO_PARTY(THIRD,ARCHER,4,500,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(THIRD,BARBARIAN,4,500,ATTACK_ENEMIES,0)

CREATE_PARTY(FOURTH)
	ADD_TO_PARTY(FOURTH,WIZARD,4,500,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(FOURTH,GIANT,4,500,ATTACK_ENEMIES,0)

CREATE_PARTY(FIFTH)
	ADD_TO_PARTY(FIFTH,WIZARD,5,500,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(FIFTH,WIZARD,5,750,ATTACK_ENEMIES,0)

CREATE_PARTY(SIXTH)
	ADD_TO_PARTY(SIXTH,MONK,6,500,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(SIXTH,MONK,6,500,ATTACK_ENEMIES,0)

CREATE_PARTY(SEVENTH)
	ADD_TO_PARTY(SEVENTH,FAIRY,6,500,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(SEVENTH,FAIRY,6,500,ATTACK_ENEMIES,0)

CREATE_PARTY(EIGHTH)
	ADD_TO_PARTY(EIGHTH,WITCH,6,500,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(EIGHTH,WITCH,6,500,ATTACK_ENEMIES,0)

CREATE_PARTY(LANDLORD)
	ADD_TO_PARTY(LANDLORD,KNIGHT,6,10000,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,ARCHER,6,900,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,BARBARIAN,6,900,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,MONK,6,900,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(LANDLORD,FAIRY,6,900,ATTACK_ENEMIES,0)

CREATE_PARTY(TENTS)
	ADD_TO_PARTY(TENTS,TENTACLE,5,0,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(TENTS,TENTACLE,5,0,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(TENTS,TENTACLE,5,0,ATTACK_DUNGEON_HEART,0)
	ADD_TO_PARTY(TENTS,TENTACLE,5,0,ATTACK_DUNGEON_HEART,0)

CREATE_PARTY(TROUBLE)
	ADD_TO_PARTY(TROUBLE,DWARFA,5,500,SABOTAGE_ROOMS,-400)
	ADD_TO_PARTY(TROUBLE,DWARFA,5,500,SABOTAGE_ROOMS,-400)
	ADD_TO_PARTY(TROUBLE,DWARFA,5,500,STEAL_SPELLS,-400)
	ADD_TO_PARTY(TROUBLE,DWARFA,5,500,STEAL_SPELLS,-400)
	ADD_TO_PARTY(TROUBLE,DWARFA,5,500,STEAL_GOLD,-400)
	ADD_TO_PARTY(TROUBLE,DWARFA,5,500,STEAL_GOLD,-400)

REM ****************************************************************************

IF(PLAYER1,CAMPAIGN_FLAG3 == 1)
	SET_CREATURE_CONFIGURATION(HELL_HOUND,Health,700)
	SET_CREATURE_CONFIGURATION(HELL_HOUND,Strength,60)
	SET_CREATURE_CONFIGURATION(HELL_HOUND,Dexterity,80)
	SET_CREATURE_CONFIGURATION(HELL_HOUND,Defence,85)
	SET_CREATURE_CONFIGURATION(HELL_HOUND,EntranceRoom,LAIR,GUARD_POST,GARDEN)
	SET_CREATURE_CONFIGURATION(HELL_HOUND,RoomSlabsRequired,9,4,1)
	SET_CREATURE_INSTANCE(HELL_HOUND, 4, FIREBALL, 4)
	SET_CREATURE_INSTANCE(HELL_HOUND, 7, EMBERS, 7)
	SET_CREATURE_INSTANCE(HELL_HOUND, 8, FIRE_BOMB, 8)
ENDIF

REM ****************************************************************************

REM - Bonus objective is to reach Tentacles before the heroes agitate them.
REM - Claim all four guard posts and stop Archers to turn the Midas Door to wood.
REM - Behind it is a storeroom containing a Demolition trap which can be used
REM - to go to the outer water area early and recruit tentacles.
REM - If you're too slow, Heroes will tunnel in and set them on you.

SET_BOX_TOOLTIP(0, "Hint Crate")
ADD_OBJECT_TO_LEVEL(SPECBOX_CUSTOM,11,0,PLAYER0)
SET_FLAG(PLAYER0,FLAG7,0)

IF(PLAYER0,BOX0_ACTIVATED > 0)
	IF(PLAYER0,FLAG7 == 0)
		NEXT_COMMAND_REUSABLE
		QUICK_INFORMATION(1,"Make a good impression on the locals.",ALL_PLAYERS,897)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER0,TIMER7)
		NEXT_COMMAND_REUSABLE
		SET_FLAG(PLAYER0,BOX0_ACTIVATED,0)
		NEXT_COMMAND_REUSABLE
		SET_FLAG(PLAYER0,FLAG7,1)
	ENDIF
ENDIF
IF(PLAYER0,TIMER7 >= 100)
	IF(PLAYER0,FLAG7 == 1)
		NEXT_COMMAND_REUSABLE
		CREATE_EFFECT(54,11)
		NEXT_COMMAND_REUSABLE
		ADD_OBJECT_TO_LEVEL(SPECBOX_CUSTOM,11,0,PLAYER0)
		NEXT_COMMAND_REUSABLE
		SET_FLAG(PLAYER0,FLAG7,0)
	ENDIF
ENDIF

REM - maybe swap this with a custom door with inpen rock texture.
IF_ACTION_POINT(10,PLAYER0)
	IF(PLAYER0,FLAG1 == 0)
		QUICK_INFORMATION(3,"This door won't break no matter how hard you hit it. I'm sure you'll be able to persuade its secrets out of the heroes.",10)
		SET_FLAG(PLAYER0,FLAG1,1)
	ENDIF
ENDIF

IF_SLAB_OWNER(13,42,PLAYER0)
	IF_SLAB_OWNER(43,16,PLAYER0)
		IF_SLAB_OWNER(71,42,PLAYER0)
			IF_SLAB_OWNER(42,71,PLAYER0)
				IF_CONTROLS(PLAYER1,ARCHER <= 2)
					ADD_GOLD_TO_PLAYER(PLAYER_GOOD,-1000000)
					REM CHANGE_SLAB_TYPE(28,50,PRETTY_PATH,NONE)
					REM PLACE_DOOR(PLAYER_GOOD,WOOD,28,50,LOCKED,FREE)
					IF(PLAYER0,FLAG1 == 0)
						QUICK_INFORMATION(4,"You've learnt how to access a secret storehouse nearby. Sounds ripe for plundering.")
						SET_FLAG(PLAYER0,FLAG1,2)
					ENDIF
					IF(PLAYER0,FLAG1 == 1)
						QUICK_INFORMATION(5,"You've learnt the secret to how that strange door works and will be able to break it down. They must be guarding something good.")
						SET_FLAG(PLAYER0,FLAG1,2)
					ENDIF
				ENDIF
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF_SLAB_OWNER(28,51,PLAYER0)
	IF(PLAYER0,FLAG0 == 0)
		QUICK_INFORMATION(6,"You have uncovered a wealth of traps to use as you see fit, alongside plans to rile up the beasts of this land against you. They would make a fine addition to your forces should you reach them first.")
		CHANGE_SLAB_OWNER(28,53,PLAYER0,NONE)
		TUTORIAL_FLASH_BUTTON(64,-1)
	ENDIF
ENDIF

IF(PLAYER0,BRIDGE > 0)
	IF(PLAYER0,FLAG0 < 2)
		SET_FLAG(PLAYER0,FLAG0,1)
	ENDIF
ENDIF

REM - If player gets to the Hero fortresses the slow way i.e. from Tunnellers, it's too late and roaming Tentacles will start swarming in.
REM - If player has broken their way in early, the Tentacles are neutral creatures found in the water and the raiding party is fought now.

IF_ACTION_POINT(5,PLAYER0)
	IF(PLAYER0,FLAG0 == 0)
		SET_FLAG(PLAYER0,FLAG0,2)
	ENDIF
	IF(PLAYER0,FLAG0 == 1)
		ADD_CREATURE_TO_LEVEL(PLAYER_NEUTRAL,TENTACLE,6,4,5,0,DEFAULT)
		ADD_CREATURE_TO_LEVEL(PLAYER_NEUTRAL,TENTACLE,7,4,5,0,DEFAULT)
		ADD_CREATURE_TO_LEVEL(PLAYER_NEUTRAL,TENTACLE,8,4,5,0,DEFAULT)
		ADD_CREATURE_TO_LEVEL(PLAYER_NEUTRAL,TENTACLE,9,4,5,0,DEFAULT)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,TROUBLE,-1,1)
		QUICK_INFORMATION(12,"Seems you've caught the Lord's raiding party with their breeches down. Clean up before he notices.")
	ENDIF
ENDIF

REM ------------------------------------

QUICK_OBJECTIVE(2,"You find yourself surrounded by the heroes of this land, the Lord is planning something big, and your creatures hate each other. Nothing like a challenge, eh?")

REM - wave spawning largely unchanged besides time between.

REM Spawn continuously the FIRST party
IF(PLAYER_GOOD,GAME_TURN >= 1500)
	SET_TIMER(PLAYER_GOOD,TIMER1)
ENDIF

IF(PLAYER_GOOD,FLAG0 == 0)
	IF(PLAYER_GOOD,TIMER1 > 1850)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FIRST,3,1)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER_GOOD,TIMER1)
	ENDIF
ENDIF

REM Spawn continuously the SECOND party
IF(PLAYER_GOOD,GAME_TURN >= 1850)
	SET_TIMER(PLAYER_GOOD,TIMER2)
ENDIF

IF(PLAYER_GOOD,FLAG0 == 0)
	IF(PLAYER_GOOD,TIMER2 > 2350)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SECOND,1,1)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER_GOOD,TIMER2)
	ENDIF
ENDIF

REM Spawn continuously the THIRD party
IF(PLAYER_GOOD,GAME_TURN >= 2350)
	SET_TIMER(PLAYER_GOOD,TIMER3)
ENDIF

IF(PLAYER_GOOD,FLAG0 == 0)
	IF(PLAYER_GOOD,TIMER3 > 2850)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,THIRD,2,1)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER_GOOD,TIMER3)
	ENDIF
ENDIF

REM Spawn continuously the FOURTH party
IF(PLAYER_GOOD,GAME_TURN >= 2850)
	SET_TIMER(PLAYER_GOOD,TIMER4)
ENDIF

IF(PLAYER_GOOD,FLAG0 == 0)
	IF(PLAYER_GOOD,TIMER4 > 3350)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FOURTH,4,1)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER_GOOD,TIMER4)
	ENDIF
ENDIF

IF_ACTION_POINT(13,PLAYER0)
	SET_FLAG(PLAYER0,FLAG2,1)
ENDIF
IF_ACTION_POINT(14,PLAYER0)
	SET_FLAG(PLAYER0,FLAG2,1)
ENDIF
IF_ACTION_POINT(15,PLAYER0)
	SET_FLAG(PLAYER0,FLAG2,1)
ENDIF
IF_ACTION_POINT(16,PLAYER0)
	SET_FLAG(PLAYER0,FLAG2,1)
ENDIF

IF(PLAYER_GOOD,GAME_TURN >= 7000)
	IF(PLAYER0,FLAG2 == 0)
		QUICK_OBJECTIVE(13,"These hero fortifications must be well-defended for a reason. Go and check them out.")
	ENDIF
ENDIF

REM Stop spawning continuous parties after a given amount of turns
IF(PLAYER_GOOD,GAME_TURN >= 20000)
	SET_FLAG(PLAYER_GOOD,FLAG0,1)
	IF_CONTROLS(PLAYER_GOOD,TOTAL_CREATURES <= 5)
		IF_CONTROLS(PLAYER_GOOD,BARBARIAN <= 0)
			IF_CONTROLS(PLAYER_GOOD,MONK <= 0)
				SET_TIMER(PLAYER0,TIMER1)
				IF(PLAYER0,TIMER1 >= 1000)
					QUICK_OBJECTIVE(7,"The invading forces are taking their time to regroup. Now would be a good time to do the same.")
					DISPLAY_COUNTDOWN(PLAYER0,TIMER1,5000,0)
				ENDIF
			ENDIF
		ENDIF
	ENDIF
ENDIF

REM Start a second wave
IF(PLAYER0,TIMER1 >= 5000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FIFTH,1,1)
ENDIF
IF(PLAYER0,TIMER1 >= 5500)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SIXTH,2,1)
ENDIF
IF(PLAYER0,TIMER1 >= 6000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SEVENTH,3,1)
ENDIF
IF(PLAYER0,TIMER1 >= 6500)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,EIGHTH,4,1)
ENDIF
IF(PLAYER0,TIMER1 >= 7000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,FIFTH,1,1)
ENDIF
IF(PLAYER0,TIMER1 >= 7500)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SIXTH,2,1)
ENDIF
IF(PLAYER0,TIMER1 >= 8000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SEVENTH,3,1)
ENDIF
IF(PLAYER0,TIMER1 >= 8500)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD,EIGHTH,4,1)
ENDIF

REM - After these waves, send a Tunneller party to raid you and release the roaming Tentacles.
REM - Unless, of course, you've grabbed them already, in which case spawn the LOTL.
IF(PLAYER0,TIMER1 >= 10000)
	IF_CONTROLS(PLAYER_GOOD,TOTAL_CREATURES < 5)
		IF_CONTROLS(PLAYER_GOOD,WIZARD <= 0)
			IF_CONTROLS(PLAYER_GOOD,MONK <= 0)
				IF_CONTROLS(PLAYER_GOOD,FAIRY <= 0)
					IF_CONTROLS(PLAYER_GOOD,WITCH <= 0)
						IF(PLAYER0,FLAG0 != 1)
							ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TROUBLE,-1,DUNGEON_HEART,0,6,500)
							QUICK_OBJECTIVE(8,"Knock knock, Keeper. I hear the murmuring of rock and splashing of water. Whatever is coming, be ready.",5)
							SET_FLAG(PLAYER0,FLAG0,2)
						ENDIF
						IF(PLAYER0,FLAG0 == 1)
							IF(PLAYER0,TENTACLE > 0)
								QUICK_OBJECTIVE(9,"Rumour has it the Lord of the Land is furious his plan failed and is coming to deal with you directly. Introduce him to your new friends.")
								SET_TIMER(PLAYER0,TIMER3)
							ENDIF
						ENDIF
					ENDIF
				ENDIF
			ENDIF
		ENDIF
	ENDIF
ENDIF	

REM - If the player fails in some way (raiding party arrives or somehow the player cheats and gets to the AP),
REM - then there were definitely bridge platforms there the whole time for angry Tentacles to swarm in.
IF(PLAYER0,FLAG0 == 2)
	CHANGE_SLAB_TYPE(10,25,BRIDGE_FRAME,NONE)
	CHANGE_SLAB_TYPE(10,26,BRIDGE_FRAME,NONE)
	CHANGE_SLAB_TYPE(10,27,BRIDGE_FRAME,NONE)
	CHANGE_SLAB_TYPE(15,20,BRIDGE_FRAME,NONE)
	CHANGE_SLAB_TYPE(16,20,BRIDGE_FRAME,NONE)
	CHANGE_SLAB_TYPE(17,20,BRIDGE_FRAME,NONE)
	CHANGE_SLAB_OWNER(10,26,PLAYER_GOOD,MATCH)
	CHANGE_SLAB_OWNER(16,20,PLAYER_GOOD,MATCH)
	SET_DOOR(UNLOCKED,16,23)
	SET_DOOR(UNLOCKED,13,26)
	ADD_PARTY_TO_LEVEL(PLAYER5,TENTS,6,1)
	ADD_PARTY_TO_LEVEL(PLAYER5,TENTS,7,1)
	ADD_PARTY_TO_LEVEL(PLAYER5,TENTS,8,1)
	ADD_PARTY_TO_LEVEL(PLAYER5,TENTS,9,1)
	SET_OBJECT_CONFIGURATION(SPECBOX_CUSTOM,AnimationID,INERTSPECIAL)
	SET_OBJECT_CONFIGURATION(SPECBOX_CUSTOM,AnimationSpeed,0)
	SET_OBJECT_CONFIGURATION(SPECBOX_CUSTOM,LightRadius,0)
	SET_OBJECT_CONFIGURATION(SPECBOX_CUSTOM,LightIntensity,0)
	IF_CONTROLS(PLAYER5,TENTACLE <=3)
		QUICK_OBJECTIVE(10,"The Lord of the Land is on his way, hoping to finish you off. Add his corpse to the pile.")
		SET_TIMER(PLAYER0,TIMER3)
	ENDIF
ENDIF

IF(PLAYER0,TIMER3 >= 200)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,LANDLORD,-1,DUNGEON_HEART,0,6,500)
	SET_TIMER(PLAYER0,TIMER2)
ENDIF

IF(PLAYER0,TIMER2 >= 200)
	IF_CONTROLS(PLAYER_GOOD,KNIGHT <= 0)
		IF(PLAYER0,FLAG0 == 1)
			QUICK_OBJECTIVE(11,"The denizens of this realm show their thanks and have decided to join you. Well done.",ALL_PLAYERS)
			PLAY_MESSAGE(PLAYER0,SOUND,159)
			ADD_OBJECT_TO_LEVEL(SPECBOX_TRANSFR,12,0)
			QUICK_INFORMATION(14,"Good work, Keeper. Use this gift wisely.",12)
			SET_FLAG(PLAYER1,CAMPAIGN_FLAG4,1)
			IF(PLAYER2,CAMPAIGN_FLAG3 == 0)
				SET_FLAG(PLAYER2,CAMPAIGN_FLAG3,2)
			ENDIF
			IF(PLAYER2,CAMPAIGN_FLAG3 == 1)
				SET_FLAG(PLAYER2,CAMPAIGN_FLAG3,3)
			ENDIF
			IF(PLAYER2,CAMPAIGN_FLAG3 == 4)
				SET_FLAG(PLAYER2,CAMPAIGN_FLAG3,6)
			ENDIF
			IF(PLAYER2,CAMPAIGN_FLAG3 == 5)
				SET_FLAG(PLAYER2,CAMPAIGN_FLAG3,7)
			ENDIF
		ENDIF
		WIN_GAME
	ENDIF
ENDIF	

REM ****************************************************************************



REM add lower capture/convert chance after a while