REM ********************************************
REM
REM             Script for Level 206
REM
REM ********************************************
LEVEL_VERSION(1)
SET_GENERATE_SPEED(500)
MAX_CREATURES(PLAYER0, 15)
START_MONEY(PLAYER0, 2000)

SET_TEXTURE(PLAYER_GOOD,18)

ADD_CREATURE_TO_POOL(WARLOCK, 10)
ADD_CREATURE_TO_POOL(GOBLIN, 10)
ADD_CREATURE_TO_POOL(TROLL, 10)
ADD_CREATURE_TO_POOL(MISTRESS, 10)
ADD_CREATURE_TO_POOL(SALAMANDER, 10)
ADD_CREATURE_TO_POOL(DARK_ELF,20)

CREATURE_AVAILABLE(ALL_PLAYERS, WARLOCK, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, GOBLIN, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, TROLL, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, MISTRESS, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, SALAMANDER, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, DARK_ELF,1,0)

SET_GAME_RULE(TrainingRoomMaxLevel,4)

ROOM_AVAILABLE(ALL_PLAYERS, RESEARCH, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GARDEN, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, LAIR, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TRAINING, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TREASURE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, WORKSHOP, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, BRIDGE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TORTURE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, PRISON, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GUARD_POST, 1, 1)

MAGIC_AVAILABLE(ALL_PLAYERS, POWER_HAND, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_OBEY, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SLAP, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_IMP, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_LIGHTNING, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_HEAL_CREATURE, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_CALL_TO_ARMS, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SIGHT, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_POSSESS, 1, 1)

DOOR_AVAILABLE(ALL_PLAYERS, WOOD, 1, 0)
TRAP_AVAILABLE(ALL_PLAYERS, EVIL_SENTRY, 1, 0)
TRAP_AVAILABLE(ALL_PLAYERS, BARRICADE_TRAP_EVIL,1,0)
TRAP_AVAILABLE(ALL_PLAYERS, FEAR_TRAP,1,0)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_POSSESS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_IMP,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_LIGHTNING,1,0)

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_IMP == 1)
    SET_POWER_CONFIGURATION(POWER_IMP,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_IMP,PanelTabIndex,2)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_OBEY == 1)
    SET_POWER_CONFIGURATION(POWER_OBEY,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_OBEY,PanelTabIndex,5)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_SIGHT == 1)
    SET_POWER_CONFIGURATION(POWER_SIGHT,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_SIGHT,PanelTabIndex,3)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_CALL_TO_ARMS == 1)
    SET_POWER_CONFIGURATION(POWER_CALL_TO_ARMS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_CALL_TO_ARMS,PanelTabIndex,6)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_HEAL_CREATURE == 1)
    SET_POWER_CONFIGURATION(POWER_HEAL_CREATURE,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_HEAL_CREATURE,PanelTabIndex,10)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_LIGHTNING == 1)
    SET_POWER_CONFIGURATION(POWER_LIGHTNING,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_LIGHTNING,PanelTabIndex,11)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_POSSESS == 1)
    SET_POWER_CONFIGURATION(POWER_POSSESS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_POSSESS,PanelTabIndex,1)
ENDIF

SET_CREATURE_CONFIGURATION(GIANT,BaseSpeed,20)

IF(PLAYER1,CAMPAIGN_FLAG1 == 1)
	CONCEAL_MAP_RECT(Player0, 120, 120, 240, 240,1)
	REVEAL_MAP_LOCATION(PLAYER0,PLAYER0,-1)
ENDIF

SET_HAND_RULE(PLAYER0,ANY_CREATURE,RULE1,DENY,DROPPED_TIME_LOWER,60)
SET_GAME_RULE(MaxThingsInHand,30)

if(player0,ENTRANCE == 9)
  next_command_reusable
  max_creatures(Player0,15)
ENDIF
if(player0,ENTRANCE == 18)
  next_command_reusable
  max_creatures(Player0,20)
ENDIF
if(player0,ENTRANCE == 27)
  next_command_reusable
  max_creatures(Player0,25)
ENDIF

CREATE_PARTY(DOOR1A)
ADD_TO_PARTY(DOOR1A, GIANT, 2, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR1A, GIANT, 2, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(DOOR1B)
ADD_TO_PARTY(DOOR1B, GIANT, 3, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(DOOR1C)
ADD_TO_PARTY(DOOR1C, GIANT, 3, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(DOOR1C, GIANT, 3, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(GIANTS)
ADD_TO_PARTY(GIANTS, GIANT, 4, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(GIANTS, GIANT, 4, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(GUARDS)
ADD_TO_PARTY(GUARDS, BARBARIAN, 3, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(GUARDS, BARBARIAN, 3, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(GUARDS, BARBARIAN, 3, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(GUARDS, BARBARIAN, 3, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(DOOR10)
ADD_TO_PARTY(DOOR10, GIANT, 1, 300, DEFEND_LOCATION, 0)

CREATE_PARTY(DOOR20)
ADD_TO_PARTY(DOOR20, GIANT, 2, 300, DEFEND_LOCATION, 0)

IF(PLAYER0, TIMER4 >= 50)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR10, 1, 1)
   	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR20, 7, 1) 
  	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR20, 8, 1)  
ENDIF

IF(PLAYER0,TIMER4 >= 40)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl7spe01.ogg")
	QUICK_OBJECTIVE(50,"Behold the fate of Dungeon Hearts and Keepers who do fail in this domain. For there are Giants who roam this land and do its good Lords bidding. Mark, these beasts are vicious as their size. And bolstered by this victory they now seek your demise.")
ENDIF

IF(PLAYER0,TIMER4 >= 400)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl7spe06.ogg")
	QUICK_INFORMATION(55,"The Giant is mighty as the ancient oak, with skin as tough as bark. While his brain is but a tiny acorn, so he's slow in wits and motion, use your speed and missiles.")
ENDIF

IF(PLAYER0,DUNGEON_DESTROYED== 1)
  CHANGE_SLAB_TYPE(4,14,PATH,MATCH)
ENDIF

REM INTRO

NEXT_COMMAND_REUSABLE
SET_CREATURE_TENDENCIES(PLAYER_GOOD,IMPRISON,1)

RUN_AFTER_VICTORY(1)

COMPUTER_PLAYER(PLAYER6,ROAMING)
ALLY_PLAYERS(PLAYER0,PLAYER6,3)
ALLY_PLAYERS(PLAYER0,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER6,3)
SET_PLAYER_COLOR(PLAYER6,RED)

SET_TIMER(PLAYER0,TIMER4)

IF(PLAYER0,TIMER4 >= 30)
    SET_POWER_CONFIGURATION(POWER_SIGHT,SoundPlayed,0)
    USE_POWER_AT_LOCATION(PLAYER0,4,POWER_SIGHT,6,1)
ENDIF

IF(PLAYER0,TIMER4 >= 10)
	IF(PLAYER0,TIMER4 <= 99)
		NEXT_COMMAND_REUSABLE
    	ZOOM_TO_LOCATION(PLAYER0,5)
	ENDIF
ENDIF

IF(PLAYER0,TIMER4 >= 110)
    ZOOM_TO_LOCATION(PLAYER0,PLAYER0)
    SET_POWER_CONFIGURATION(POWER_SIGHT,POWER,10,6)
    USE_POWER_AT_LOCATION(PLAYER0,5,POWER_SIGHT,6,1)
ENDIF

IF(PLAYER0,TIMER4 >= 120)
    SET_POWER_CONFIGURATION(POWER_SIGHT,SoundPlayed,51)
    SET_POWER_CONFIGURATION(POWER_SIGHT,POWER,896,6)
ENDIF

REM SETTINGS

IF(PLAYER0,SALAMANDER ==1)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl7spe02.ogg")
	QUICK_INFORMATION(51,"Behold a Salamander: graceful ancient lizard who cannot be harmed by fire. He'll even wade through lava streams with no impediment.")
ENDIF

IF_ACTION_POINT(8, PLAYER0)
	SET_TIMER(PLAYER0, TIMER0)
	IF(PLAYER0, TIMER0 >= 2750)
		ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR1A, -1, 1)
		IF(PLAYER0, TIMER0 >= 4250)
			ADD_PARTY_TO_LEVEL(PLAYER_GOOD, DOOR1A, -2, 1)
		ENDIF
	ENDIF
ENDIF

IF_ACTION_POINT(2, PLAYER0)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl7spe03.ogg")
	QUICK_INFORMATION(52,"The entrance to Lord Sigmunds Fort is accessible through many different passages. These offer resistance of varying degree.")
ENDIF

REM PL3,FLAG5 active music track
rem value 2: dk2track02.mp3
rem value 4: dk2track04.mp3
SET_MUSIC("dk2track03.mp3")
SET_FLAG(PLAYER3,FLAG5,2)

IF(PLAYER3,FLAG5 != 4)
    REM Time battle music been playing
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER7)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES == 0)
	REM Time battle has been going on
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER3,TIMER6)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES > 0)
    REM Time no battle has been going on
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER5)
ENDIF

REM Start battle music if battle has been going on for at least 60 gameturns (3 seconds) and is not already playing
IF(PLAYER3,TIMER6 > 60)
    IF(PLAYER3,FLAG5 != 4)
		IF(PLAYER6,TIMER2 >=1200)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("battle04.mp3")
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER3,FLAG5,4)
		ENDIF
    ENDIF
ENDIF

REM Start only Battle Music if it hasn't been played for 1min

SET_TIMER(PLAYER6,TIMER2)
ADD_TO_TIMER(PLAYER6,TIMER2,1100)

IF(PLAYER3,FLAG5 == 4)
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER6,TIMER2)
ENDIF

REM Start regular music if battle music lasted at least 15 seconds and no fighting has occured for at least 5 seconds
IF(PLAYER3,TIMER7 > 300)
    IF(PLAYER3,TIMER5 > 100)
        IF(PLAYER3,FLAG5 != 2)
            NEXT_COMMAND_REUSABLE
            SET_MUSIC("dk2track03.mp3")
            NEXT_COMMAND_REUSABLE
            SET_FLAG(PLAYER3,FLAG5,2)
        ENDIF
    ENDIF
ENDIF

SET_TIMER(PLAYER0,TIMER2)

IF(PLAYER0,TIMER2 >= 250)
   	IF(PLAYER0,IMP <= 4)
        NEXT_COMMAND_REUSABLE
		ADD_CREATURE_TO_LEVEL(PLAYER0,IMP,PLAYER0,2,1,100)
        NEXT_COMMAND_REUSABLE
        SET_TIMER(PLAYER0,TIMER2)
	ENDIF
ENDIF 

REM WIN CONDITION

IF_ACTION_POINT(3, PLAYER0)
	QUICK_OBJECTIVE(53,"Before this day is done your lifes blood will spill on the unforgiving earth.")
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl7spe04.ogg")
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, GUARDS, -3, 1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, GIANTS, -4, 1)
	IF(PLAYER_GOOD, KNIGHT == 0)
		QUICK_OBJECTIVE(54,"The Land Lord now lies wasted and his fort destroyed around him. So the Portal Gem is yours, and I salute your efforts, Evil Keeper.")
		PLAY_MESSAGE(PLAYER0,SPEECH,"lvl7spe05.ogg")
		WIN_GAME	
		SET_NEXT_LEVEL(207)	
  	 	ADD_OBJECT_TO_LEVEL(FAKE_GEM,LAST_DEATH_EVENT[PLAYER_GOOD],1,PLAYER5)
 		COMPUTER_PLAYER(PLAYER5,ROAMING)
 		SET_TIMER(PLAYER6,TIMER6)
		REVEAL_MAP_LOCATION(PLAYER0,PLAYER_GOOD,-1)
	ENDIF
ENDIF

REM OUTRO

HIDE_HERO_GATE(5,1)

IF(PLAYER6,TIMER6 >= 20)
    MAGIC_AVAILABLE(PLAYER0,POWER_POSSESS,0,0)
ENDIF

IF(PLAYER6,TIMER6 >= 60)
    ZOOM_TO_LOCATION(PLAYER0,-5)
    CREATE_EFFECT(EFFECT_FLASH,PLAYER0)
ENDIF

IF(PLAYER6,TIMER6 >= 70)
    CREATE_EFFECT(EFFECT_WORD_OF_POWER,-5)
    CREATE_EFFECT(EFFECT_EXPLOSION_5,-5)
    CREATE_EFFECT(EFFECT_SPANGLE_RED,-5)
    ADD_OBJECT_TO_LEVEL(HORNY_SPAWN,-5,1,PLAYER0,South)
ENDIF

IF(PLAYER6,TIMER6 >= 138)
	RUN_LUA_CODE("SpawnHorny(-5)")
	SET_OBJECT_CONFIGURATION(HORNY_SPAWN,MaximumSize,0)
ENDIF

IF(PLAYER5,HEART_HEALTH > 0)
    SET_FLAG(PLAYER0,FLAG0,8)
ENDIF

IF(PLAYER0,FLAG0 == 8)
    IF(PLAYER5,HEART_HEALTH < 3)
        SET_OBJECT_CONFIGURATION(FAKE_GEM,UpdateFunction,UPDATE_POWER_LIGHTNING)
        SET_TIMER(PLAYER6,TIMER7)
    ENDIF
ENDIF

IF(PLAYER6,TIMER7 > 5)
    PLAY_MESSAGE(PLAYER0,SOUND,116)
ENDIF

IF(PLAYER6,TIMER7 > 100)
    KILL_CREATURE(PLAYER6,EVILLORD,ANYWHERE,1)
ENDIF