REM ********************************************
REM
REM Script for Level 203
REM
REM ****************BY MARK NASH****************

REM VERSION 2.0

REM **********     SETUP COMMANDS     **********


REM ***** Set the Generation Speed of the  *****
REM ***** Entrances                        *****

SET_GENERATE_SPEED(450)


REM ***** Set the computer players going   *****

REM Player		Player Type

COMPUTER_PLAYER(PLAYER1,10)
SET_COMPUTER_CHECKS(PLAYER1,"CHECK FOR NEUTRAL PLACES",15000,0,0,0,65000)
REM CheckEvery	AttackPercent	CTADuration	MinForAttack	LastCheck
SET_COMPUTER_CHECKS(PLAYER1,"CHECK FOR QUICK ATTACK",700,70,3000,8,12500)
SET_COMPUTER_PROCESS(PLAYER1,"ATTACK SAFE ATTACK",-1,100,17,100,0)
SET_COMPUTER_PROCESS(PLAYER1,"ATTACK PLAN 1",-1,100,17,100,0)
SET_COMPUTER_PROCESS(PLAYER1,"BUILD A SCAVENGER ROOM",-10,2,2,9,8)

COMPUTER_PLAYER(PLAYER2,1)
SET_COMPUTER_CHECKS(PLAYER2,"CHECK FOR NEUTRAL PLACES",15000,0,0,0,65000)
REM CheckEvery	AttackPercent	CTADuration	MinForAttack	LastCheck
SET_COMPUTER_CHECKS(PLAYER2,"CHECK FOR QUICK ATTACK",700,70,3000,8,12500)
SET_COMPUTER_PROCESS(PLAYER2,"ATTACK SAFE ATTACK",-1,100,17,100,0)
SET_COMPUTER_PROCESS(PLAYER2,"ATTACK PLAN 1",-1,100,17,100,0)
SET_COMPUTER_PROCESS(PLAYER2,"BUILD A SCAVENGER ROOM",-10,2,2,9,8)

ALLY_PLAYERS(PLAYER1,PLAYER2)

REM ***** Set the maximum number of        *****
REM ***** creatures each player can have   *****

REM Player  Number of creatures

MAX_CREATURES(PLAYER0,40)
MAX_CREATURES(PLAYER1,45)
MAX_CREATURES(PLAYER2,45)

REM ***** Set the amount of gold each      *****
REM ***** player starts with               *****

REM Player	    Amount of gold

START_MONEY(PLAYER0,10000)
START_MONEY(PLAYER1,8000)
START_MONEY(PLAYER2,8000)

REM **********       SET MAGIC        **********
REM **********     AND CREATURES      **********

REM ***** Setup the creature pool          *****

REM Creature Name	Number of creatures

ADD_CREATURE_TO_POOL(BUG,40)
ADD_CREATURE_TO_POOL(FLY,40)
ADD_CREATURE_TO_POOL(SPIDER,10)
ADD_CREATURE_TO_POOL(SORCEROR,20)
ADD_CREATURE_TO_POOL(DEMONSPAWN,20)
ADD_CREATURE_TO_POOL(DRAGON,5)
ADD_CREATURE_TO_POOL(TROLL,15)
ADD_CREATURE_TO_POOL(ORC,10)
ADD_CREATURE_TO_POOL(HELL_HOUND,10)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,8)
ADD_CREATURE_TO_POOL(BILE_DEMON,25)

REM ***** Enable each player to recieve    *****
REM ***** creatures from pool              *****

REM Player		Creatures	Can be available	Is now available

CREATURE_AVAILABLE(ALL_PLAYERS,BUG,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,FLY,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,SPIDER,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,SORCEROR,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,DEMONSPAWN,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,DRAGON,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,TROLL,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,ORC,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,HELL_HOUND,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,DARK_MISTRESS,1,1)
CREATURE_AVAILABLE(ALL_PLAYERS,BILE_DEMON,1,1)
CREATURE_AVAILABLE(PLAYER0,SAMURAI,1,1)

REM ***** Set the rooms available to each  *****
REM ***** player                           *****

REM Player		Room type	Can be available	Is available

ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,GARDEN,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,TRAINING,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
ROOM_AVAILABLE(ALL_PLAYERS,WORKSHOP,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BARRACKS,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GUARD_POST,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,BRIDGE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,PRISON,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TORTURE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,SCAVENGER,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,0)
ROOM_AVAILABLE(ALL_PLAYERS,GRAVEYARD,1,0)


REM ***** Set the doors available to each  *****
REM ***** player                           *****

REM Player		Door type		Can be available	Is available

DOOR_AVAILABLE(ALL_PLAYERS,WOOD,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,BRACED,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,STEEL,1,0)
DOOR_AVAILABLE(ALL_PLAYERS,MAGIC,1,0)


REM ***** Set the traps available to each  *****
REM ***** player                           *****

REM Player		Trap type		Can be available	Is available

TRAP_AVAILABLE(ALL_PLAYERS,BOULDER,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,ALARM,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,POISON_GAS,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LIGHTNING,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,WORD_OF_POWER,1,0)
TRAP_AVAILABLE(ALL_PLAYERS,LAVA,1,0)


REM ***** Set the spells available to each *****
REM ***** player                           *****

REM Player		Spell type		Can be available	Is available

MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_OBEY,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CAVE_IN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SPEED,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DISEASE,0,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_CHICKEN,1,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_DESTROY_WALLS,0,0)
MAGIC_AVAILABLE(ALL_PLAYERS,POWER_ARMAGEDDON,0,0)

REM **********  ADJUST ANY CREATURE   **********
REM ********** OR RESEARCH STATISTICS **********

REM Example:
REM ***** Change the research value of the *****
REM ***** Scavenger Room from 27500 to     *****
REM ***** 50000                            *****

REM RESEARCH(PLAYER1,ROOM,SCAVENGER,50000)


REM ********** SETUP FLAGS AND TIMERS **********

REM ***** FLAGS *****

REM Player		Flag Name	Flag's number

SET_FLAG(PLAYER0,FLAG0,0)
SET_FLAG(PLAYER0,FLAG1,1)

REM ***** TIMERS *****
REM Player  Timer Name

SET_TIMER(PLAYER0,TIMER0)

REM **********     OBJECTIVES AND     **********
REM **********      INFORMATION       **********

REM Below is how you place text within the game,
REM it uses the "?" and will come up automatically, you can have it as
REM DISPLAY_INFORMATION but that will be a "!" like when you capture new rooms
REM or new monsters join you in the main game, With Deeper Dungeons You can write your own objectives.
REM until I get my hands on that I'll have to steal TEXT from the main game.

DISPLAY_OBJECTIVE(113,PLAYER0)

REM **********     CREATE AND ADD     **********
REM **********  CREATURES TO PARTIES  **********

REM ***** Create any parties               *****

REM Party Name

CREATE_PARTY(PARTY1)
CREATE_PARTY(PARTY2)
CREATE_PARTY(PARTY3)
CREATE_PARTY(PARTY4)
CREATE_PARTY(PARTY5)

REM ***** Add creatures to those parties   *****

REM Party Name	Creature Name	Experience 	Amount of Gold	Objective		Countdown

    ADD_TO_PARTY(PARTY1,GIANT,3,200,DEFEND_PARTY,0)
    ADD_TO_PARTY(PARTY1,BARBARIAN,4,200,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(PARTY1,BARBARIAN,4,200,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(PARTY1,BARBARIAN,4,200,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(PARTY1,DWARFA,5,1000,ATTACK_ROOMS,0)

    ADD_TO_PARTY(PARTY2,DWARFA,5,1000,DEFEND_PARTY,0)
    ADD_TO_PARTY(PARTY2,ARCHER,3,200,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(PARTY2,WIZARD,5,800,STEAL_SPELLS,0)
    ADD_TO_PARTY(PARTY2,ARCHER,3,200,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(PARTY2,GIANT,4,200,DEFEND_PARTY,0)

    ADD_TO_PARTY(PARTY3,SAMURAI,8,500,DEFEND_PARTY,0)
    ADD_TO_PARTY(PARTY3,ARCHER,3,600,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(PARTY3,ARCHER,3,600,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(PARTY3,GIANT,4,200,DEFEND_PARTY,0)
    ADD_TO_PARTY(PARTY3,GIANT,4,200,DEFEND_PARTY,0)
    ADD_TO_PARTY(PARTY3,WIZARD,5,600,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(PARTY3,WIZARD,5,500,ATTACK_ENEMIES,0)

    ADD_TO_PARTY(PARTY4,THIEF,1,500,STEAL_GOLD,0)
    ADD_TO_PARTY(PARTY4,THIEF,1,100,STEAL_GOLD,0)
    ADD_TO_PARTY(PARTY4,THIEF,1,100,STEAL_GOLD,0)
    ADD_TO_PARTY(PARTY4,THIEF,1,100,STEAL_GOLD,0)
    ADD_TO_PARTY(PARTY4,THIEF,1,100,STEAL_GOLD,0)

    ADD_TO_PARTY(PARTY5,BARBARIAN,5,200,DEFEND_PARTY,0)
    ADD_TO_PARTY(PARTY5,MONK,4,0,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(PARTY5,THIEF,3,200,STEAL_GOLD,0)
    ADD_TO_PARTY(PARTY5,THIEF,3,200,ATTACK_ENEMIES,0)
    ADD_TO_PARTY(PARTY5,FAIRY,5,1500,DEFEND_PARTY,0)

REM **********      MAIN SCRIPT       **********


REM **********      IF COMMANDS       **********

REM Action Point	Which player you want to detect

IF_ACTION_POINT(3,PLAYER0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY3,-1,1)
ENDIF

IF(PLAYER0,TIMER0 >= 32400)
    DISPLAY_OBJECTIVE(130,PLAYER0)
    NEXT_COMMAND_REUSABLE
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY1,1,DUNGEON,0,3,400)
    NEXT_COMMAND_REUSABLE
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY2,2,DUNGEON,0,3,400)
    NEXT_COMMAND_REUSABLE
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY5,5,DUNGEON,0,3,400)
    NEXT_COMMAND_REUSABLE
    SET_TIMER(PLAYER0,TIMER0)
ENDIF

IF(PLAYER0,TIMER0 >= 21600)
    NEXT_COMMAND_REUSABLE
    ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY4,1,APPROPIATE_DUNGEON,0,1,600)
ENDIF

IF(PLAYER0,TIMER0 >= 5760)
    
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,1,DUNGEON,0,1,0)
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,2,DUNGEON,0,1,0)
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,3,DUNGEON,1,1,0)
    ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,3,DUNGEON,2,1,0)
    
ENDIF

IF(PLAYER0,TOTAL_CREATURES >= 39)
    ADD_CREATURE_TO_POOL(SAMURAI,1)
ENDIF

IF(PLAYER0,SAMURAI > 0)
    CREATURE_AVAILABLE(PLAYER0,THIEF,1,1)
    CREATURE_AVAILABLE(PLAYER0,BARBARIAN,1,1)
    ADD_CREATURE_TO_POOL(THIEF,5)
    ADD_CREATURE_TO_POOL(BARBARIAN,3)
    
ENDIF

REM **********      WIN AND LOSE      **********

REM Player		Variable		Comparison	Value

IF(PLAYER1,DUNGEON_DESTROYED == 1)
    IF(PLAYER2,DUNGEON_DESTROYED == 1)
        DISPLAY_OBJECTIVE(111,PLAYER0)
        SET_TIMER(PLAYER0,TIMER1)
        IF(PLAYER0,TIMER1 >= 720)
            ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,KNIGHT,-1,1,10,1000000)
            ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,WIZARD,-1,1,8,5000)
            ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,-1,2,4,2500)
            ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY1,-1,1)
            ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY2,-1,1)
            ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY4,-1,1)
            ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY5,-1,1)
            DISPLAY_OBJECTIVE(73,PLAYER0)
            IF(PLAYER_GOOD,TOTAL_CREATURES == 0)
                DISPLAY_OBJECTIVE(112,PLAYER0)
                WIN_GAME
            ENDIF
        ENDIF
    ENDIF
ENDIF
