REM ********************************************
REM
REM             Script for Level 203
REM
REM ********************************************
LEVEL_VERSION(1)
SET_GENERATE_SPEED(400)

SET_TEXTURE(PLAYER_GOOD,18)

MAX_CREATURES(PLAYER0, 15)
START_MONEY(PLAYER0, 3000)

REM For Testing Only ----------
REM REVEAL_MAP_RECT(PLAYER0,127,127,254,254)

REM -------------

ADD_CREATURE_TO_POOL(WARLOCK, 4)
ADD_CREATURE_TO_POOL(TROLL, 4)
ADD_CREATURE_TO_POOL(FIREFLY, 2)
ADD_CREATURE_TO_POOL(GOBLIN, 4)
ADD_CREATURE_TO_POOL(DARK_ELF,6)

CREATURE_AVAILABLE(ALL_PLAYERS, WARLOCK, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, FIREFLY, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, TROLL, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, GOBLIN, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, DARK_ELF,1,0)

SET_GAME_RULE(TrainingRoomMaxLevel,4)

ROOM_AVAILABLE(ALL_PLAYERS, RESEARCH, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GARDEN, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, LAIR, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TRAINING, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TREASURE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, WORKSHOP, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GUARD_POST, 3, 0)

MAGIC_AVAILABLE(ALL_PLAYERS, POWER_HAND, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SIGHT, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SLAP, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_IMP, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_LIGHTNING, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_POSSESS, 1, 0)

DOOR_AVAILABLE(ALL_PLAYERS, WOOD, 1, 0)
TRAP_AVAILABLE(ALL_PLAYERS, EVIL_SENTRY, 1, 0)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_POSSESS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_IMP,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_LIGHTNING,1,0)

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_IMP == 1)
    SET_POWER_CONFIGURATION(POWER_IMP,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_IMP,PanelTabIndex,2)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_SIGHT == 1)
    SET_POWER_CONFIGURATION(POWER_SIGHT,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_SIGHT,PanelTabIndex,3)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_LIGHTNING == 1)
    SET_POWER_CONFIGURATION(POWER_LIGHTNING,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_LIGHTNING,PanelTabIndex,11)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_POSSESS == 1)
    SET_POWER_CONFIGURATION(POWER_POSSESS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_POSSESS,PanelTabIndex,1)
ENDIF

REVEAL_MAP_LOCATION(PLAYER0,PLAYER0,-1)

REM # "Happy Box: All friendly minions get happy."

SET_BOX_TOOLTIP(10,"Make Happy Box")

IF(PLAYER0,BOX10_ACTIVATED == 1)
    NEXT_COMMAND_REUSABLE
    CHANGE_CREATURES_ANNOYANCE(PLAYER0,ANY_CREATURE,SET,0)
    NEXT_COMMAND_REUSABLE
    CHANGE_CREATURES_ANNOYANCE(PLAYER0,IMP,SET,0)
    NEXT_COMMAND_REUSABLE
    SET_FLAG(PLAYER0,BOX10_ACTIVATED,0)
ENDIF

RUN_AFTER_VICTORY(1)

SET_GAME_RULE(MaxThingsInHand,30)
SET_HAND_RULE(PLAYER0,ANY_CREATURE,RULE1,DENY,DROPPED_TIME_LOWER,60)
SET_CREATURE_PROPERTY(KNIGHT,LORD,0)

IF(PLAYER1,CAMPAIGN_FLAG1 == 1)
	CONCEAL_MAP_RECT(Player0, 5, 5, 440, 440,1)
    REVEAL_MAP_LOCATION(PLAYER0,5,6)
    REVEAL_MAP_LOCATION(PLAYER0,PLAYER0,-1)
ENDIF

CREATE_PARTY(DOOR1A)
ADD_TO_PARTY(DOOR1A, DWARFA, 1, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR1A, DWARFA, 2, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(DOOR1B)
ADD_TO_PARTY(DOOR1B, THIEF, 1, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR1B, THIEF, 2, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR1B, BARBARIAN, 1, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(DOOR2A)
ADD_TO_PARTY(DOOR2A, DWARFA, 1, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR2A, DWARFA, 2, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR2A, THIEF, 2, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(DOOR2B)
ADD_TO_PARTY(DOOR2B, BARBARIAN, 1, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR2B, DWARFA, 2, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR2B, THIEF, 2, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(DOOR3A)
ADD_TO_PARTY(DOOR3A, DWARFA, 2, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR3A, THIEF, 2, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(DOOR4A)
ADD_TO_PARTY(DOOR4A, DWARFA, 2, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR4A, BARBARIAN, 2, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(DOOR4B)
ADD_TO_PARTY(DOOR4B, BARBARIAN, 2, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR4B, BARBARIAN, 2, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR4B, THIEF, 1, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(DOOR5A)
ADD_TO_PARTY(DOOR5A, THIEF, 3, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR5A, THIEF, 2, 300, ATTACK_ENEMIES, 0)

if(player0,ENTRANCE == 9)
  next_command_reusable
  max_creatures(Player0,15)
ENDIF
if(player0,ENTRANCE == 18)
  next_command_reusable
  max_creatures(Player0,20)
ENDIF

REM START INTRO

NEXT_COMMAND_REUSABLE
SET_CREATURE_TENDENCIES(PLAYER_GOOD,IMPRISON,1)

RUN_AFTER_VICTORY(1)

COMPUTER_PLAYER(PLAYER6,ROAMING)
ALLY_PLAYERS(PLAYER0,PLAYER6,3)
ALLY_PLAYERS(PLAYER0,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER6,3)
SET_PLAYER_COLOR(PLAYER6,RED)

SET_TIMER(PLAYER0,TIMER4)

IF(PLAYER0,TIMER4 >= 30)
    SET_POWER_CONFIGURATION(POWER_SIGHT,SoundPlayed,0)
    USE_POWER_AT_LOCATION(PLAYER0,6,POWER_SIGHT,6,1)
ENDIF


IF(PLAYER0,TIMER4 >= 10)
	IF(PLAYER0,TIMER4 <= 199)
		NEXT_COMMAND_REUSABLE
    	ZOOM_TO_LOCATION(PLAYER0,7)
	ENDIF
ENDIF

IF(PLAYER0,TIMER4 >= 200)
    ZOOM_TO_LOCATION(PLAYER0,PLAYER0)
    SET_POWER_CONFIGURATION(POWER_SIGHT,POWER,10,6)
    USE_POWER_AT_LOCATION(PLAYER0,7,POWER_SIGHT,6,1)
ENDIF

IF(PLAYER0,TIMER4 >= 220)
    SET_POWER_CONFIGURATION(POWER_SIGHT,SoundPlayed,51)
    SET_POWER_CONFIGURATION(POWER_SIGHT,POWER,896,6)
ENDIF

REM SETTINGS

IF(PLAYER0,DUNGEON_DESTROYED== 1)
  CHANGE_SLAB_TYPE(25,60,PATH,MATCH)
ENDIF

IF(PLAYER0,TIMER4 >= 20)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl4spe01.ogg")
	QUICK_OBJECTIVE(32,"Lord Ludwig knows of your intentions, evil Keeper. But mark, he cowers in his castle locked away, behind what he supposes is the safety of the drawbridge now destroyed by his own hand. From here he has entrusted your destruction to his goodly warriors, whom he feels are more than equal to the task.  For our part, we must know that they and he will perish, slain by forces under your command.")
ENDIF

IF (PLAYER0, GUARD_POST >= 1)
	    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl4spe03.ogg")
    QUICK_OBJECTIVE(33,"The Guardroom. Drop your creatures here to keep them lively and alert, thence ready for the fight. The flashing area which surrounds it marks the zone where any brush with trouble by your creatures will give cause for them to dash back and report, so reinforcements can be found.  Make sure there's adequate provision for your minions needs nearby, for though they are on guard, they still require their creature comforts, and it's wise to minimise the time they stray from duty.")
ENDIF

IF (PLAYER0, DARK_ELF >= 1)
	    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl4spe02.ogg")
    QUICK_INFORMATION(34,"Behold the Dark Elf. Her sniping skills as sharp as bolted arrows which she shoots. She serves you well in line behind your fighters, and excels in duty as a guard.")
ENDIF

IF_ACTION_POINT(4, PLAYER0)
	SET_TIMER(PLAYER0, TIMER0)
	IF(PLAYER0, TIMER0 >= 500)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR1A, -5, 1)
		IF(PLAYER0, TIMER0 >= 2000)
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR2A, -6, 1)
			IF(PLAYER0, TIMER0 >= 4500)
				ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR1B, -5, 1)
				IF(PLAYER0, TIMER0 >= 5750)
					ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR2B, -6, 1)
				ENDIF
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF(PLAYER0,TOTAL_CREATURES > 3)
	SET_TIMER(PLAYER0, TIMER1)
ENDIF

IF(PLAYER0, TIMER1 >= 1650)
		ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR4A, -1,DUNGEON_HEART,1,1,0)
ENDIF
IF(PLAYER0, TIMER1 >= 3500)
		ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR2B, -1,DUNGEON_HEART,1,1,0)
ENDIF

IF(PLAYER0, TIMER1 >= 750)
		ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR3A, -2,DUNGEON_HEART,1,1,0)
ENDIF

IF(PLAYER0, TIMER1 >= 5000)
		ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR4B, -2,DUNGEON_HEART,1,1,0)
ENDIF

IF_ACTION_POINT(3, PLAYER0)
	IF(PLAYER_GOOD,KNIGHT==1)
    	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl4spe04.ogg")
    	QUICK_OBJECTIVE(36,"My sword will pierce your Heart, Keeper.")
	ENDIF
ENDIF

REM PL3,FLAG5 active music track
rem value 2: dk2track02.mp3
rem value 4: dk2track04.mp3
SET_MUSIC("dk2track02.mp3")
SET_FLAG(PLAYER3,FLAG5,2)

IF(PLAYER3,FLAG5 != 4)
    REM Time battle music been playing
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER7)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES == 0)
	REM Time battle has been going on
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER3,TIMER6)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES > 0)
    REM Time no battle has been going on
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER5)
ENDIF

REM Start battle music if battle has been going on for at least 60 gameturns (3 seconds) and is not already playing
IF(PLAYER3,TIMER6 > 60)
    IF(PLAYER3,FLAG5 != 4)
		IF(PLAYER6,TIMER2 >=1200)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("battle02.mp3")
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER3,FLAG5,4)
		ENDIF
    ENDIF
ENDIF

REM Start only Battle Music if it hasn't been played for 1min

SET_TIMER(PLAYER6,TIMER2)
ADD_TO_TIMER(PLAYER6,TIMER2,1100)

IF(PLAYER3,FLAG5 == 4)
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER6,TIMER2)
ENDIF

REM Start regular music if battle music lasted at least 15 seconds and no fighting has occured for at least 5 seconds
IF(PLAYER3,TIMER7 > 300)
    IF(PLAYER3,TIMER5 > 100)
        IF(PLAYER3,FLAG5 != 2)
            NEXT_COMMAND_REUSABLE
            SET_MUSIC("dk2track02.mp3")
            NEXT_COMMAND_REUSABLE
            SET_FLAG(PLAYER3,FLAG5,2)
        ENDIF
    ENDIF
ENDIF

SET_TIMER(PLAYER0,TIMER2)

IF(PLAYER0,TIMER2 >= 250)
   		IF(PLAYER0,IMP <= 4)
        		NEXT_COMMAND_REUSABLE
			ADD_CREATURE_TO_LEVEL(PLAYER0,IMP,PLAYER0,2,1,100)
        		NEXT_COMMAND_REUSABLE
        		SET_TIMER(PLAYER0,TIMER2)
		ENDIF
ENDIF 

REM WIN CONDITION

IF_ACTION_POINT(3, PLAYER0)
	IF(PLAYER_GOOD,KNIGHT==1)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR1A, -3, 1)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR1B, -3, 1)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR2A, -4, 1)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR2B, -4, 1)
	ENDIF
ENDIF


IF(PLAYER_GOOD, KNIGHT == 0)
  	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl4spe05.ogg")
	QUICK_INFORMATION(37,"Your deeds impress me, Keeper - your new found skills are suitably employed. But mark, you'll need both brain and brawn to overcome your foe, so keep your wits about you well and victory will be yours..")
	WIN_GAME
    ADD_OBJECT_TO_LEVEL(FAKE_GEM,LAST_DEATH_EVENT[PLAYER_GOOD],1,PLAYER5)
    COMPUTER_PLAYER(PLAYER5,ROAMING)
    SET_TIMER(PLAYER6,TIMER6)
	REVEAL_MAP_LOCATION(PLAYER0,PLAYER_GOOD,-1)
ENDIF

REM OUTRO

HIDE_HERO_GATE(7,1)

IF(PLAYER6,TIMER6 >= 20)
    MAGIC_AVAILABLE(PLAYER0,POWER_POSSESS,0,0)
ENDIF

IF(PLAYER6,TIMER6 >= 60)
    ZOOM_TO_LOCATION(PLAYER0,-7)
    CREATE_EFFECT(EFFECT_FLASH,PLAYER0)
ENDIF

IF(PLAYER6,TIMER6 >= 70)
    CREATE_EFFECT(EFFECT_WORD_OF_POWER,-7)
    CREATE_EFFECT(EFFECT_EXPLOSION_5,-7)
    CREATE_EFFECT(EFFECT_SPANGLE_RED,-7)
    ADD_OBJECT_TO_LEVEL(HORNY_SPAWN,-7,1,PLAYER0,South)
ENDIF

IF(PLAYER6,TIMER6 >= 138)
	RUN_LUA_CODE("SpawnHorny(-7)")
	SET_OBJECT_CONFIGURATION(HORNY_SPAWN,MaximumSize,0)
ENDIF

IF(PLAYER5,HEART_HEALTH > 0)
    SET_FLAG(PLAYER0,FLAG0,8)
ENDIF

IF(PLAYER0,FLAG0 == 8)
    IF(PLAYER5,HEART_HEALTH < 3)
        SET_OBJECT_CONFIGURATION(FAKE_GEM,UpdateFunction,UPDATE_POWER_LIGHTNING)
        SET_TIMER(PLAYER6,TIMER7)
    ENDIF
ENDIF

IF(PLAYER6,TIMER7 > 5)
    PLAY_MESSAGE(PLAYER0,SOUND,116)
ENDIF

IF(PLAYER6,TIMER7 > 100)
    KILL_CREATURE(PLAYER6,EVILLORD,ANYWHERE,1)
ENDIF