REM ********************************************
REM
REM             Script for Level 208
REM
REM ********************************************

LEVEL_VERSION(1)
BONUS_LEVEL_TIME(17900)

SET_GENERATE_SPEED(400)
MAX_CREATURES(PLAYER0, 15)
START_MONEY(PLAYER0, 1500)

SET_TEXTURE(PLAYER_GOOD,18)

ADD_CREATURE_TO_POOL(WARLOCK, 3)
ADD_CREATURE_TO_POOL(GOBLIN, 2)
ADD_CREATURE_TO_POOL(TROLL, 3)
ADD_CREATURE_TO_POOL(FIREFLY, 1)
ADD_CREATURE_TO_POOL(MISTRESS, 2)
ADD_CREATURE_TO_POOL(BILE_DEMON, 4)
ADD_CREATURE_TO_POOL(DARK_ELF,2)
ADD_CREATURE_TO_POOL(ROGUE,8)

CREATURE_AVAILABLE(ALL_PLAYERS, WARLOCK, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, GOBLIN, 1, 1)
CREATURE_AVAILABLE(ALL_PLAYERS, FIREFLY, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, TROLL, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, MISTRESS, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, BILE_DEMON, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, DARK_ELF,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS, ROGUE,1,0)

SET_GAME_RULE(TrainingRoomMaxLevel,4)

ROOM_AVAILABLE(ALL_PLAYERS, RESEARCH, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GARDEN, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, LAIR, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TRAINING, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TREASURE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, WORKSHOP, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TORTURE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, PRISON, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, BRIDGE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, STONE_BRIDGE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, CASINO, 1, 1)

MAGIC_AVAILABLE(ALL_PLAYERS, POWER_HAND, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_OBEY, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SLAP, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_IMP, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_LIGHTNING, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_HEAL_CREATURE, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SIGHT, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_CALL_TO_ARMS, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_POSSESS, 1, 0)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_POSSESS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_IMP,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_LIGHTNING,1,0)

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_IMP == 1)
    SET_POWER_CONFIGURATION(POWER_IMP,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_IMP,PanelTabIndex,2)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_OBEY == 1)
    SET_POWER_CONFIGURATION(POWER_OBEY,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_OBEY,PanelTabIndex,5)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_SIGHT == 1)
    SET_POWER_CONFIGURATION(POWER_SIGHT,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_SIGHT,PanelTabIndex,3)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_CALL_TO_ARMS == 1)
    SET_POWER_CONFIGURATION(POWER_CALL_TO_ARMS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_CALL_TO_ARMS,PanelTabIndex,6)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_HEAL_CREATURE == 1)
    SET_POWER_CONFIGURATION(POWER_HEAL_CREATURE,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_HEAL_CREATURE,PanelTabIndex,10)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_LIGHTNING == 1)
    SET_POWER_CONFIGURATION(POWER_LIGHTNING,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_LIGHTNING,PanelTabIndex,11)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_POSSESS == 1)
    SET_POWER_CONFIGURATION(POWER_POSSESS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_POSSESS,PanelTabIndex,1)
ENDIF

TRAP_AVAILABLE(ALL_PLAYERS,EVIL_SENTRY,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,BARRICADE_TRAP_EVIL,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
TRAP_AVAILABLE(ALL_PLAYERS, FEAR_TRAP,1,0)

DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)

SET_GAME_RULE(GameTurnsInFlee,3000,PLAYER_GOOD)

SET_HAND_RULE(PLAYER0,ANY_CREATURE,RULE1,DENY,DROPPED_TIME_LOWER,60)
SET_GAME_RULE(MaxThingsInHand,30)

SET_CREATURE_FEAR_STRONGER(KNIGHT,10)
SET_CREATURE_FEAR_WOUNDED(KNIGHT,100)
SET_CREATURE_STRENGTH(KNIGHT,20)
SET_CREATURE_CONFIGURATION(KNIGHT,BaseSpeed,64)

IF(PLAYER1,CAMPAIGN_FLAG1 == 1)
	CONCEAL_MAP_RECT(Player0, 127, 80, 500, 240,1)
    REVEAL_MAP_LOCATION(PLAYER0,PLAYER0,-1)
	REVEAL_MAP_LOCATION(PLAYER0,2,2)
ENDIF

if(player0,ENTRANCE == 9)
  next_command_reusable
  max_creatures(Player0,15)
ENDIF
if(player0,ENTRANCE == 18)
  next_command_reusable
  max_creatures(Player0,20)
ENDIF
if(player0,ENTRANCE == 27)
  next_command_reusable
  max_creatures(Player0,25)
ENDIF

SET_FLAG(PLAYER0, FLAG0, 0)
SET_TIMER(PLAYER0, TIMER0)

CREATE_PARTY(SCOUT1)
ADD_TO_PARTY(SCOUT1, DWARFA, 1, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(SCOUT1, DWARFA, 1, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(SCOUT1, DWARFA, 1, 300, ATTACK_DUNGEON_HEART, 0)


CREATE_PARTY(SCOUT2)
ADD_TO_PARTY(SCOUT2, DWARFA, 2, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(SCOUT2, DWARFA, 2, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(SCOUT2, DWARFA, 3, 300, ATTACK_DUNGEON_HEART, 0)


CREATE_PARTY(SCOUT3)
ADD_TO_PARTY(SCOUT3, ARCHER, 3, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(SCOUT3, ARCHER, 3, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(SCOUT3, ARCHER, 4, 300, ATTACK_DUNGEON_HEART, 0)

CREATE_PARTY(SCOUT4)
ADD_TO_PARTY(SCOUT4, THIEF, 3, 300, STEAL_GOLD, 0)
ADD_TO_PARTY(SCOUT4, THIEF, 3, 300, STEAL_GOLD, 0)
ADD_TO_PARTY(SCOUT4, THIEF, 4, 300, STEAL_GOLD, 0)

CREATE_PARTY(MAGIC1)

ADD_TO_PARTY(MAGIC1, WIZARD, 3, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(MAGIC1, WIZARD, 3, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(MAGIC1, WITCH, 3, 300, ATTACK_DUNGEON_HEART, 0)

CREATE_PARTY(MAGIC2)

ADD_TO_PARTY(MAGIC2, WIZARD, 3, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(MAGIC2, WITCH, 4, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(MAGIC2, WITCH, 4, 300, ATTACK_DUNGEON_HEART, 0)

CREATE_PARTY(MELEE1)

ADD_TO_PARTY(MELEE1, BARBARIAN, 3, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(MELEE1, BARBARIAN, 3, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(MELEE1, MONK, 4, 300, DEFEND_PARTY, 0)

CREATE_PARTY(MELEE2)
ADD_TO_PARTY(MELEE2, GIANT, 3, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(MELEE2, GIANT, 3, 300, ATTACK_ENEMIES, 0)
ADD_TO_PARTY(MELEE2, GIANT, 3, 300, ATTACK_ENEMIES, 0)

CREATE_PARTY(LORD)
ADD_TO_PARTY(LORD, KNIGHT, 7, 0, DEFEND_ROOMS, 0)
ADD_TO_PARTY(LORD, BARBARIAN, 3, 300, DEFEND_PARTY, 0)
ADD_TO_PARTY(LORD, WIZARD, 4, 300, DEFEND_PARTY, 0)
ADD_TO_PARTY(LORD, ARCHER, 4, 300, DEFEND_PARTY, 0)
ADD_TO_PARTY(LORD, ARCHER, 4, 300, DEFEND_PARTY, 0)

IF(PLAYER0,TIMER4 >= 30)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl9spe01.ogg")
	QUICK_OBJECTIVE(63,"Take this Gem, Sir Knight across this next domain. You must approach the outpost Guards - alert them of your holy quest, and pray they listen. For if their hearts are good they will abandon where they're posted and will rally to your cause. Be swift and may the goodness of your mission give you strength.")
ENDIF

IF(PLAYER0,TIMER4 >= 400)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl9spe02.ogg")
	QUICK_OBJECTIVE(64,"Be wary of this Knight, brave Keeper for he'll strive for nothing other than the task he has been set and will avoid all battles if he can. Your creatures must then corner him to do him any damage, else he put to flight.")
ENDIF

IF(PLAYER0, BILE_DEMON >= 1)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl9spe03.ogg")
	QUICK_INFORMATION(65,"Ah, the Bile Demon. Acquaint yourself with him - a slovenly beast, whose girth impedes, but size and stubbornness bear him fruit in battle when it's needed.")
ENDIF

IF(PLAYER0,DUNGEON_DESTROYED== 1)
  CHANGE_SLAB_TYPE(74,36,PATH,MATCH)
ENDIF

REM # "Imp box , 10 imps around the heart"

SET_BOX_TOOLTIP(11,"Create Imp Box")

IF(PLAYER0,BOX11_ACTIVATED == 1)
    NEXT_COMMAND_REUSABLE
    ADD_CREATURE_TO_LEVEL(PLAYER0,IMP,PLAYER0,10,1,0,JUMP)
    NEXT_COMMAND_REUSABLE
    CREATE_EFFECT(EFFECT_COLFOUNTN_1,PLAYER0)
    NEXT_COMMAND_REUSABLE
    CREATE_EFFECT(EFFECT_COLFOUNTN_2,PLAYER0)
    NEXT_COMMAND_REUSABLE
    CREATE_EFFECT(EFFECT_COLFOUNTN_3,PLAYER0)
    NEXT_COMMAND_REUSABLE
    SET_FLAG(PLAYER0,BOX11_ACTIVATED,0)
ENDIF

REM # "Research box"

SET_BOX_TOOLTIP(12,"Research box")

IF(PLAYER0,BOX12_ACTIVATED == 1)
    NEXT_COMMAND_REUSABLE
    SET_FLAG(PLAYER0,SACRIFICED[FLY],2)
    NEXT_COMMAND_REUSABLE    
    SET_FLAG(PLAYER0,BOX12_ACTIVATED,0)
ENDIF

REM INTRO

NEXT_COMMAND_REUSABLE
SET_CREATURE_TENDENCIES(PLAYER_GOOD,IMPRISON,1)

RUN_AFTER_VICTORY(1)

COMPUTER_PLAYER(PLAYER6,ROAMING)
ALLY_PLAYERS(PLAYER0,PLAYER6,3)
ALLY_PLAYERS(PLAYER0,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER6,3)
SET_PLAYER_COLOR(PLAYER6,RED)

SET_TIMER(PLAYER0,TIMER4)

IF(PLAYER0,TIMER4 >= 30)
    SET_POWER_CONFIGURATION(POWER_SIGHT,SoundPlayed,0)
    USE_POWER_AT_LOCATION(PLAYER0,3,POWER_SIGHT,6,1)
ENDIF

IF(PLAYER0,TIMER4 >= 10)
	IF(PLAYER0,TIMER4 <= 339)
		NEXT_COMMAND_REUSABLE
    	ZOOM_TO_LOCATION(PLAYER0,4)
	ENDIF
ENDIF

IF(PLAYER0,TIMER4 >= 340)
    ZOOM_TO_LOCATION(PLAYER0,PLAYER0)
    SET_POWER_CONFIGURATION(POWER_SIGHT,POWER,10,6)
    USE_POWER_AT_LOCATION(PLAYER0,4,POWER_SIGHT,6,1)
ENDIF

IF(PLAYER0,TIMER4 >= 10)
	SET_OBJECT_CONFIGURATION(AVATAR_TALK,MaximumSize,500)
	SET_OBJECT_CONFIGURATION(KNIGHT_STATUE,MaximumSize,370)
ENDIF

IF(PLAYER0,TIMER4 >= 350)
    SET_POWER_CONFIGURATION(POWER_SIGHT,SoundPlayed,51)
    SET_POWER_CONFIGURATION(POWER_SIGHT,POWER,896,6)
	SET_OBJECT_CONFIGURATION(LORD_STATUE,MaximumSize,0)
	SET_OBJECT_CONFIGURATION(AVATAR_TALK,MaximumSize,0)
	SET_OBJECT_CONFIGURATION(OBJECT_GEM,MaximumSize,0)
    SET_OBJECT_CONFIGURATION(KNIGHT_STATUE,MaximumSize,0)
ENDIF

REM SETTINGS

IF(PLAYER0, TIMER0 >= 18000)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl9spe05.ogg")
	QUICK_OBJECTIVE(66,"Distraction is disaster, Keeper. Keep your task in mind. To kill the Knight who bears the Gem for only then can you taste victory sweet within this realm.")
	SET_FLAG(PLAYER0, FLAG0, 1)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, SCOUT1, 3, DUNGEON_HEART, 0, 4, 600)
ENDIF

IF(PLAYER0, TIMER0 >= 18250)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, SCOUT2, 6, 1)
ENDIF

IF(PLAYER0, TIMER0 >= 18500)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, SCOUT3, 3, 1)
ENDIF

IF(PLAYER0, TIMER0 >= 18750)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, SCOUT3, 3, 1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, SCOUT4, 6, 1)
ENDIF

IF(PLAYER0, TIMER0 >= 19000)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, MELEE1, 3, 1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, MELEE2, 6, 1)
ENDIF

IF(PLAYER0, TIMER0 >= 19500)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, MELEE1, 3, 1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, MAGIC1, 3, 1)
ENDIF

IF(PLAYER0, TIMER0 >= 20500)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, MELEE2, 6, 1)
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, MAGIC2, 6, 1)
ENDIF

IF(PLAYER0, TIMER0 >= 21000)
	CHANGE_SLAB_TYPE(25,31,PRETTY_PATH,MATCH)
	CHANGE_SLAB_TYPE(27,29,PRETTY_PATH,MATCH)
	CHANGE_SLAB_TYPE(27,31,PRETTY_PATH,MATCH)
	CHANGE_SLAB_TYPE(31,31,PRETTY_PATH,MATCH)
	CHANGE_SLAB_TYPE(27,35,PRETTY_PATH,MATCH)
	CHANGE_SLAB_TYPE(59,31,PRETTY_PATH,MATCH)
	CHANGE_SLAB_TYPE(91,31,PRETTY_PATH,MATCH)
	SET_FLAG(PLAYER0, FLAG0, 2)
	ZOOM_TO_LOCATION(PLAYER0,3)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl9spe04.ogg")
	QUICK_OBJECTIVE(67,"Behold the Knight and his companions sally forth towards this land.")
	ADD_PARTY_TO_LEVEL(PLAYER_GOOD, LORD, 3, 1)
	ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD, MELEE1, 6, DUNGEON_HEART, 0, 4, 600)
	
ENDIF

IF_SLAB_TYPE(104,47,TORTURE_AREA)
	IF_SLAB_TYPE(103,46,TORTURE_AREA)
		IF_SLAB_TYPE(103,47,TORTURE_AREA)
			IF_SLAB_TYPE(103,48,TORTURE_AREA)
				CHANGE_SLAB_TYPE(105,47,PATH)
				CHANGE_SLAB_TYPE(106,47,PATH)
				CHANGE_SLAB_TYPE(107,47,PATH)
				CHANGE_SLAB_TYPE(108,47,PATH)
				CHANGE_SLAB_TYPE(109,47,PATH)
			ENDIF
		ENDIF
	ENDIF
ENDIF

REM PL3,FLAG5 active music track
rem value 2: dk2track02.mp3
rem value 4: dk2track04.mp3
SET_MUSIC("dk2track01.mp3")
SET_FLAG(PLAYER3,FLAG5,2)

IF(PLAYER3,FLAG5 != 4)
    REM Time battle music been playing
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER7)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES == 0)
	REM Time battle has been going on
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER3,TIMER6)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES > 0)
    REM Time no battle has been going on
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER5)
ENDIF

REM Start battle music if battle has been going on for at least 60 gameturns (3 seconds) and is not already playing
IF(PLAYER3,TIMER6 > 60)
    IF(PLAYER3,FLAG5 != 4)
		IF(PLAYER6,TIMER2 >=1200)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("battle03.mp3")
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER3,FLAG5,4)
		ENDIF
    ENDIF
ENDIF

REM Start only Battle Music if it hasn't been played for 1min

SET_TIMER(PLAYER6,TIMER2)
ADD_TO_TIMER(PLAYER6,TIMER2,1100)

IF(PLAYER3,FLAG5 == 4)
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER6,TIMER2)
ENDIF

REM Start regular music if battle music lasted at least 15 seconds and no fighting has occured for at least 5 seconds
IF(PLAYER3,TIMER7 > 300)
    IF(PLAYER3,TIMER5 > 100)
        IF(PLAYER3,FLAG5 != 2)
            NEXT_COMMAND_REUSABLE
            SET_MUSIC("dk2track01.mp3")
            NEXT_COMMAND_REUSABLE
            SET_FLAG(PLAYER3,FLAG5,2)
        ENDIF
    ENDIF
ENDIF

SET_TIMER(PLAYER0,TIMER2)

IF(PLAYER0,TIMER2 >= 250)
   		IF(PLAYER0,IMP <= 4)
        		NEXT_COMMAND_REUSABLE
			ADD_CREATURE_TO_LEVEL(PLAYER0,IMP,PLAYER0,2,1,100)
        		NEXT_COMMAND_REUSABLE
        		SET_TIMER(PLAYER0,TIMER2)
		ENDIF
ENDIF 

REM WIN CONDITION

IF(PLAYER0, FLAG0 == 2)
	IF(PLAYER_GOOD, KNIGHT == 0)
		PLAY_MESSAGE(PLAYER0,SPEECH,"lvl9spe07.ogg")
		QUICK_OBJECTIVE(68,"The Knight is slain, he could keep neither head nor Gem, a glorious and unholy setback to the King. An evil deed well done!")
		WIN_GAME
  	 	ADD_OBJECT_TO_LEVEL(FAKE_GEM,LAST_DEATH_EVENT[PLAYER_GOOD],1,PLAYER5)
 		COMPUTER_PLAYER(PLAYER5,ROAMING)
 		SET_TIMER(PLAYER6,TIMER6)
	ENDIF
ENDIF

REM OUTRO

IF(PLAYER6,TIMER6 >= 20)
    MAGIC_AVAILABLE(PLAYER0,POWER_POSSESS,0,0)
ENDIF

IF(PLAYER6,TIMER6 >= 60)
    ZOOM_TO_LOCATION(PLAYER0,7)
    CREATE_EFFECT(EFFECT_FLASH,PLAYER0)
ENDIF

IF(PLAYER6,TIMER6 >= 70)
    CREATE_EFFECT(EFFECT_WORD_OF_POWER,7)
    CREATE_EFFECT(EFFECT_EXPLOSION_5,7)
    CREATE_EFFECT(EFFECT_SPANGLE_RED,7)
    ADD_OBJECT_TO_LEVEL(HORNY_SPAWN,7,1,PLAYER0,South)
ENDIF

IF(PLAYER6,TIMER6 >= 138)
	RUN_LUA_CODE("SpawnHorny(7)")
	SET_OBJECT_CONFIGURATION(HORNY_SPAWN,MaximumSize,0)
ENDIF

IF(PLAYER5,HEART_HEALTH > 0)
    SET_FLAG(PLAYER0,FLAG0,8)
ENDIF

IF(PLAYER0,FLAG0 == 8)
    IF(PLAYER5,HEART_HEALTH < 3)
        SET_OBJECT_CONFIGURATION(FAKE_GEM,UpdateFunction,UPDATE_POWER_LIGHTNING)
        SET_TIMER(PLAYER6,TIMER7)
    ENDIF
ENDIF

IF(PLAYER6,TIMER7 > 5)
    PLAY_MESSAGE(PLAYER0,SOUND,116)
ENDIF

IF(PLAYER6,TIMER7 > 100)
    KILL_CREATURE(PLAYER6,EVILLORD,ANYWHERE,1)
ENDIF


REM loosing condition if LotL flees

IF(PLAYER0, FLAG0 == 2)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(1,PLAYER_GOOD,KNIGHT,PLAYER_NEUTRAL,FLAG1)
ENDIF

SET_FLAG(PLAYER_NEUTRAL,FLAG1,0)

IF(PLAYER_NEUTRAL, FLAG1 > 0)
	LOSE_GAME
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl9spe06.ogg")
	QUICK_OBJECTIVE(69,"This unimpressive show does not become your evil cause. For moves you make are slower than a lowly snail. Next time this challenge face with faster pace more suited to your stature.")
ENDIF
