
REM ##########################################
REM ########### The Realm of Salvi ###########
REM ##########################################


REM V 1.0


REM By

REM Cisz Helion the Halfmaterial

REM Cisz_Helion@gmx.de



REM This Map is done with Unded (slabs and setup section of the .txt),
REM AdiktEd and DKedit (details and finishing). (And a .txt Editor of
REM course :) The Messages were changed with the AdiktEd utils.


REM All ye Keepers, come to Fizz Ban's Keep at
REM www.scott.net/~sragan/dungeon



REM The Story

REM The realm you're about to enter is a well known place for
REM your opponent, a mighty Keeper that is about to take control
REM of it.

REM Even worse, your powers are few because he is much more
REM famous than you are (at least round here).

REM The evil gods are on his side, but maybe you can get their
REM attention and perhaps even their assistance.

REM Please don't read any further before playing the Level.

REM ################# Game Setup ################



REM ************ Basic Settings **************

COMPUTER_PLAYER(PLAYER2,0)

START_MONEY(PLAYER0,5000)
START_MONEY(PLAYER2,5000)
MAX_CREATURES(PLAYER0,16)
MAX_CREATURES(PLAYER2,24)



REM ********** Creatures *************

CREATURE_AVAILABLE(PLAYER0,FLY,1,1)
CREATURE_AVAILABLE(PLAYER0,SPIDER,1,1)
CREATURE_AVAILABLE(PLAYER0,BUG,1,1)

CREATURE_AVAILABLE(PLAYER2,DRAGON,1,1)
CREATURE_AVAILABLE(PLAYER2,ORC,1,1)
CREATURE_AVAILABLE(PLAYER2,HELL_HOUND,1,1)
CREATURE_AVAILABLE(PLAYER2,SPIDER,1,1)
CREATURE_AVAILABLE(PLAYER2,BUG,1,1)
CREATURE_AVAILABLE(PLAYER2,BILE_DEMON,1,1)
CREATURE_AVAILABLE(PLAYER2,SORCEROR,1,1)
CREATURE_AVAILABLE(PLAYER2,DARK_MISTRESS,1,1)
CREATURE_AVAILABLE(PLAYER2,FLY,1,1)
CREATURE_AVAILABLE(PLAYER2,DEMONSPAWN,1,1)

ADD_CREATURE_TO_POOL(DRAGON,8)
ADD_CREATURE_TO_POOL(ORC,10)
ADD_CREATURE_TO_POOL(HELL_HOUND,4)
ADD_CREATURE_TO_POOL(SPIDER,15)
ADD_CREATURE_TO_POOL(BUG,15)
ADD_CREATURE_TO_POOL(BILE_DEMON,8)
ADD_CREATURE_TO_POOL(SORCEROR,8)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,10)
ADD_CREATURE_TO_POOL(FLY,15)
ADD_CREATURE_TO_POOL(DEMONSPAWN,4)



REM ********** Magic **********

MAGIC_AVAILABLE(PLAYER0,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_DESTROY_WALLS,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_HAND,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_SLAP,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_POSSESS,1,1)
MAGIC_AVAILABLE(PLAYER0,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(PLAYER0,POWER_SPEED,1,0)

MAGIC_AVAILABLE(PLAYER2,POWER_CHICKEN,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_CALL_TO_ARMS,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_HOLD_AUDIENCE,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_PROTECT,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_DESTROY_WALLS,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_HAND,1,1)
MAGIC_AVAILABLE(PLAYER2,POWER_SLAP,1,1)
MAGIC_AVAILABLE(PLAYER2,POWER_CAVE_IN,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_LIGHTNING,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_CONCEAL,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_POSSESS,1,1)
MAGIC_AVAILABLE(PLAYER2,POWER_IMP,1,1)
MAGIC_AVAILABLE(PLAYER2,POWER_SIGHT,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_HEAL_CREATURE,1,0)
MAGIC_AVAILABLE(PLAYER2,POWER_SPEED,1,0)



REM ************* Rooms ***********

ROOM_AVAILABLE(PLAYER0,TORTURE,1,0)
ROOM_AVAILABLE(PLAYER0,BARRACKS,1,0)
ROOM_AVAILABLE(PLAYER0,TREASURE,1,1)
ROOM_AVAILABLE(PLAYER0,GUARD_POST,1,0)
ROOM_AVAILABLE(PLAYER0,GARDEN,1,1)
ROOM_AVAILABLE(PLAYER0,RESEARCH,1,1)
ROOM_AVAILABLE(PLAYER0,LAIR,1,1)
ROOM_AVAILABLE(PLAYER0,PRISON,1,0)

ROOM_AVAILABLE(PLAYER2,GRAVEYARD,1,0)
ROOM_AVAILABLE(PLAYER2,TRAINING,1,0)
ROOM_AVAILABLE(PLAYER2,BARRACKS,1,0)
ROOM_AVAILABLE(PLAYER2,TREASURE,1,1)
ROOM_AVAILABLE(PLAYER2,WORKSHOP,1,0)
ROOM_AVAILABLE(PLAYER2,GARDEN,1,1)
ROOM_AVAILABLE(PLAYER2,RESEARCH,1,1)
ROOM_AVAILABLE(PLAYER2,SCAVENGER,1,0)
ROOM_AVAILABLE(PLAYER2,LAIR,1,1)
ROOM_AVAILABLE(PLAYER2,GUARD_POST,1,0)
ROOM_AVAILABLE(PLAYER2,PRISON,1,0)
ROOM_AVAILABLE(PLAYER2,TEMPLE,1,0)
ROOM_AVAILABLE(PLAYER2,BRIDGE,1,0)
ROOM_AVAILABLE(PLAYER2,TORTURE,1,0)



REM ********** Traps 'n Doors **************

TRAP_AVAILABLE(PLAYER0,POISON_GAS,1,0)
TRAP_AVAILABLE(PLAYER0,LIGHTNING,1,0)
DOOR_AVAILABLE(PLAYER0,WOOD,1,0)

TRAP_AVAILABLE(PLAYER2,LIGHTNING,1,0)
TRAP_AVAILABLE(PLAYER2,WORD_OF_POWER,1,0)
DOOR_AVAILABLE(PLAYER2,MAGIC,1,0)






REM ################### Events ###################

REM Information counter: 2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17




REM ********** Welcome ********

DISPLAY_INFORMATION(17,PLAYER0)
REM "...you will get only the weakest creatures..."
DISPLAY_OBJECTIVE(5,PLAYER0)
REM "...dig carefull, there are enemies around..."



REM ********** Quest for Rooms *********

IF_AVAILABLE(PLAYER0,POWER_SIGHT == 1)
    DISPLAY_INFORMATION(6,PLAYER0)
    REM "...workshop and training room can be found in this realm..."
ENDIF

IF(PLAYER0,TRAINING > 0)
    ROOM_AVAILABLE(PLAYER0,TRAINING,1,1)
ENDIF

IF(PLAYER0,WORKSHOP > 0)
    ROOM_AVAILABLE(PLAYER0,WORKSHOP,1,1)
ENDIF



REM ********** 4 Trolls for a Tempel ***********

IF(PLAYER0,TOTAL_CREATURES >= 3)
    DISPLAY_OBJECTIVE(2,PLAYER0)
    REM "...force 4 Trolls to work for you to get a reward..."
ENDIF

IF(PLAYER0,TROLL > 3)
    ROOM_AVAILABLE(PLAYER0,TEMPLE,1,1)
    TUTORIAL_FLASH_BUTTON(12,PLAYER0)
    DISPLAY_OBJECTIVE(3,PLAYER0)
    REM "...the gods finally noticed you. You are rewarded..."
ENDIF

IF(PLAYER0,HORNY > 3)
    MAGIC_AVAILABLE(PLAYER0,POWER_OBEY,1,1)
    MAGIC_AVAILABLE(PLAYER0,POWER_IMP,1,1)
    TUTORIAL_FLASH_BUTTON(21,PLAYER0)
    DISPLAY_OBJECTIVE(7,PLAYER0)
    REM "...now try to kill that nasty rival across the river of lava..."
    DISPLAY_INFORMATION(4,PLAYER0)
    REM "...you will get along a little faster now..."
ENDIF



REM ************ Player Progress Messages **************

IF(PLAYER0,TOTAL_CREATURES > 19)
    DISPLAY_INFORMATION(9,PLAYER0)
    REM "Seems you know how to make Prisoners."
ENDIF

IF(PLAYER0,DARK_MISTRESS == 8)
    DISPLAY_INFORMATION(13,PLAYER0)
    REM "Yes, never leave your home without a handfull of mistresses."
ENDIF

IF_AVAILABLE(PLAYER0,POWER_LIGHTNING == 1)
    DISPLAY_INFORMATION(10,PLAYER0)
    TUTORIAL_FLASH_BUTTON(25,PLAYER0)
    REM "Danger! High Voltage!"
ENDIF



REM ************ Computer Progress Messages **********

IF(PLAYER2,TOTAL_CREATURES >= 24)
    DISPLAY_INFORMATION(11,PLAYER0)
    TUTORIAL_FLASH_BUTTON(1,PLAYER0)
    REM "What's mean and green and powerful too?"
ENDIF

IF(PLAYER2,BRIDGE > 1)
    DISPLAY_INFORMATION(14,PLAYER0)
    REM "What's mean and green and building a bridge?"
ENDIF

IF(PLAYER0,CREATURES_SCAVENGED_LOST >= 1)
    DISPLAY_INFORMATION(15,PLAYER0)
    REM "What's mean and green and steals your creatures?"
ENDIF

IF(PLAYER2,BATTLES_LOST > 13)
    IF(PLAYER2,TOTAL_CREATURES < 10)
        TUTORIAL_FLASH_BUTTON(1,PLAYER0)
        DISPLAY_INFORMATION(16,PLAYER0)
        REM "What's mean and green and about to die?"
    ENDIF
ENDIF


REM ############## Hidden Tricks ##############

REM Don't read any further, try to find out yourself.


REM ************* The Tentacle Trick **************

REM There is no clue about this in the game, so you have
REM to find it by accident or by reading this script.
REM But noone would read this script, that's illegal :)

IF(PLAYER0,TENTACLE > 5)
    MAGIC_AVAILABLE(PLAYER0,POWER_CHICKEN,1,1)
    TUTORIAL_FLASH_BUTTON(30,PLAYER0)
    DISPLAY_INFORMATION(12,PLAYER0)
    REM "I love tentacles too! Do you know what they do to a chicken?"
ENDIF



REM ************ Win or Lose **************

IF(PLAYER2,DUNGEON_DESTROYED == 1)
    DISPLAY_OBJECTIVE(8,PLAYER0)
    REM "...won..."
    WIN_GAME
ENDIF

IF(PLAYER0,DUNGEON_DESTROYED == 1)
    LOSE_GAME
ENDIF
