REM ********************************************
REM
REM             Script for Level 218
REM
REM ********************************************

LEVEL_VERSION(1)

SET_GENERATE_SPEED(240)

SET_TEXTURE(PLAYER_GOOD,18)

MAX_CREATURES(ALL_PLAYERS, 20)

START_MONEY(ALL_PLAYERS, 17250)

ADD_CREATURE_TO_POOL(BILE_DEMON,10)
ADD_CREATURE_TO_POOL(MISTRESS,10)
ADD_CREATURE_TO_POOL(SALAMANDER,10)
ADD_CREATURE_TO_POOL(WARLOCK,10)
ADD_CREATURE_TO_POOL(TROLL,10)
ADD_CREATURE_TO_POOL(GOBLIN,10)
ADD_CREATURE_TO_POOL(BLACK_KNIGHT,10)
ADD_CREATURE_TO_POOL(DARK_ELF,10)
ADD_CREATURE_TO_POOL(ROGUE,4)
ADD_CREATURE_TO_POOL(ANGEL,10)

CREATURE_AVAILABLE(ALL_PLAYERS, TROLL, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, GOBLIN, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, FIREFLY, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, MISTRESS, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, WARLOCK, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, BILE_DEMON, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, SALAMANDER, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, BLACK_KNIGHT, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, DARK_ELF,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS, ROGUE,1,0)
CREATURE_AVAILABLE(ALL_PLAYERS, ANGEL,1,0)

ROOM_AVAILABLE(ALL_PLAYERS, GUARD_POST, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TREASURE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, RESEARCH, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, WORKSHOP, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GARDEN, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, LAIR, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GRAVEYARD, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, PRISON, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TORTURE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TRAINING, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, BARRACKS, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TEMPLE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, BRIDGE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, STONE_BRIDGE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, CASINO, 1, 1)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_OBEY,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_POSSESS, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CAVE_IN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CHICKEN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DESTROY_WALLS,1,0)

TRAP_AVAILABLE(ALL_PLAYERS,EVIL_SENTRY,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,BARRICADE_TRAP_EVIL,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,FREEZE_TRAP,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,BOULDER,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNINGTRAP,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,SPIKETRAP,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,WORD_OF_POWER,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
TRAP_AVAILABLE(ALL_PLAYERS, FEAR_TRAP,1,0)

DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,SECRET,1,0)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_POSSESS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_IMP,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_CAVE_IN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_LIGHTNING,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_CHICKEN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_DESTROY_WALLS,1,0)

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_IMP == 1)
    SET_POWER_CONFIGURATION(POWER_IMP,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_IMP,PanelTabIndex,2)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_OBEY == 1)
    SET_POWER_CONFIGURATION(POWER_OBEY,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_OBEY,PanelTabIndex,5)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_SIGHT == 1)
    SET_POWER_CONFIGURATION(POWER_SIGHT,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_SIGHT,PanelTabIndex,3)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_CALL_TO_ARMS == 1)
    SET_POWER_CONFIGURATION(POWER_CALL_TO_ARMS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_CALL_TO_ARMS,PanelTabIndex,6)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_CAVE_IN == 1)
    SET_POWER_CONFIGURATION(POWER_CAVE_IN,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_CAVE_IN,PanelTabIndex,9)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_HEAL_CREATURE == 1)
    SET_POWER_CONFIGURATION(POWER_HEAL_CREATURE,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_HEAL_CREATURE,PanelTabIndex,10)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_LIGHTNING == 1)
    SET_POWER_CONFIGURATION(POWER_LIGHTNING,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_LIGHTNING,PanelTabIndex,11)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_PROTECT == 1)
    SET_POWER_CONFIGURATION(POWER_PROTECT,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_PROTECT,PanelTabIndex,12)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_CHICKEN == 1)
    SET_POWER_CONFIGURATION(POWER_CHICKEN,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_CHICKEN,PanelTabIndex,13)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_DESTROY_WALLS == 1)
    SET_POWER_CONFIGURATION(POWER_DESTROY_WALLS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_DESTROY_WALLS,PanelTabIndex,16)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_POSSESS == 1)
    SET_POWER_CONFIGURATION(POWER_POSSESS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_POSSESS,PanelTabIndex,1)
ENDIF

REM only for this map to they flee long enough

SET_GAME_RULE(GameTurnsInFlee,1500,PLAYER_GOOD)

SET_CREATURE_PROPERTY(TRISTAN,LORD,0)
SET_CREATURE_PROPERTY(TRISTAN,NO_IMPRISONMENT,0)

SET_CREATURE_PROPERTY(BALDER,LORD,0)
SET_CREATURE_PROPERTY(BALDER,NO_IMPRISONMENT,0)

SET_CREATURE_PROPERTY(FELIX,LORD,0)
SET_CREATURE_PROPERTY(FELIX,NO_IMPRISONMENT,0)

IF(PLAYER1,CAMPAIGN_FLAG1 == 1)
	CONCEAL_MAP_RECT(Player0, 120, 120, 240, 240,1)
    REVEAL_MAP_LOCATION(PLAYER0,PLAYER0,-1)
    REVEAL_MAP_LOCATION(PLAYER0,9,67)
    REVEAL_MAP_LOCATION(PLAYER0,10,67)
    REVEAL_MAP_LOCATION(PLAYER0,11,6)
ENDIF

IF(PLAYER0,DUNGEON_DESTROYED== 1)
  CHANGE_SLAB_TYPE(29,39,PATH,MATCH)
ENDIF

NEXT_COMMAND_REUSABLE
SET_CREATURE_TENDENCIES(PLAYER_GOOD,IMPRISON,1)

SET_GAME_RULE(MaxThingsInHand,30)
SET_HAND_RULE(PLAYER0,ANY_CREATURE,RULE1,DENY,DROPPED_TIME_LOWER,60)

SET_GAME_RULE(TrainingRoomMaxLevel,4)

IF(PLAYER0, BARRACKS >= 8)
	SET_GAME_RULE(TrainingRoomMaxLevel,8)
ENDIF

if(player0,ENTRANCE == 9)
  next_command_reusable
  max_creatures(Player0,15)
ENDIF
if(player0,ENTRANCE == 18)
  next_command_reusable
  max_creatures(Player0,20)
ENDIF
if(player0,ENTRANCE == 27)
  next_command_reusable
  max_creatures(Player0,25)
ENDIF

REM START INTRO

RUN_AFTER_VICTORY(1)

COMPUTER_PLAYER(PLAYER6,ROAMING)
ALLY_PLAYERS(PLAYER0,PLAYER6,3)
ALLY_PLAYERS(PLAYER0,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER6,3)
SET_PLAYER_COLOR(PLAYER6,RED)

SET_TIMER(PLAYER0,TIMER0)

IF(PLAYER0,TIMER0 >= 30)
    SET_POWER_CONFIGURATION(POWER_SIGHT,SoundPlayed,0)
    USE_POWER_AT_LOCATION(PLAYER0,7,POWER_SIGHT,6,1)
ENDIF

IF(PLAYER0,TIMER0 >= 10)
	IF(PLAYER0,TIMER0 <= 299)
		NEXT_COMMAND_REUSABLE
    	ZOOM_TO_LOCATION(PLAYER0,6)
	ENDIF
ENDIF

IF(PLAYER0,TIMER0 >= 300)
    ZOOM_TO_LOCATION(PLAYER0,PLAYER0)
    SET_POWER_CONFIGURATION(POWER_SIGHT,POWER,10,6)
    USE_POWER_AT_LOCATION(PLAYER0,7,POWER_SIGHT,6,1)
ENDIF

IF(PLAYER0,TIMER0 >= 320)
    SET_POWER_CONFIGURATION(POWER_SIGHT,SoundPlayed,51)
    SET_POWER_CONFIGURATION(POWER_SIGHT,POWER,896,6)
	SET_OBJECT_CONFIGURATION(AVATAR_TALK,MaximumSize,0)
    SET_OBJECT_CONFIGURATION(KNIGHT_STATUE,MaximumSize,0)
ENDIF

IF(PLAYER0,TIMER0 >= 45)
    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl19spe01.ogg")
    QUICK_OBJECTIVE(130,"Tristran, Felix, Balder - my beloved sons, I must send you on a mission to the neighbouring land. Patrol there and be sure to bring me word if evil Keeper stalks. And hold most precious all you three the secret of the Gem - if any one of you is threatened, you must return to safety by my side.")
	SET_OBJECT_CONFIGURATION(AVATAR_TALK,MaximumSize,500)
	SET_OBJECT_CONFIGURATION(KNIGHT_STATUE,MaximumSize,450)
ENDIF

IF(PLAYER0,TIMER0 >= 2000)
    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl19spe02.ogg")
    QUICK_OBJECTIVE(131,"Your mission is to capture and convert all three Princes to your side. They must neither die nor be allowed to flee through Hero Gates, which they'll attempt once one of them is injured. So to work!")
ENDIF

IF(PLAYER0, TRISTAN >= 1)
    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl19spe03.ogg")
    QUICK_OBJECTIVE(132,"I yield, Keeper. I, Tristran, will serve you well.")
ENDIF

IF(PLAYER0, BALDER >= 1)
    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl19spe04.ogg")
    QUICK_OBJECTIVE(133,"You are my master, Keeper. I, Balder will share with you my secret knowledge.")
ENDIF
IF(PLAYER0, FELIX >= 1)
    PLAY_MESSAGE(PLAYER0,SPEECH,"lvl19spe05.ogg")
    QUICK_OBJECTIVE(134,"Your torments have broken me. I, Felix, will fight for you against my father's land.")
ENDIF


IF_SLAB_OWNER(61,9,PLAYER0)
	IF_SLAB_OWNER(62,9,PLAYER0)
		IF_SLAB_OWNER(63,9,PLAYER0)
			IF_SLAB_OWNER(64,9,PLAYER0)
				IF_SLAB_OWNER(61,12,PLAYER0)
					IF_SLAB_OWNER(62,12,PLAYER0)
						IF_SLAB_OWNER(63,12,PLAYER0)
							IF_SLAB_OWNER(64,12,PLAYER0)
								IF_SLAB_OWNER(61,10,PLAYER0)
									IF_SLAB_OWNER(61,11,PLAYER0)
										IF_SLAB_OWNER(64,10,PLAYER0)
											IF_SLAB_OWNER(64,11,PLAYER0)
												CHANGE_SLAB_TYPE(62,10,BROKEN_ENTRANCE2x2,MATCH)
                                                HIDE_HERO_GATE(-2,1)
												CREATE_EFFECT(EFFECT_HARMLESS_GAS_1,8)
												USE_POWER_AT_LOCATION(PLAYER_GOOD,8,POWER_CAVE_IN,6,1)
												CREATE_EFFECT(EFFECT_HARMLESS_GAS_1,16)
												USE_POWER_AT_LOCATION(PLAYER_GOOD,16,POWER_CAVE_IN,6,1)
												PLAY_MESSAGE(PLAYER0,SOUND,152)
											ENDIF
										ENDIF
									ENDIF
								ENDIF
							ENDIF
						ENDIF
					ENDIF
				ENDIF
			ENDIF
		ENDIF
	ENDIF
ENDIF

IF_SLAB_OWNER(37,64,PLAYER0)
	IF_SLAB_OWNER(38,64,PLAYER0)
		IF_SLAB_OWNER(39,64,PLAYER0)
			IF_SLAB_OWNER(40,64,PLAYER0)
				IF_SLAB_OWNER(37,67,PLAYER0)
					IF_SLAB_OWNER(38,67,PLAYER0)
						IF_SLAB_OWNER(39,67,PLAYER0)
							IF_SLAB_OWNER(40,67,PLAYER0)
								IF_SLAB_OWNER(37,66,PLAYER0)
									IF_SLAB_OWNER(37,65,PLAYER0)
										IF_SLAB_OWNER(40,65,PLAYER0)
											IF_SLAB_OWNER(40,66,PLAYER0)
												CHANGE_SLAB_TYPE(38,65,BROKEN_ENTRANCE2x2,MATCH)
                                                HIDE_HERO_GATE(-3,1)
												CREATE_EFFECT(EFFECT_HARMLESS_GAS_1,17)
												USE_POWER_AT_LOCATION(PLAYER_GOOD,17,POWER_CAVE_IN,6,1)
												CREATE_EFFECT(EFFECT_HARMLESS_GAS_1,18)
												USE_POWER_AT_LOCATION(PLAYER_GOOD,18,POWER_CAVE_IN,6,1)
												PLAY_MESSAGE(PLAYER0,SOUND,152)
											ENDIF
										ENDIF
									ENDIF
								ENDIF
							ENDIF
						ENDIF
					ENDIF
				ENDIF
			ENDIF
		ENDIF
	ENDIF
ENDIF

REM PL3,FLAG5 active music track
rem value 2: dk2track02.mp3
rem value 4: dk2track04.mp3
SET_MUSIC("dk2track02.mp3")
SET_FLAG(PLAYER3,FLAG5,2)

IF(PLAYER3,FLAG5 != 4)
    REM Time battle music been playing
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER7)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES == 0)
	REM Time battle has been going on
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER3,TIMER6)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES > 0)
    REM Time no battle has been going on
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER5)
ENDIF

REM Start battle music if battle has been going on for at least 60 gameturns (3 seconds) and is not already playing
IF(PLAYER3,TIMER6 > 60)
    IF(PLAYER3,FLAG5 != 4)
		IF(PLAYER6,TIMER2 >=1200)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("battle04.mp3")
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER3,FLAG5,4)
		ENDIF
    ENDIF
ENDIF

REM Start only Battle Music if it hasn't been played for 1min

SET_TIMER(PLAYER6,TIMER2)
ADD_TO_TIMER(PLAYER6,TIMER2,1100)

IF(PLAYER3,FLAG5 == 4)
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER6,TIMER2)
ENDIF

REM Start regular music if battle music lasted at least 15 seconds and no fighting has occured for at least 5 seconds
IF(PLAYER3,TIMER7 > 300)
    IF(PLAYER3,TIMER5 > 100)
        IF(PLAYER3,FLAG5 != 2)
            NEXT_COMMAND_REUSABLE
            SET_MUSIC("dk2track02.mp3")
            NEXT_COMMAND_REUSABLE
            SET_FLAG(PLAYER3,FLAG5,2)
        ENDIF
    ENDIF
ENDIF

SET_TIMER(PLAYER0,TIMER2)

IF(PLAYER0,TIMER2 >= 250)
   		IF(PLAYER0,IMP <= 4)
        		NEXT_COMMAND_REUSABLE
			ADD_CREATURE_TO_LEVEL(PLAYER0,IMP,PLAYER0,2,1,100)
        		NEXT_COMMAND_REUSABLE
        		SET_TIMER(PLAYER0,TIMER2)
		ENDIF
ENDIF 

REM Triggerpoints

SET_TIMER(PLAYER3,TIMER4)

IF(PLAYER3,TIMER4 >=10)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(15,PLAYER_GOOD,FELIX,PLAYER_NEUTRAL,FLAG1)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(15,PLAYER_GOOD,BALDER,PLAYER_NEUTRAL,FLAG2)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(15,PLAYER_GOOD,TRISTAN,PLAYER_NEUTRAL,FLAG3)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(2,PLAYER_GOOD,FELIX,PLAYER5,FLAG1)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(2,PLAYER_GOOD,BALDER,PLAYER5,FLAG2)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(2,PLAYER_GOOD,TRISTAN,PLAYER5,FLAG3)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(1,PLAYER_GOOD,FELIX,PLAYER6,FLAG1)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(1,PLAYER_GOOD,BALDER,PLAYER6,FLAG2)
	NEXT_COMMAND_REUSABLE
	COUNT_CREATURES_AT_ACTION_POINT(1,PLAYER_GOOD,TRISTAN,PLAYER6,FLAG3)
	NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER4)
ENDIF

SET_FLAG(PLAYER_NEUTRAL,FLAG1,0)
SET_FLAG(PLAYER_NEUTRAL,FLAG2,0)
SET_FLAG(PLAYER_NEUTRAL,FLAG3,0)

SET_FLAG(PLAYER5,FLAG1,0)
SET_FLAG(PLAYER5,FLAG2,0)
SET_FLAG(PLAYER5,FLAG3,0)

SET_FLAG(PLAYER6,FLAG1,0)
SET_FLAG(PLAYER6,FLAG2,0)
SET_FLAG(PLAYER6,FLAG3,0)
SET_FLAG(PLAYER6,FLAG4,0)

IF(PLAYER_NEUTRAL, FLAG1 > 0)
	SET_FLAG(PLAYER6,FLAG4,1)
ENDIF

IF(PLAYER_NEUTRAL, FLAG2 > 0)
	SET_FLAG(PLAYER6,FLAG4,1)
ENDIF

IF(PLAYER_NEUTRAL, FLAG3 > 0)
	SET_FLAG(PLAYER6,FLAG4,1)
ENDIF

IF(PLAYER5, FLAG1 > 0)
	SET_FLAG(PLAYER6,FLAG4,1)
ENDIF

IF(PLAYER5, FLAG2 > 0)
	SET_FLAG(PLAYER6,FLAG4,1)
ENDIF

IF(PLAYER5, FLAG3 > 0)
	SET_FLAG(PLAYER6,FLAG4,1)
ENDIF

IF(PLAYER6, FLAG1 > 0)
	SET_FLAG(PLAYER6,FLAG4,1)
ENDIF

IF(PLAYER6, FLAG2 > 0)
	SET_FLAG(PLAYER6,FLAG4,1)
ENDIF

IF(PLAYER6, FLAG3 > 0)
	SET_FLAG(PLAYER6,FLAG4,1)
ENDIF


IF(PLAYER6, FLAG4 > 0)
	LOSE_GAME
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl19spe06.ogg")
	QUICK_OBJECTIVE(135,"Fool. You allow this Prince to flee despite my warning. Now the Gem will always lie beyond your reach.")
ENDIF




IF(PLAYER0,GAME_TURN >=2000)
    IF(PLAYER_GOOD, FELIX == 0)
        IF(PLAYER0, FELIX == 0)
            PLAY_MESSAGE(PLAYER0,SPEECH,"lvl19spe07.ogg")
            QUICK_OBJECTIVE(136,"Fool. You allow this Prince to die despite my warning. Now your hands will never hold the Portal Gem.")
            LOSE_GAME
        ENDIF
	ENDIF
ENDIF

IF(PLAYER0,GAME_TURN >=2000)
    IF(PLAYER_GOOD, BALDER == 0)
        IF(PLAYER0, BALDER == 0)
            PLAY_MESSAGE(PLAYER0,SPEECH,"lvl19spe07.ogg")
            QUICK_OBJECTIVE(136,"Fool. You allow this Prince to die despite my warning. Now your hands will never hold the Portal Gem.")
            LOSE_GAME
        ENDIF
	ENDIF
ENDIF

IF(PLAYER0,GAME_TURN >=2000)
    IF(PLAYER_GOOD, TRISTAN == 0)
    	IF(PLAYER0, TRISTAN == 0)
        	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl19spe07.ogg")
    		QUICK_OBJECTIVE(136,"Fool. You allow this Prince to die despite my warning. Now your hands will never hold the Portal Gem.")
    		LOSE_GAME
        ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD, TRISTAN == 0)
    IF(PLAYER_GOOD, BALDER == 0)
        IF(PLAYER_GOOD, FELIX == 0)
	        IF(PLAYER0, TRISTAN == 1)
	            IF(PLAYER0, BALDER == 1)
	                IF(PLAYER0, FELIX == 1)
	                	SET_TIMER(PLAYER2,TIMER6)
                    ENDIF
                ENDIF
            ENDIF
        ENDIF            
	ENDIF
ENDIF

IF(PLAYER2,TIMER6 >= 250)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl19spe08.ogg")
	QUICK_OBJECTIVE(137,"At last, you've turned the King's three spineless sons against him with your evil cunning. So they lead you to the Gem. Your pleasure is my satisfaction Keeper; journey on.")
	WIN_GAME
	ADD_OBJECT_TO_LEVEL(FAKE_GEM,12,1,PLAYER5)
	ZOOM_TO_LOCATION(PLAYER0,12)
  	COMPUTER_PLAYER(PLAYER5,ROAMING)
  	SET_TIMER(PLAYER6,TIMER6) 
	REVEAL_MAP_LOCATION(PLAYER0,PLAYER_GOOD,-1)
    CHANGE_SLAB_TYPE(61,40,PRETTY_PATH)
    CHANGE_SLAB_TYPE(61,42,PRETTY_PATH)
    CHANGE_SLAB_TYPE(60,41,PRETTY_PATH)
    CHANGE_SLAB_TYPE(62,41,PRETTY_PATH)
    CHANGE_SLAB_OWNER(61,40,PLAYER0)
    CHANGE_SLAB_OWNER(61,42,PLAYER0)
    CHANGE_SLAB_OWNER(60,41,PLAYER0)
    CHANGE_SLAB_OWNER(62,41,PLAYER0)
    CHANGE_SLAB_OWNER(61,41,PLAYER0)
ENDIF

REM OUTRO

IF(PLAYER6,TIMER6 >= 20)
    MAGIC_AVAILABLE(PLAYER0,POWER_POSSESS,0,0)
ENDIF

IF(PLAYER6,TIMER6 >= 60)
    ZOOM_TO_LOCATION(PLAYER0,14)
    CREATE_EFFECT(EFFECT_FLASH,PLAYER0)
ENDIF

IF(PLAYER6,TIMER6 >= 70)
    CREATE_EFFECT(EFFECT_WORD_OF_POWER,14)
    CREATE_EFFECT(EFFECT_EXPLOSION_5,14)
    CREATE_EFFECT(EFFECT_SPANGLE_RED,14)
    ADD_OBJECT_TO_LEVEL(HORNY_SPAWN,14,1,PLAYER0,South)
ENDIF

IF(PLAYER6,TIMER6 >= 138)
	RUN_LUA_CODE("SpawnHorny(14)")
	SET_OBJECT_CONFIGURATION(HORNY_SPAWN,MaximumSize,0)
ENDIF

IF(PLAYER5,HEART_HEALTH > 0)
    SET_FLAG(PLAYER0,FLAG0,8)
ENDIF

IF(PLAYER0,FLAG0 == 8)
    IF(PLAYER5,HEART_HEALTH < 3)
        SET_OBJECT_CONFIGURATION(FAKE_GEM,UpdateFunction,UPDATE_POWER_LIGHTNING)
        SET_TIMER(PLAYER6,TIMER7)
    ENDIF
ENDIF

IF(PLAYER6,TIMER7 > 5)
    PLAY_MESSAGE(PLAYER0,SOUND,116)
ENDIF

IF(PLAYER6,TIMER7 > 100)
    KILL_CREATURE(PLAYER6,EVILLORD,ANYWHERE,1)
ENDIF