REM ********************************************
REM
REM             Script for Level 216
REM
REM ********************************************


LEVEL_VERSION(1)

SET_GENERATE_SPEED(300)

SET_TEXTURE(PLAYER_GOOD,18)

MAX_CREATURES(PLAYER0, 20)
MAX_CREATURES(PLAYER1, 20)
MAX_CREATURES(PLAYER2, 20)

COMPUTER_PLAYER(PLAYER1,9)
COMPUTER_PLAYER(PLAYER2,9)

SET_TIMER(PLAYER2,TIMER0)

IF(PLAYER2,TIMER0 > 18000)
  COMPUTER_PLAYER(PLAYER1,0)
  COMPUTER_PLAYER(PLAYER2,0)
ENDIF

START_MONEY(PLAYER0, 10000)
START_MONEY(PLAYER1, 12500)
START_MONEY(PLAYER2, 12500)

ADD_CREATURE_TO_POOL(WARLOCK, 10)
ADD_CREATURE_TO_POOL(GOBLIN, 10)
ADD_CREATURE_TO_POOL(TROLL, 10)
ADD_CREATURE_TO_POOL(FIREFLY, 5)
ADD_CREATURE_TO_POOL(SALAMANDER, 10)
ADD_CREATURE_TO_POOL(MISTRESS, 10)
ADD_CREATURE_TO_POOL(BILE_DEMON, 10)
ADD_CREATURE_TO_POOL(BLACK_KNIGHT, 10)
ADD_CREATURE_TO_POOL(DARK_ELF,10)
ADD_CREATURE_TO_POOL(ROGUE,8)

CREATURE_AVAILABLE(ALL_PLAYERS, WARLOCK, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, GOBLIN, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, FIREFLY, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, TROLL, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, MISTRESS, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, BILE_DEMON, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, SALAMANDER, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, BLACK_KNIGHT, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, DARK_ELF,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS, ROGUE,1,0)

ROOM_AVAILABLE(ALL_PLAYERS, RESEARCH, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GARDEN, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, LAIR, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TRAINING, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TREASURE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, WORKSHOP, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, BRIDGE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, STONE_BRIDGE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TORTURE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GUARD_POST, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, PRISON, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, BARRACKS, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GRAVEYARD, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, CASINO, 1, 1)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_OBEY,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_POSSESS, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CAVE_IN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CHICKEN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DESTROY_WALLS,1,0)

TRAP_AVAILABLE(ALL_PLAYERS,EVIL_SENTRY,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,BARRICADE_TRAP_EVIL,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,FREEZE_TRAP,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,BOULDER,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNINGTRAP,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,SPIKETRAP,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,WORD_OF_POWER,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,FEAR_TRAP,1,0)

DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,SECRET,1,0)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_POSSESS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_IMP,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_CAVE_IN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_LIGHTNING,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_CHICKEN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_DESTROY_WALLS,1,0)

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_IMP == 1)
    SET_POWER_CONFIGURATION(POWER_IMP,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_IMP,PanelTabIndex,2)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_OBEY == 1)
    SET_POWER_CONFIGURATION(POWER_OBEY,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_OBEY,PanelTabIndex,5)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_SIGHT == 1)
    SET_POWER_CONFIGURATION(POWER_SIGHT,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_SIGHT,PanelTabIndex,3)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_CALL_TO_ARMS == 1)
    SET_POWER_CONFIGURATION(POWER_CALL_TO_ARMS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_CALL_TO_ARMS,PanelTabIndex,6)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_CAVE_IN == 1)
    SET_POWER_CONFIGURATION(POWER_CAVE_IN,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_CAVE_IN,PanelTabIndex,9)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_HEAL_CREATURE == 1)
    SET_POWER_CONFIGURATION(POWER_HEAL_CREATURE,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_HEAL_CREATURE,PanelTabIndex,10)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_LIGHTNING == 1)
    SET_POWER_CONFIGURATION(POWER_LIGHTNING,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_LIGHTNING,PanelTabIndex,11)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_PROTECT == 1)
    SET_POWER_CONFIGURATION(POWER_PROTECT,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_PROTECT,PanelTabIndex,12)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_CHICKEN == 1)
    SET_POWER_CONFIGURATION(POWER_CHICKEN,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_CHICKEN,PanelTabIndex,13)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_DESTROY_WALLS == 1)
    SET_POWER_CONFIGURATION(POWER_DESTROY_WALLS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_DESTROY_WALLS,PanelTabIndex,16)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_POSSESS == 1)
    SET_POWER_CONFIGURATION(POWER_POSSESS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_POSSESS,PanelTabIndex,1)
ENDIF

IF(PLAYER1,CAMPAIGN_FLAG1 == 1)
	CONCEAL_MAP_RECT(Player0, 127, 127, 250, 250,1)
  REVEAL_MAP_LOCATION(PLAYER0,8,2)
  REVEAL_MAP_LOCATION(PLAYER0,9,2)
  REVEAL_MAP_LOCATION(PLAYER0,6,6)
  REVEAL_MAP_LOCATION(PLAYER0,7,6)
ENDIF

IF(PLAYER1,DUNGEON_DESTROYED== 1)
  CHANGE_SLAB_TYPE(5,5,PATH,MATCH)
ENDIF
IF(PLAYER2,DUNGEON_DESTROYED== 1)
  CHANGE_SLAB_TYPE(70,5,PATH,MATCH)
ENDIF

REVEAL_MAP_LOCATION(PLAYER0,5,12)

CREATE_PARTY(LORD)
ADD_TO_PARTY(LORD, ANGEL, 10, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(LORD, ANGEL, 10, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(LORD, ANGEL, 10, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(LORD, ANGEL, 10, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(LORD, ANGEL, 10, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(LORD, ANGEL, 10, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(LORD, ANGEL, 10, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(LORD, ANGEL, 10, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(LORD, ANGEL, 10, 300, ATTACK_DUNGEON_HEART, 0)
ADD_TO_PARTY(LORD, ANGEL, 10, 300, ATTACK_DUNGEON_HEART, 0)

SET_GAME_RULE(MaxThingsInHand,30)
SET_HAND_RULE(PLAYER0,ANY_CREATURE,RULE1,DENY,DROPPED_TIME_LOWER,60)
REMOVE_SACRIFICE_RECIPE(BILE_DEMON,DARK_MISTRESS,TROLL)

REVEAL_MAP_LOCATION(PLAYER0,PLAYER0,-1)

IF(PLAYER0, BARRACKS <= 8)
	NEXT_COMMAND_REUSABLE
	SET_GAME_RULE(TrainingRoomMaxLevel,4,PLAYER0)
ENDIF

IF(PLAYER1, BARRACKS <= 8)
	NEXT_COMMAND_REUSABLE
	SET_GAME_RULE(TrainingRoomMaxLevel,4,PLAYER1)
ENDIF

IF(PLAYER2, BARRACKS <= 8)
	NEXT_COMMAND_REUSABLE
	SET_GAME_RULE(TrainingRoomMaxLevel,4,PLAYER2)
ENDIF

IF(PLAYER0, BARRACKS >= 8)
	NEXT_COMMAND_REUSABLE
	SET_GAME_RULE(TrainingRoomMaxLevel,8,PLAYER0)
ENDIF

IF(PLAYER1, BARRACKS >= 8)
	NEXT_COMMAND_REUSABLE
	SET_GAME_RULE(TrainingRoomMaxLevel,8,PLAYER1)
ENDIF

IF(PLAYER2, BARRACKS >= 8)
	NEXT_COMMAND_REUSABLE
	SET_GAME_RULE(TrainingRoomMaxLevel,8,PLAYER2)
ENDIF

if(player0,ENTRANCE == 9)
  next_command_reusable
  max_creatures(Player0,15)
ENDIF
if(player0,ENTRANCE == 18)
  next_command_reusable
  max_creatures(Player0,20)
ENDIF
if(player0,ENTRANCE == 27)
  next_command_reusable
  max_creatures(Player0,25)
ENDIF
if(player0,ENTRANCE == 36)
  next_command_reusable
  max_creatures(Player0,30)
ENDIF
if(player1,ENTRANCE == 9)
  next_command_reusable
  max_creatures(Player1,15)
ENDIF
if(player1,ENTRANCE == 18)
  next_command_reusable
  max_creatures(Player1,20)
ENDIF
if(player1,ENTRANCE == 27)
  next_command_reusable
  max_creatures(Player1,25)
ENDIF
if(player1,ENTRANCE == 36)
  next_command_reusable
  max_creatures(Player1,30)
ENDIF
if(player2,ENTRANCE == 9)
  next_command_reusable
  max_creatures(Player2,15)
ENDIF
if(player2,ENTRANCE == 18)
  next_command_reusable
  max_creatures(Player2,20)
ENDIF
if(player2,ENTRANCE == 27)
  next_command_reusable
  max_creatures(Player2,25)
ENDIF
if(player2,ENTRANCE == 36)
  next_command_reusable
  max_creatures(Player2,30)
ENDIF

DISPLAY_VARIABLE_WITH_LABEL(PLAYER0,BATTLES_WON,Kills)

REM # "Happy Box: All friendly minions get happy."

SET_BOX_TOOLTIP(10,"Make Happy Box")

IF(PLAYER0,BOX10_ACTIVATED == 1)
    NEXT_COMMAND_REUSABLE
    CHANGE_CREATURES_ANNOYANCE(PLAYER0,ANY_CREATURE,SET,0)
    NEXT_COMMAND_REUSABLE
    CHANGE_CREATURES_ANNOYANCE(PLAYER0,IMP,SET,0)
    NEXT_COMMAND_REUSABLE
    SET_FLAG(PLAYER0,BOX10_ACTIVATED,0)
ENDIF

REM # "Research box"

SET_BOX_TOOLTIP(12,"Research box")

IF(PLAYER0,BOX12_ACTIVATED == 1)
    NEXT_COMMAND_REUSABLE
    SET_FLAG(PLAYER0,SACRIFICED[FLY],2)
    NEXT_COMMAND_REUSABLE    
    SET_FLAG(PLAYER0,BOX12_ACTIVATED,0)
ENDIF

REM only one player is getting the reward after 20 kills

SET_FLAG(PLAYER2,FLAG2,0)

IF(PLAYER0,BATTLES_WON[PLAYER_GOOD] > 19)
  IF(PLAYER2,FLAG2 == 0)
      SET_TIMER(PLAYER3,TIMER2)
      ADD_PARTY_TO_LEVEL(PLAYER0, LORD, 5, 1)
      SET_FLAG(PLAYER2,FLAG2,1)
      PLAY_MESSAGE(PLAYER0,SPEECH,"lvl17spe07.mp3")
      QUICK_MESSAGE(121,"I'd have 'em all if all of them dared face me.",REAPER)
      QUICK_MESSAGE(120,"Dark Angels, pah! They don't scare me.",REAPER)
  ENDIF
ENDIF

IF(PLAYER1,BATTLES_WON[PLAYER_GOOD] > 19)
  IF(PLAYER2,FLAG2 == 0)
    SET_TIMER(PLAYER3,TIMER2)
    ADD_PARTY_TO_LEVEL(PLAYER1, LORD, 5, 1)
    SET_FLAG(PLAYER2,FLAG2,1)
  ENDIF
ENDIF

IF(PLAYER2,BATTLES_WON[PLAYER_GOOD] > 19)
  IF(PLAYER2,FLAG2 == 0)
    SET_TIMER(PLAYER3,TIMER2)
    ADD_PARTY_TO_LEVEL(PLAYER2, LORD, 5, 1)
    SET_FLAG(PLAYER2,FLAG2,1)
  ENDIF
ENDIF

REM start the spawn if someone has the temple and no one has reached 20 kills yet

SET_FLAG(PLAYER2,FLAG5,0)

IF(PLAYER0,TEMPLE > 0)
  IF(PLAYER2,FLAG5 == 0)
      ROOM_AVAILABLE(PLAYER0, TEMPLE, 1, 1)
      PLAY_MESSAGE(PLAYER0,SPEECH,"lvl17spe02.ogg")
      QUICK_OBJECTIVE(110,"You have boldly claimed the Temple. Now the Dark Angels will take note of your brave deeds.")
      SET_FLAG(PLAYER2,FLAG5,1)
  ENDIF
ENDIF

IF(PLAYER1,TEMPLE > 0)
  IF(PLAYER2,FLAG5 == 0)
      ROOM_AVAILABLE(PLAYER1, TEMPLE, 1, 1)
      PLAY_MESSAGE(PLAYER0,SPEECH,"lvl17spe04.ogg")
      QUICK_OBJECTIVE(111,"Your opposition claims the Temple, they have gained its power and their glory draws attention from those Dark Angels, whose allegiance you do seek.")
      SET_FLAG(PLAYER2,FLAG5,1)
  ENDIF
ENDIF

IF(PLAYER2,TEMPLE > 0)
  IF(PLAYER2,FLAG5 == 0)
      ROOM_AVAILABLE(PLAYER2, TEMPLE, 1, 1)
      PLAY_MESSAGE(PLAYER0,SPEECH,"lvl17spe04.ogg")
      QUICK_OBJECTIVE(111,"Your opposition claims the Temple, they have gained its power and their glory draws attention from those Dark Angels, whose allegiance you do seek.")
      SET_FLAG(PLAYER2,FLAG5,1)
  ENDIF
ENDIF

CREATE_PARTY(SPAWN)
  ADD_TO_PARTY(SPAWN, WIZARD, 7, 300, ATTACK_DUNGEON_HEART, 0)
  ADD_TO_PARTY(SPAWN, ARCHER, 7, 300, ATTACK_DUNGEON_HEART, 0)
  ADD_TO_PARTY(SPAWN, MONK, 6, 300, ATTACK_DUNGEON_HEART, 0)
  ADD_TO_PARTY(SPAWN, GIANT, 7, 300, ATTACK_DUNGEON_HEART, 0)
  ADD_TO_PARTY(SPAWN, BARBARIAN, 8, 300, ATTACK_DUNGEON_HEART, 0)

IF(PLAYER2,FLAG5 == 1)
  SET_TIMER(PLAYER2,TIMER5)
ENDIF

IF(PLAYER2,TIMER5 > 2000)
  IF(PLAYER2,FLAG2 == 0)
    NEXT_COMMAND_REUSABLE
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,SPAWN,-1,1)
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER2,TIMER5)
  ENDIF
ENDIF

CREATE_PARTY(HERO)
  ADD_TO_PARTY(HERO, KNIGHT, 8, 300, ATTACK_DUNGEON_HEART, 0)
  ADD_TO_PARTY(HERO, WIZARD, 7, 300, ATTACK_DUNGEON_HEART, 0)
  ADD_TO_PARTY(HERO, WIZARD, 7, 300, ATTACK_DUNGEON_HEART, 0)
  ADD_TO_PARTY(HERO, MONK, 6, 300, ATTACK_DUNGEON_HEART, 0)
  ADD_TO_PARTY(HERO, MONK, 8, 300, ATTACK_DUNGEON_HEART, 0)
  ADD_TO_PARTY(HERO, BARBARIAN, 8, 300, ATTACK_DUNGEON_HEART, 0)

IF(PLAYER3,TIMER2 >= 1000)
  ADD_PARTY_TO_LEVEL(PLAYER_GOOD,HERO,-1,1)
ENDIF

IF(PLAYER0,DUNGEON_DESTROYED== 1)
  CHANGE_SLAB_TYPE(37,68,PATH,MATCH)
ENDIF

REM START INTRO

NEXT_COMMAND_REUSABLE
SET_CREATURE_TENDENCIES(PLAYER_GOOD,IMPRISON,1)

RUN_AFTER_VICTORY(1)

COMPUTER_PLAYER(PLAYER6,ROAMING)
ALLY_PLAYERS(PLAYER0,PLAYER6,3)
ALLY_PLAYERS(PLAYER0,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER6,3)
ALLY_PLAYERS(PLAYER1,PLAYER6,3)
ALLY_PLAYERS(PLAYER1,PLAYER5,3)
ALLY_PLAYERS(PLAYER2,PLAYER6,3)
ALLY_PLAYERS(PLAYER2,PLAYER5,3)
SET_PLAYER_COLOR(PLAYER6,RED)

SET_TIMER(PLAYER0,TIMER0)

IF(PLAYER0,TIMER0 >= 30)
    SET_POWER_CONFIGURATION(POWER_SIGHT,SoundPlayed,0)
    USE_POWER_AT_LOCATION(PLAYER0,5,POWER_SIGHT,6,1)
ENDIF

IF(PLAYER0,TIMER0 >= 10)
	IF(PLAYER0,TIMER0 <= 199)
		NEXT_COMMAND_REUSABLE
    	ZOOM_TO_LOCATION(PLAYER0,5)
	ENDIF
ENDIF

IF(PLAYER0,TIMER0 >= 200)
    ZOOM_TO_LOCATION(PLAYER0,PLAYER0)
    SET_POWER_CONFIGURATION(POWER_SIGHT,POWER,10,6)
    USE_POWER_AT_LOCATION(PLAYER0,5,POWER_SIGHT,6,1)
ENDIF

IF(PLAYER0,TIMER0 >= 220)
    SET_POWER_CONFIGURATION(POWER_SIGHT,SoundPlayed,51)
    SET_POWER_CONFIGURATION(POWER_SIGHT,POWER,896,6)
ENDIF

IF(PLAYER0,TIMER0 >= 45)
    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl17spe01.ogg")
    QUICK_OBJECTIVE(112,"Behold the Temple - a gateway leading to realms below the Earth. From here Dark Angels scout beyond their subterranean thrones towards the surface ever watching out for evil. Theirs is the Portal Gem, and if you triumph in slaying twenty Heroes you'll attract their confidence enough for them to rally to your side. But careful, there exist two rival Keepers, who are just as keen as you to seek out their allegiance, and its them you must outwit. But once you've killed your quota, and Dark Angels join your side, your victory should be easy 'gainst your rivals, thence you'll claim your prize.")
ENDIF

IF(PLAYER0,TIMER0 >= 2000)
    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl17spe05.ogg")
    QUICK_OBJECTIVE(113,"Capture Temple first and as much of its surrounds as you are able. From this base you'll kill as many of the Heroes as you can before the other Keepers here arrive. And once you hold a favourable advantage, do not allow't to slip at any cost.")
ENDIF

IF(PLAYER0, ANGEL >= 1)
    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl17spe03.ogg")
    QUICK_OBJECTIVE(114,"A victor! Truly you are the most pitiless and cold-blooded mercenary we have beheld. The Gem is yours - if you can finish off your former foes. We shall aid you, but mind that you mark our presence by gracing us with unhallowed ground. One Temple shall two of our brethren require. Should you have need of us further, another Temple must be crafted in our name.")
ENDIF

REM SETTINGS

REM PL3,FLAG5 active music track
rem value 2: dk2track02.mp3
rem value 4: dk2track04.mp3
SET_MUSIC("dk2track02.mp3")
SET_FLAG(PLAYER3,FLAG5,2)

IF(PLAYER3,FLAG5 != 4)
    REM Time battle music been playing
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER7)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES == 0)
	REM Time battle has been going on
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER3,TIMER6)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES > 0)
    REM Time no battle has been going on
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER5)
ENDIF

REM Start battle music if battle has been going on for at least 60 gameturns (3 seconds) and is not already playing
IF(PLAYER3,TIMER6 > 60)
    IF(PLAYER3,FLAG5 != 4)
		IF(PLAYER6,TIMER2 >=1200)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("battle03.mp3")
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER3,FLAG5,4)
		ENDIF
    ENDIF
ENDIF

REM Start only Battle Music if it hasn't been played for 1min

SET_TIMER(PLAYER6,TIMER2)
ADD_TO_TIMER(PLAYER6,TIMER2,1100)

IF(PLAYER3,FLAG5 == 4)
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER6,TIMER2)
ENDIF

REM Start regular music if battle music lasted at least 15 seconds and no fighting has occured for at least 5 seconds
IF(PLAYER3,TIMER7 > 300)
    IF(PLAYER3,TIMER5 > 100)
        IF(PLAYER3,FLAG5 != 2)
            NEXT_COMMAND_REUSABLE
            SET_MUSIC("dk2track02.mp3")
            NEXT_COMMAND_REUSABLE
            SET_FLAG(PLAYER3,FLAG5,2)
        ENDIF
    ENDIF
ENDIF

SET_TIMER(PLAYER0,TIMER2)

IF(PLAYER0,TIMER2 >= 250)
   		IF(PLAYER0,IMP <= 4)
        		NEXT_COMMAND_REUSABLE
			ADD_CREATURE_TO_LEVEL(PLAYER0,IMP,PLAYER0,2,1,100)
        		NEXT_COMMAND_REUSABLE
        		SET_TIMER(PLAYER0,TIMER2)
		ENDIF
ENDIF 

REM WIN CONDITION

SET_FLAG(PLAYER2,FLAG1,0)

IF(PLAYER1,DUNGEON_DESTROYED==1)
  IF(PLAYER2,DUNGEON_DESTROYED==1)
    SET_FLAG(PLAYER2,FLAG1,1)
  ENDIF
ENDIF

IF(PLAYER_GOOD, KNIGHT == 0)
  IF(PLAYER2,FLAG1==1)
    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl17spe06.ogg")
    QUICK_OBJECTIVE(115,"Dark Angels answer only to the Hierarchs of Hell. 'Tis purely for their higher purpose that they side with you, so careful in their treatment - do not anger them, unless you wish them turn on you, with grave and horrid consequence.")
    ADD_OBJECT_TO_LEVEL(FAKE_GEM,LAST_DEATH_EVENT[PLAYER_GOOD],1,PLAYER5)
    COMPUTER_PLAYER(PLAYER5,ROAMING)
    SET_TIMER(PLAYER6,TIMER6) 
    WIN_GAME
  ENDIF
ENDIF


REM OUTRO

HIDE_HERO_GATE(2,1)

IF(PLAYER6,TIMER6 >= 20)
    MAGIC_AVAILABLE(PLAYER0,POWER_POSSESS,0,0)
ENDIF

IF(PLAYER6,TIMER6 >= 60)
    ZOOM_TO_LOCATION(PLAYER0,-2)
    CREATE_EFFECT(EFFECT_FLASH,PLAYER0)
ENDIF

IF(PLAYER6,TIMER6 >= 70)
    CREATE_EFFECT(EFFECT_SPAWN,-2)
    CREATE_EFFECT(EFFECT_EXPLOSION_5,-2)
    CREATE_EFFECT(EFFECT_SPANGLE_RED,-2)
    ADD_OBJECT_TO_LEVEL(HORNY_SPAWN,-2,1,PLAYER0,South)
ENDIF

IF(PLAYER6,TIMER6 >= 138)
	RUN_LUA_CODE("SpawnHorny(-2)")
	SET_OBJECT_CONFIGURATION(HORNY_SPAWN,MaximumSize,0)
ENDIF

IF(PLAYER5,HEART_HEALTH > 0)
    SET_FLAG(PLAYER0,FLAG0,8)
ENDIF

IF(PLAYER0,FLAG0 == 8)
    IF(PLAYER5,HEART_HEALTH < 3)
        SET_OBJECT_CONFIGURATION(FAKE_GEM,UpdateFunction,UPDATE_POWER_LIGHTNING)
        SET_TIMER(PLAYER6,TIMER7)
    ENDIF
ENDIF

IF(PLAYER6,TIMER7 > 5)
    PLAY_MESSAGE(PLAYER0,SOUND,116)
ENDIF

IF(PLAYER6,TIMER7 > 100)
    KILL_CREATURE(PLAYER6,EVILLORD,ANYWHERE,1)
ENDIF
