REM ********************************************
REM
REM             Script for Level 202
REM
REM ********************************************
LEVEL_VERSION(1)
SET_GENERATE_SPEED(400)

SET_TEXTURE(PLAYER_GOOD,18)

MAX_CREATURES(PLAYER0, 15)
START_MONEY(PLAYER0, 15000)

ADD_CREATURE_TO_POOL(WARLOCK, 5)
ADD_CREATURE_TO_POOL(FIREFLY, 2)
ADD_CREATURE_TO_POOL(GOBLIN, 6)
ADD_CREATURE_TO_POOL(TROLL, 6)


CREATURE_AVAILABLE(ALL_PLAYERS, WARLOCK, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, FIREFLY, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, GOBLIN, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, TROLL, 1, 0)

SET_CREATURE_PROPERTY(KNIGHT,LORD,0)
SET_GAME_RULE(MaxThingsInHand,30)

SET_GAME_RULE(TrainingRoomMaxLevel,4)

ROOM_AVAILABLE(ALL_PLAYERS, RESEARCH, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GARDEN, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, LAIR, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TRAINING, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TREASURE, 3, 0)
ROOM_AVAILABLE(ALL_PLAYERS, WORKSHOP, 1, 1)

MAGIC_AVAILABLE(ALL_PLAYERS, POWER_HAND, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SIGHT, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SLAP, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_IMP, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_LIGHTNING, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_POSSESS, 1, 0)

DOOR_AVAILABLE(ALL_PLAYERS, WOOD, 1, 0)
TRAP_AVAILABLE(ALL_PLAYERS, EVIL_SENTRY,1,0)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_POSSESS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_IMP,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_LIGHTNING,1,0)

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_IMP == 1)
    SET_POWER_CONFIGURATION(POWER_IMP,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_IMP,PanelTabIndex,2)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_SIGHT == 1)
    SET_POWER_CONFIGURATION(POWER_SIGHT,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_SIGHT,PanelTabIndex,3)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_LIGHTNING == 1)
    SET_POWER_CONFIGURATION(POWER_LIGHTNING,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_LIGHTNING,PanelTabIndex,11)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_POSSESS == 1)
    SET_POWER_CONFIGURATION(POWER_POSSESS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_POSSESS,PanelTabIndex,1)
ENDIF

CREATE_PARTY(DOOR1A)
ADD_TO_PARTY(DOOR1A, DWARFA, 1, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(DOOR1B)
ADD_TO_PARTY(DOOR1B, THIEF, 1, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(DOOR2)
ADD_TO_PARTY(DOOR2, THIEF, 1, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR2, THIEF, 1, 300, ATTACK_ENEMIES, 0)

IF(PLAYER1,CAMPAIGN_FLAG1 == 1)
	CONCEAL_MAP_RECT(Player0, 25, 25, 243, 243,1)
	REVEAL_MAP_LOCATION(PLAYER0,5,6)
	REVEAL_MAP_LOCATION(PLAYER0,PLAYER0,-1)
ENDIF

SET_HAND_RULE(PLAYER0,ANY_CREATURE,RULE1,DENY,DROPPED_TIME_LOWER,60)
IF(PLAYER0,TIMER0 >= 40)
    QUICK_OBJECTIVE(20,"Lord Avaricious hides within his fortress proud. He is well defended but gold's his weakness. To lure him from his stronghold, mine all the gold within this realm.")
    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl3spe01.ogg")
ENDIF

IF(PLAYER0, FIREFLY >= 1)
    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl1spe06.ogg")
    QUICK_INFORMATION(6,"The swift light Firefly is essential as an airborne scout. His eyes are yours to penetrate dark places and report.")
ENDIF

REM START INTRO

NEXT_COMMAND_REUSABLE
SET_CREATURE_TENDENCIES(PLAYER_GOOD,IMPRISON,1)

RUN_AFTER_VICTORY(1)

COMPUTER_PLAYER(PLAYER6,ROAMING)
ALLY_PLAYERS(PLAYER0,PLAYER6,3)
ALLY_PLAYERS(PLAYER0,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER6,3)
SET_PLAYER_COLOR(PLAYER6,RED)

SET_TIMER(PLAYER0,TIMER0)

IF(PLAYER0,TIMER0 >= 30)
    ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,FAKELORD,3,1,3,0,INITIALIZE)
    SET_POWER_CONFIGURATION(POWER_SIGHT,SoundPlayed,0)
    USE_POWER_AT_LOCATION(PLAYER0,3,POWER_SIGHT,6,1)
ENDIF


IF(PLAYER0,TIMER0 >= 10)
	IF(PLAYER0,TIMER0 <= 199)
		NEXT_COMMAND_REUSABLE
    	ZOOM_TO_LOCATION(PLAYER0,6)
	ENDIF
ENDIF

IF(PLAYER0,TIMER0 >= 200)
    ZOOM_TO_LOCATION(PLAYER0,PLAYER0)
    SET_POWER_CONFIGURATION(POWER_SIGHT,POWER,10,6)
    USE_POWER_AT_LOCATION(PLAYER0,3,POWER_SIGHT,6,1)
ENDIF

IF(PLAYER0,TIMER0 >= 220)
    SET_POWER_CONFIGURATION(POWER_SIGHT,SoundPlayed,51)
    SET_POWER_CONFIGURATION(POWER_SIGHT,POWER,896,6)
    KILL_CREATURE(PLAYER_GOOD,FAKELORD,ANYWHERE,1)
ENDIF

REM SETTINGS

IF(PLAYER0,DUNGEON_DESTROYED== 1)
  CHANGE_SLAB_TYPE(24,34,PATH,MATCH)
ENDIF

IF(PLAYER0,TIMER0 >= 400)
        PLAY_MESSAGE(PLAYER0,SPEECH,"lvl3spe02.ogg")
    	QUICK_INFORMATION(21,"A Workshop should be built so Trolls will come and use it for their fabrication, benefiting you with Traps and Doors to help defend your underground creation.")
ENDIF

IF(PLAYER0, TREASURE >= 1)
        PLAY_MESSAGE(PLAYER0,SPEECH,"lvl3spe05.ogg")
    	QUICK_INFORMATION(22,"A Treasury allows more gold to be amassed. If placed near seams of gold, your Imps will not have far to carry it.")
ENDIF

IF(PLAYER0, TROLL >= 1)
        PLAY_MESSAGE(PLAYER0,SPEECH,"lvl3spe03.ogg")
    	QUICK_INFORMATION(23,"A Troll arrives, attracted by the splendour of your Workshop. His craftsman skills are set to serve you well as one whose toil will make both Traps and Doors for you to use in your defence.")
ENDIF

IF_AVAILABLE(PLAYER0, WOOD >= 1)
        PLAY_MESSAGE(PLAYER0,SPEECH,"lvl3spe06.ogg")
    	QUICK_INFORMATION(24,"Place well your Wooden Doors in narrow tunnels to slow down hostile enemies as they invade.")
ENDIF

IF_AVAILABLE(PLAYER0, EVIL_SENTRY >= 1)
        PLAY_MESSAGE(PLAYER0,SPEECH,"lvl3spe07.ogg")
    	QUICK_INFORMATION(25,"The Sentry Trap will fire magic bolts which damage any of your foes within its range.")
ENDIF

IF_ACTION_POINT(4, PLAYER0)
	SET_FLAG(PLAYER_GOOD, FLAG0, 0)
	SET_FLAG(PLAYER_GOOD, FLAG1, 0)
	SET_TIMER(PLAYER0, TIMER2)
	SET_TIMER(PLAYER0, TIMER1)
ENDIF

IF(PLAYER_GOOD, FLAG0 == 0)
	IF(PLAYER0, TIMER2 >= 2040)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR1A, -1, 1)
		
		IF(PLAYER0, TIMER2 >= 4080)
			NEXT_COMMAND_REUSABLE
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR1B, -1, 1)
		ENDIF
		
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER0, TIMER2)
	ENDIF
ENDIF

IF_SLAB_OWNER(44,13,PLAYER0)
	IF_SLAB_OWNER(45,13,PLAYER0)
		IF_SLAB_OWNER(46,13,PLAYER0)
			IF_SLAB_OWNER(47,13,PLAYER0)
				IF_SLAB_OWNER(44,14,PLAYER0)
					IF_SLAB_OWNER(44,15,PLAYER0)
						IF_SLAB_OWNER(44,16,PLAYER0)
							IF_SLAB_OWNER(45,16,PLAYER0)
								IF_SLAB_OWNER(46,16,PLAYER0)
									IF_SLAB_OWNER(47,16,PLAYER0)
										IF_SLAB_OWNER(47,15,PLAYER0)
											IF_SLAB_OWNER(47,14,PLAYER0)
	                                            SET_FLAG(PLAYER_GOOD, FLAG0, 1)
                                                PLAY_MESSAGE(PLAYER0,SPEECH,"lvl3spe08.ogg")
    	                                        QUICK_INFORMATION(26,"You've claimed the land around the Hero Gate and thus broken it. No more thieving Heroes will invade your realm this way!")
												CHANGE_SLAB_TYPE(45,14,BROKEN_ENTRANCE2x2,MATCH)
                                                ZOOM_TO_LOCATION(PLAYER0,-1)
												HIDE_HERO_GATE(-1,1)
												CREATE_EFFECT(EFFECT_HARMLESS_GAS_1,-1)
												USE_POWER_AT_LOCATION(PLAYER_GOOD,-1,POWER_CAVE_IN,6,1)
												CREATE_EFFECT(EFFECT_HARMLESS_GAS_1,1)
												USE_POWER_AT_LOCATION(PLAYER_GOOD,1,POWER_CAVE_IN,6,1)
												CREATE_EFFECT(EFFECT_HARMLESS_GAS_1,8)
												USE_POWER_AT_LOCATION(PLAYER_GOOD,8,POWER_CAVE_IN,6,1)
												PLAY_MESSAGE(PLAYER0,SOUND,152)
											ENDIF
										ENDIF
									ENDIF
								ENDIF
							ENDIF
						ENDIF
					ENDIF
				ENDIF
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF_SLAB_OWNER(8,12,PLAYER0)
	IF_SLAB_OWNER(9,12,PLAYER0)
		IF_SLAB_OWNER(10,12,PLAYER0)
			IF_SLAB_OWNER(11,12,PLAYER0)
				IF_SLAB_OWNER(11,13,PLAYER0)
					IF_SLAB_OWNER(8,13,PLAYER0)
						IF_SLAB_OWNER(8,14,PLAYER0)
							IF_SLAB_OWNER(8,15,PLAYER0)
								IF_SLAB_OWNER(9,15,PLAYER0)
									IF_SLAB_OWNER(10,15,PLAYER0)
										IF_SLAB_OWNER(11,15,PLAYER0)
											IF_SLAB_OWNER(11,14,PLAYER0)
	                                            SET_FLAG(PLAYER_GOOD, FLAG1, 1)
                                                PLAY_MESSAGE(PLAYER0,SPEECH,"lvl3spe08.ogg")
    	                                        QUICK_INFORMATION(26,"You've claimed the land around the Hero Gate and thus broken it. No more thieving Heroes will invade your realm this way!")
												CHANGE_SLAB_TYPE(9,13,BROKEN_ENTRANCE2x2,MATCH)
                                                ZOOM_TO_LOCATION(PLAYER0,-2)
												HIDE_HERO_GATE(-2,1)
												CREATE_EFFECT(EFFECT_HARMLESS_GAS_1,-2)
												USE_POWER_AT_LOCATION(PLAYER_GOOD,-2,POWER_CAVE_IN,6,1)
												CREATE_EFFECT(EFFECT_HARMLESS_GAS_1,9)
												USE_POWER_AT_LOCATION(PLAYER_GOOD,9,POWER_CAVE_IN,6,1)
												CREATE_EFFECT(EFFECT_HARMLESS_GAS_1,10)
												USE_POWER_AT_LOCATION(PLAYER_GOOD,10,POWER_CAVE_IN,6,1)
												PLAY_MESSAGE(PLAYER0,SOUND,152)
											ENDIF
										ENDIF
									ENDIF
								ENDIF
							ENDIF
						ENDIF
					ENDIF
				ENDIF
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD, FLAG1 == 0)
	IF(PLAYER0, TIMER1 >= 1440)
		NEXT_COMMAND_REUSABLE
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR2, -2, 1)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER0, TIMER1)
	ENDIF
ENDIF

IF(PLAYER0,TOTAL_GOLD_MINED >= 20000)
		PLAY_MESSAGE(PLAYER0,SPEECH,"lvl3spe09.ogg")
        QUICK_OBJECTIVE(27,"To lure Lord Avaricious from his stronghold, mine all the gold within his realm.")
ENDIF

IF(PLAYER0,TOTAL_GOLD_MINED >= 40000)
		PLAY_MESSAGE(PLAYER0,SPEECH,"lvl3spe10.ogg")
        QUICK_OBJECTIVE(28,"You need more gold.  Explore and find it: send your Imps to mine it!")
ENDIF

IF(PLAYER0,TOTAL_GOLD_MINED >= 69000)
	IF(PLAYER_GOOD,KNIGHT == 1)
			RUN_LUA_CODE("StopPatrol()")
			PLAY_MESSAGE(PLAYER0,SPEECH,"lvl3spe04.ogg")
			QUICK_OBJECTIVE(29,"You thieving Keeper!  I will punish you for daring to despoil my land.")
	ENDIF
ENDIF

REM PL3,FLAG5 active music track
rem value 2: dk2track02.mp3
rem value 4: dk2track04.mp3
SET_MUSIC("dk2track01.mp3")
SET_FLAG(PLAYER3,FLAG5,2)

IF(PLAYER3,FLAG5 != 4)
    REM Time battle music been playing
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER7)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES == 0)
	REM Time battle has been going on
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER3,TIMER6)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES > 0)
    REM Time no battle has been going on
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER5)
ENDIF

REM Start battle music if battle has been going on for at least 60 gameturns (3 seconds) and is not already playing
IF(PLAYER3,TIMER6 > 60)
    IF(PLAYER3,FLAG5 != 4)
		IF(PLAYER6,TIMER2 >=1200)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("battle01.mp3")
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER3,FLAG5,4)
		ENDIF
    ENDIF
ENDIF

REM Start only Battle Music if it hasn't been played for 1min

SET_TIMER(PLAYER6,TIMER2)
ADD_TO_TIMER(PLAYER6,TIMER2,1100)

IF(PLAYER3,FLAG5 == 4)
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER6,TIMER2)
ENDIF

REM Start regular music if battle music lasted at least 15 seconds and no fighting has occured for at least 5 seconds
IF(PLAYER3,TIMER7 > 300)
    IF(PLAYER3,TIMER5 > 100)
        IF(PLAYER3,FLAG5 != 2)
            NEXT_COMMAND_REUSABLE
            SET_MUSIC("dk2track01.mp3")
            NEXT_COMMAND_REUSABLE
            SET_FLAG(PLAYER3,FLAG5,2)
        ENDIF
    ENDIF
ENDIF

SET_TIMER(PLAYER0,TIMER2)

IF(PLAYER0,TIMER2 >= 250)
   		IF(PLAYER0,IMP <= 4)
        		NEXT_COMMAND_REUSABLE
			ADD_CREATURE_TO_LEVEL(PLAYER0,IMP,PLAYER0,2,1,100)
        		NEXT_COMMAND_REUSABLE
        		SET_TIMER(PLAYER0,TIMER2)
		ENDIF
ENDIF 

REM WIN CONDITION

SET_TIMER(PLAYER2,TIMER4)

IF(PLAYER_GOOD, KNIGHT == 0)
	IF(PLAYER2,TIMER4 >= 1100)
		PLAY_MESSAGE(PLAYER0,SPEECH,"lvl3spe11.ogg")
		QUICK_OBJECTIVE(30,"Success, my evil friend, another Portal Gem is yours. Your wickedness inspires us all, your sinful way's a glory to behold!")
		ADD_OBJECT_TO_LEVEL(FAKE_GEM,LAST_DEATH_EVENT[PLAYER_GOOD],1,PLAYER5)
		COMPUTER_PLAYER(PLAYER5,ROAMING)
		SET_TIMER(PLAYER6,TIMER6)
		WIN_GAME
		REVEAL_MAP_LOCATION(PLAYER0,PLAYER_GOOD,-1)	
	ENDIF
ENDIF

REM OUTRO

HIDE_HERO_GATE(4,1)

IF(PLAYER6,TIMER6 >= 20)
    MAGIC_AVAILABLE(PLAYER0,POWER_POSSESS,0,0)
ENDIF

IF(PLAYER6,TIMER6 >= 60)
    ZOOM_TO_LOCATION(PLAYER0,-4)
    CREATE_EFFECT(EFFECT_FLASH,PLAYER0)
ENDIF

IF(PLAYER6,TIMER6 >= 70)
    CREATE_EFFECT(EFFECT_WORD_OF_POWER,-4)
    CREATE_EFFECT(EFFECT_EXPLOSION_5,-4)
    CREATE_EFFECT(EFFECT_SPANGLE_RED,-4)
    ADD_OBJECT_TO_LEVEL(HORNY_SPAWN,-4,1,PLAYER0,South)
ENDIF

IF(PLAYER6,TIMER6 >= 138)
	RUN_LUA_CODE("SpawnHorny(-4)")
	SET_OBJECT_CONFIGURATION(HORNY_SPAWN,MaximumSize,0)
ENDIF

IF(PLAYER5,HEART_HEALTH > 0)
    SET_FLAG(PLAYER0,FLAG0,8)
ENDIF

IF(PLAYER0,FLAG0 == 8)
    IF(PLAYER5,HEART_HEALTH < 3)
        SET_OBJECT_CONFIGURATION(FAKE_GEM,UpdateFunction,UPDATE_POWER_LIGHTNING)
        SET_TIMER(PLAYER6,TIMER7)
    ENDIF
ENDIF

IF(PLAYER6,TIMER7 > 5)
    PLAY_MESSAGE(PLAYER0,SOUND,116)
ENDIF

IF(PLAYER6,TIMER7 > 100)
    KILL_CREATURE(PLAYER6,EVILLORD,ANYWHERE,1)
ENDIF