REM ********************************************
REM
REM             Script for Level 226
REM
REM ********************************************
LEVEL_VERSION(1)
SET_GENERATE_SPEED(400)
MAX_CREATURES(PLAYER0, 15)
START_MONEY(PLAYER0, 10000)

SET_TEXTURE(PLAYER_GOOD,18)

ADD_CREATURE_TO_POOL(WARLOCK, 10)
ADD_CREATURE_TO_POOL(GOBLIN, 10)
ADD_CREATURE_TO_POOL(TROLL, 10)
ADD_CREATURE_TO_POOL(FIREFLY, 5)
ADD_CREATURE_TO_POOL(GOBLIN, 10)
ADD_CREATURE_TO_POOL(MISTRESS, 5)
ADD_CREATURE_TO_POOL(DARK_ELF,20)

CREATURE_AVAILABLE(ALL_PLAYERS, WARLOCK, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, GOBLIN, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, FIREFLY, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, TROLL, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, GOBLIN, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, MISTRESS, 1, 0)
CREATURE_AVAILABLE(ALL_PLAYERS, DARK_ELF,1,0)

SET_GAME_RULE(TrainingRoomMaxLevel,4)

ROOM_AVAILABLE(ALL_PLAYERS, RESEARCH, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, GARDEN, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, LAIR, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TRAINING, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, TREASURE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, WORKSHOP, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, BRIDGE, 1, 1)
ROOM_AVAILABLE(ALL_PLAYERS, PRISON, 1, 1)

MAGIC_AVAILABLE(ALL_PLAYERS, POWER_HAND, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_OBEY, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_SLAP, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_IMP, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_POSSESS, 1, 1)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_LIGHTNING, 1, 0)
MAGIC_AVAILABLE(ALL_PLAYERS, POWER_HEAL_CREATURE, 1, 0)

DOOR_AVAILABLE(ALL_PLAYERS, WOOD, 1, 0)
TRAP_AVAILABLE(ALL_PLAYERS, EVIL_SENTRY, 1, 0)
TRAP_AVAILABLE(ALL_PLAYERS, BARRICADE_TRAP_EVIL,1,0)
TRAP_AVAILABLE(ALL_PLAYERS, FEAR_TRAP,1,0)

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_POSSESS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_IMP,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ADVANCED_LIGHTNING,1,0)

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_IMP == 1)
    SET_POWER_CONFIGURATION(POWER_IMP,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_IMP,PanelTabIndex,2)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_OBEY == 1)
    SET_POWER_CONFIGURATION(POWER_OBEY,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_OBEY,PanelTabIndex,5)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_HEAL_CREATURE == 1)
    SET_POWER_CONFIGURATION(POWER_HEAL_CREATURE,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_HEAL_CREATURE,PanelTabIndex,10)
ENDIF

IF_AVAILABLE(PLAYER0,POWER_ADVANCED_LIGHTNING == 1)
    SET_POWER_CONFIGURATION(POWER_LIGHTNING,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_LIGHTNING,PanelTabIndex,11)
ENDIF
IF_AVAILABLE(PLAYER0,POWER_ADVANCED_POSSESS == 1)
    SET_POWER_CONFIGURATION(POWER_POSSESS,PanelTabIndex,0)
        SET_POWER_CONFIGURATION(POWER_ADVANCED_POSSESS,PanelTabIndex,1)
ENDIF

SET_HAND_RULE(PLAYER0,ANY_CREATURE,RULE1,DENY,DROPPED_TIME_LOWER,60)
SET_GAME_RULE(MaxThingsInHand,30)

IF(PLAYER1,CAMPAIGN_FLAG1 == 1)
	CONCEAL_MAP_RECT(Player0, 127, 127, 250, 250,1)
ENDIF

SET_CREATURE_PROPERTY(KNIGHT,LORD,0)

REVEAL_MAP_LOCATION(PLAYER0,PLAYER0,-1)

if(player0,ENTRANCE == 9)
  next_command_reusable
  max_creatures(Player0,15)
ENDIF
if(player0,ENTRANCE == 18)
  next_command_reusable
  max_creatures(Player0,20)
ENDIF
if(player0,ENTRANCE == 27)
  next_command_reusable
  max_creatures(Player0,25)
ENDIF

REM # "Happy Box: All friendly minions get happy."

SET_BOX_TOOLTIP(10,"Make Happy Box")

IF(PLAYER0,BOX10_ACTIVATED == 1)
    NEXT_COMMAND_REUSABLE
    CHANGE_CREATURES_ANNOYANCE(PLAYER0,ANY_CREATURE,SET,0)
    NEXT_COMMAND_REUSABLE
    CHANGE_CREATURES_ANNOYANCE(PLAYER0,IMP,SET,0)
    NEXT_COMMAND_REUSABLE
    SET_FLAG(PLAYER0,BOX10_ACTIVATED,0)
ENDIF

REM # "Research box"

SET_BOX_TOOLTIP(12,"Research box")

IF(PLAYER0,BOX12_ACTIVATED == 1)
    NEXT_COMMAND_REUSABLE
    SET_FLAG(PLAYER0,SACRIFICED[FLY],2)
    NEXT_COMMAND_REUSABLE    
    SET_FLAG(PLAYER0,BOX12_ACTIVATED,0)
ENDIF

REM INTRO

RUN_AFTER_VICTORY(1)

IF(PLAYER0,DUNGEON_DESTROYED== 1)
  CHANGE_SLAB_TYPE(56,73,PATH,MATCH)
ENDIF

COMPUTER_PLAYER(PLAYER6,ROAMING)
ALLY_PLAYERS(PLAYER0,PLAYER6,3)
ALLY_PLAYERS(PLAYER0,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER5,3)
ALLY_PLAYERS(PLAYER_GOOD,PLAYER6,3)
SET_PLAYER_COLOR(PLAYER6,RED)

SET_TIMER(PLAYER0,TIMER4)

IF(PLAYER0,TIMER4 >= 30)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl6Bspe01.ogg")
	QUICK_OBJECTIVE(43,"Seek amongst these caverns and you'll find much useful tackle stowed here o'er the years by good Lord Ironhelm and his cronies. Help yourself - for just as 'finders keepers', Keepers finders be!")
ENDIF

IF(PLAYER0,TIMER4 >= 1200)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl6spe03.ogg")
	QUICK_INFORMATION(44,"Your creatures are outnumbered: a trouble, since no Portal provides entry to this realm. They are indeed in danger, unless you find a clever way to make their numbers swell.")
ENDIF

IF(PLAYER0,TIMER4 >= 2000)
	ROOM_AVAILABLE(ALL_PLAYERS, TORTURE, 1, 1)
	TUTORIAL_FLASH_BUTTON(10,1)
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl6spe04.ogg")
	ZOOM_TO_LOCATION(PLAYER0,9)
	QUICK_INFORMATION(45,"Behold the Torture Chamber. A paradise of pain. To use it pick your captives from the Prison and then drop them there on those machines and watch them scream out secrets to their captors. Finally the spineless scum amongst them beg for mercy then betray their goodly comrades switching sides to yours. Your Evil Hand can cast this spell to heal the wounds and scars and broken bones of battle-weary warriors whose fight is in your name.")
ENDIF

IF(PLAYER0, GHOST >= 1)
	QUICK_INFORMATION(47,"A fragile Hero has died in your Torture Chamber. Heal them if you can to prolong their suffering, and allow them time to convert to your cause.")
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl6spe06.ogg")
ENDIF

REM PL3,FLAG5 active music track
rem value 2: dk2track02.mp3
rem value 4: dk2track04.mp3
SET_MUSIC("dk2track02.mp3")
SET_FLAG(PLAYER3,FLAG5,2)

IF(PLAYER3,FLAG5 != 4)
    REM Time battle music been playing
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER7)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES == 0)
	REM Time battle has been going on
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER3,TIMER6)
ENDIF

IF(PLAYER0,ACTIVE_BATTLES > 0)
    REM Time no battle has been going on
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER3,TIMER5)
ENDIF

REM Start battle music if battle has been going on for at least 60 gameturns (3 seconds) and is not already playing
IF(PLAYER3,TIMER6 > 60)
    IF(PLAYER3,FLAG5 != 4)
		IF(PLAYER6,TIMER2 >=1200)
			NEXT_COMMAND_REUSABLE
			SET_MUSIC("battle02.mp3")
			NEXT_COMMAND_REUSABLE
			SET_FLAG(PLAYER3,FLAG5,4)
		ENDIF
    ENDIF
ENDIF

REM Start only Battle Music if it hasn't been played for 1min

SET_TIMER(PLAYER6,TIMER2)
ADD_TO_TIMER(PLAYER6,TIMER2,1100)

IF(PLAYER3,FLAG5 == 4)
	NEXT_COMMAND_REUSABLE
	SET_TIMER(PLAYER6,TIMER2)
ENDIF

REM Start regular music if battle music lasted at least 15 seconds and no fighting has occured for at least 5 seconds
IF(PLAYER3,TIMER7 > 300)
    IF(PLAYER3,TIMER5 > 100)
        IF(PLAYER3,FLAG5 != 2)
            NEXT_COMMAND_REUSABLE
            SET_MUSIC("dk2track02.mp3")
            NEXT_COMMAND_REUSABLE
            SET_FLAG(PLAYER3,FLAG5,2)
        ENDIF
    ENDIF
ENDIF

SET_TIMER(PLAYER0,TIMER2)

IF(PLAYER0,TIMER2 >= 250)
   		IF(PLAYER0,IMP <= 4)
        		NEXT_COMMAND_REUSABLE
			ADD_CREATURE_TO_LEVEL(PLAYER0,IMP,PLAYER0,2,1,100)
        		NEXT_COMMAND_REUSABLE
        		SET_TIMER(PLAYER0,TIMER2)
		ENDIF
ENDIF 

IF(PLAYER_GOOD, KNIGHT == 0)
	WIN_GAME
	SET_NEXT_LEVEL(206)
	HIDE_BONUS_LEVEL(226)
	QUICK_OBJECTIVE(49,"I see with satisfaction the slaughtered beast that once was called Lord Ironhelm. Sad? For him maybe, but yours is not to pity. His path was sickly righteous, its disposal served our needs. And you must bask in reputation well deserved - pure evil are your deeds.")
	PLAY_MESSAGE(PLAYER0,SPEECH,"lvl6spe08.ogg")
  	ADD_OBJECT_TO_LEVEL(FAKE_GEM,LAST_DEATH_EVENT[PLAYER_GOOD],1,PLAYER5)
 	COMPUTER_PLAYER(PLAYER5,ROAMING)
 	SET_TIMER(PLAYER6,TIMER6)
	REVEAL_MAP_LOCATION(PLAYER0,PLAYER_GOOD,-1)
ENDIF

HIDE_HERO_GATE(1,1)

REM OUTRO

IF(PLAYER6,TIMER6 >= 20)
    MAGIC_AVAILABLE(PLAYER0,POWER_POSSESS,0,0)
ENDIF

IF(PLAYER6,TIMER6 >= 60)
    ZOOM_TO_LOCATION(PLAYER0,-1)
    CREATE_EFFECT(EFFECT_FLASH,PLAYER0)
ENDIF

IF(PLAYER6,TIMER6 >= 70)
    CREATE_EFFECT(EFFECT_WORD_OF_POWER,-1)
    CREATE_EFFECT(EFFECT_EXPLOSION_5,-1)
    CREATE_EFFECT(EFFECT_SPANGLE_RED,-1)
    ADD_OBJECT_TO_LEVEL(HORNY_SPAWN,-1,1,PLAYER0,South)
ENDIF

IF(PLAYER6,TIMER6 >= 138)
	RUN_LUA_CODE("SpawnHorny(-1)")
	SET_OBJECT_CONFIGURATION(HORNY_SPAWN,MaximumSize,0)
ENDIF

IF(PLAYER5,HEART_HEALTH > 0)
    SET_FLAG(PLAYER0,FLAG0,8)
ENDIF

IF(PLAYER0,FLAG0 == 8)
    IF(PLAYER5,HEART_HEALTH < 3)
        SET_OBJECT_CONFIGURATION(FAKE_GEM,UpdateFunction,UPDATE_POWER_LIGHTNING)
        SET_TIMER(PLAYER6,TIMER7)
    ENDIF
ENDIF

IF(PLAYER6,TIMER7 > 5)
    PLAY_MESSAGE(PLAYER0,SOUND,116)
ENDIF

IF(PLAYER6,TIMER7 > 100)
    KILL_CREATURE(PLAYER6,EVILLORD,ANYWHERE,1)
ENDIF